Hotkeys (Maus-, Joystick- und Tastaturkombinationen)

Inhaltsverzeichnis

Einführung und einfache Beispiele

Hotkeys werden manchmal auch als Tastenkürzel bezeichnet, weil sie schnell und einfach eine Aktion auslösen können (eine Aktion wäre beispielsweise das Starten eines Programms oder Tastatur-Makros). Das folgende Beispiel zeigt, wie der Texteditor mit dem Hotkey WIN+N gestartet werden kann. Das Raute-Zeichen [#] ist ein sogenannter Modifikator und symbolisiert die WIN-Taste:

#n::
Run Notepad
return

Das return in der letzten Zeile beendet den Hotkey. Wenn ein Hotkey allerdings nur eine einzige Zeile ausführen muss, kann diese Zeile rechts neben dem Doppelpunkt-Paar geschrieben werden. In diesem Fall wird das return automatisch angewendet:

#n::Run Notepad

Um zu erreichen, dass ein Hotkey von mehr als einem Modifikator ausgelöst werden kann, müssen diese nebeneinander aufgelistet werden (die Reihenfolge spielt keine Rolle). Das folgende Beispiel benutzt ^!s, um STRG+ALT+S zu kennzeichnen:

^!s::
Send Mit freundlichen Grüßen,{Enter}John Smith  ; Diese Zeile sendet Tastatureingaben an das aktive (vorderste) Fenster.
return

Folgende Modifikatorsymbole sind zum Definieren von Hotkeys möglich:

Symbol Beschreibung
# WIN-Taste (Windows-Logo-Taste). In v1.0.48.01+ werden, sofern man Windows Vista oder höher hat, Hotkeys in Verbindung mit der WIN-Taste (z. B. #a) warten, bis die WIN-Taste losgelassen wird, bevor ein beliebiger Text mit einem "L" gesendet wird. Dadurch wird verhindert, dass ein Send in so einem Hotkey den PC unbeabsichtigt sperrt. Diese Änderung gilt für alle Sendemethoden, außer SendPlay (weil es das nicht braucht) und Blind-Modus.
! ALT-Taste
^ STRG-Taste
+ UMSCHALT-Taste
& Mit einem Und-Zeichen können zwei beliebige Tasten oder Maustasten zu einem benutzerdefinierten Hotkey kombiniert werden. Siehe unten für weitere Details.
< Verwendet die linke Taste des Tastenpaares. Zum Beispiel würde <!a das gleiche wie !a bewirken, allerdings kann der Hotkey nur mit der linken ALT-Taste ausgelöst werden.
> Verwendet die rechte Taste des Tastenpaares.
<^>!

ALTGR-Taste (alternativer Schriftsatz). Wenn Ihre Tastaturbelegung eine ALTGR-Taste anstelle einer rechten ALT-Taste aufweist, kann diese Symbolreihe in der Regel für ALTGR benutzt werden. Zum Beispiel:

<^>!m::MsgBox Sie haben ALTGR+M gedrückt.
<^<!m::MsgBox Sie haben STRGLinks+ALTLinks+M gedrückt.

Wenn die ALTGR-Taste stattdessen selbst zu einem Hotkey gemacht werden soll, muss der folgende Hotkey benutzt werden (ohne dass Hotkeys wie oben vorhanden sind):

LControl & RAlt::MsgBox Sie haben ALTGR gedrückt.
*

Platzhalter: Bewirkt, dass der Hotkey immer ausgelöst wird, egal ob zusätzliche Modifikatoren gedrückt gehalten werden. Dieses Symbol wird oft zum Neubelegen von Tasten oder Maustasten benutzt. Zum Beispiel:

*#c::Run Calc.exe  ; WIN+C, UMSCHALT+WIN+C und STRG+WIN+C usw. können diesen Hotkey auslösen.
*ScrollLock::Run Notepad  ; ScrollLock wird diesen Hotkey immer auslösen, egal ob Modifikatoren gedrückt gehalten werden.

Platzhalter-Hotkeys sowie Hotkeys, die mit einem Platzhalter-Hotkey übereinstimmen würden, benutzen immer den Tastatur-Hook. Zum Beispiel würde die Anwesenheit von *a:: bewirken, dass ^a:: immer auf den Hook zugreifen wird.

~

Verhindert, dass die ursprünglichen Funktionen der Hotkey-Tasten blockiert werden (bzw. im System versteckt werden). Die Hotkeys im folgenden Beispiel bewirken, dass der Mausklick des Benutzers an das aktive Fenster gesendet wird, egal welche Aktionen ihnen zugewiesen ist:

~RButton::MsgBox Sie haben die rechte Maustaste gedrückt.
~RButton & C::MsgBox Sie haben C gedrückt`, während Sie die rechte Maustaste gedrückt hielten.

Im Gegensatz zu den anderen Präfix-Symbolen darf das Tilde-Präfix in einigen Varianten eines Hotkeys vorkommen und in anderen nicht. Wenn ein Tildezeichen allerdings an die Präfixtaste einer beliebigen benutzerdefinierten Tastenkombination angefügt wurde, die weder ausgeschaltet noch gesperrt ist, wird das Verhalten dieser Präfixtaste bei allen Kombinationen beeinflusst.

Spezielle Hotkeys, die etwas mit Alt-Tab zu tun haben, ignorieren immer das Tilde-Präfix.

[v1.1.14+]: Wenn das Tilde-Präfix an eine benutzerdefinierte Modifikatortaste (Präfixtaste) angefügt wird, die selbst auch ein Hotkey ist, wird dieser Hotkey ausgelöst, sobald die Taste nach unten gedrückt wird, und nicht erst, nachdem die Taste losgelassen wurde. Zum Beispiel wird der oben genannte Hotkey ~RButton bereits ausgelöst, wenn die Maustaste nach unten gedrückt wird. Vor v1.1.14 (bzw. ohne Tilde-Präfix) wurde der Hotkey erst ausgelöst, nachdem die Maustaste losgelassen wurde, sofern die Tastenkombination RButton & C nicht aktiviert war.

Wenn das Tilde-Präfix nur an die benutzerdefinierte Tastenkombination angefügt wird, aber nicht an den kombinationslosen Hotkey, wird die ursprüngliche Funktion der Taste weiterhin blockiert. Zum Beispiel bewirkt das folgende Skript, dass die MENÜ-Taste, sobald sie gedrückt gehalten wird, nicht das Kontextmenü auslöst, sondern einen ToolTip anzeigt:

AppsKey::ToolTip Drücke < oder > zum Durchschalten der Fenster.
AppsKey Up::ToolTip
~AppsKey & <::Send !+{Esc}
~AppsKey & >::Send !{Esc}

Sobald der Tilde-Modifikator bei mindestens einer Variante eines Tastatur-Hotkeys angegeben ist, wird dieser Hotkey immer den Tastatur-Hook benutzen.

$

Dieses Präfix ist normalerweise nur notwendig, um zu verhindern, dass ein Hotkey sich selbst via Send-Befehl auslösen kann. Das $-Präfix zwingt den Tastatur-Hook diesen Hotkey zu implementieren, um zu erreichen, dass dieser Hotkey nicht mehr durch den Send-Befehl ausgelöst werden kann. Dieses Präfix ist das gleiche wie, als hätte man #UseHook irgendwo vor der Hotkey-Definition angegeben.

Das $-Präfix hat keinen Effekt auf Maus-Hotkeys, weil solche Hotkeys immer auf den Maus-Hook zugreifen. Außerdem hat es keinen Effekt auf Hotkeys, die den Tastatur-Hook bereits einbeziehen, wie z. B. Tastatur-Hotkeys mit Tilde- (~) oder Platzhalter-Modifikatoren (*), KeyUp-Hotkeys und benutzerdefinierte Kombinationen. Mit ListHotkeys kann man feststellen, ob ein bestimmter Hotkey den Tastatur-Hook benutzt.

[v1.1.06+]: #InputLevel und SendLevel ermöglichen zusätzliche Kontrolle darüber, welche Hotkeys und Hotstrings durch den Send-Befehl ausgelöst werden sollen.

UP

Das UP-Wort muss nach dem Namen eines Hotkeys erfolgen und bewirkt, dass der Hotkey erst ausgelöst wird, wenn die Taste losgelassen wird, und nicht, wenn sie bereits nach unten gedrückt wird. Das folgende Beispiel zeigt, wie LWin neubelegt werden kann, um den Effekt von LControl nachzuahmen:

*LWin::Send {LControl Down}
*LWin Up::Send {LControl Up}

Das UP-Wort kann auch bei normalen Hotkeys angewendet werden. Zum Beispiel: ^!r Up::MsgBox Sie haben STRG+ALT+R gedrückt und losgelassen. Dieses Wort funktioniert auch bei Kombinations-Hotkeys (z. B. F1 & e Up::)

Einschränkungen: 1) UP funktioniert nicht in Verbindung mit Joystick-Tasten; und 2) Ein UP-Hotkey ohne entsprechendem Counterpart (normaler Hotkey oder DOWN-Hotkey) wird diese Taste komplett übernehmen, um zu verhindern, dass sie stecken bleibt. Eine Möglichkeit dies zu verhindern wäre es, ein Tilde-Präfix anzufügen (z. B. ~LControl up::)

UP-Hotkeys und ihre Counterparts (DOWN-Hotkeys, sofern vorhanden) benutzen immer den Tastatur-Hook.

Erwähnenswert ist außerdem, dass mit einer ähnlichen Methode wie oben ein Hotkey zu einer Präfix-Taste gemacht werden kann. Der Vorteil: Obwohl der Hotkey nach dem Loslassen ausgelöst wird, wird er dies nur tun, wenn Sie keine andere Taste drücken, während er gedrückt gehalten wurde. Zum Beispiel:

LControl & F1::return  ; Die linke STRG-Taste wird zu einem Präfix, sobald sie mindestens einmal vor "&" verwendet wird.
LControl::MsgBox Sie haben LControl losgelassen`, ohne mit ihr eine andere Taste zu modifizieren.

(Die Tastenliste enthält alle unterstützten Tastatur-, Maus- oder Joystick-Tasten)


Mehrere Hotkeys können vertikal übereinander gestapelt werden, um sie die gleiche Aktion durchführen zu lassen. Zum Beispiel:

^Numpad0::
^Numpad1::
MsgBox Drücke entweder STRG+Numpad0 oder STRG+Numpad1`, um diese Meldung anzuzeigen.
return

Um eine Taste oder Tastenkombination im kompletten System zu deaktivieren, ist es erforderlich, sie nichts tun zu lassen. Das folgende Beispiel deaktiviert die rechte WIN-Taste:

RWin::return

Kontextabhängige Hotkeys

Die Direktiven #IfWinActive/Exist und #If können benutzt werden, um Hotkeys je nach Bedingung unterschiedliche (oder überhaupt keine) Aktionen durchführen zu lassen. Zum Beispiel:

#IfWinActive, ahk_class Notepad
^a::MsgBox Sie haben STRG+A gedrückt`, während der Texteditor aktiv ist. Drückt man STRG+A in irgendeinem anderen Fenster, wird die Tastenkombination selbst gesendet.
#c::MsgBox Sie haben WIN+C gedrückt`, während der Texteditor aktiv ist.

#IfWinActive
#c::MsgBox Sie haben WIN+C gedrückt`, während ein beliebiges Fenster außer Texteditor aktiv ist.

#If MouseIsOver("ahk_class Shell_TrayWnd")
WheelUp::Send {Volume_Up}     ; Mausrad über die Taskleiste: Lautstärke erhöhen/verringern.
WheelDown::Send {Volume_Down} ;

Benutzerdefinierte Kombinationen

Um eine benutzerdefinierte Kombination zu definieren, die aus zwei Tasten (außer Joystick-Tasten) besteht, ist es erforderlich, " & " zwischen diesen Tasten zu setzen. Das folgende Beispiel zeigt, wie ein Hotkey ausgelöst werden kann, wenn Numpad0 gedrückt gehalten und danach eine zweite Taste gedrückt wird:

Numpad0 & Numpad1::MsgBox Sie haben Numpad1 gedrückt`, während Sie Numpad0 gedrückt hielten.
Numpad0 & Numpad2::Run Notepad

Die Präfixtaste verliert ihre ursprüngliche Funktion: Im oberen Beispiel wurde Numpad0 zu einer Präfixtaste gemacht; allerdings hat dies den Effekt, dass Numpad0 ihre originale/ursprüngliche Funktion nicht durchführen kann, sobald sie selbst gedrückt wird. Um das zu vermeiden, sollte man das Skript so konfigurieren, dass Numpad0 eine neue Aktion durchführt, wie z. B.:

Numpad0::WinMaximize A   ; Maximiert das aktive/vorderste Fenster.
Numpad0::Send {Numpad0}  ; Numpad0 erzeugt nach dem Loslassen eine Numpad0-Tastatureingabe. Siehe unteren Kommentar.

Hotkey nach dem Loslassen auslösen: Bereits einer der oben genannten benutzerdefinierten Kombinations-Hotkeys bewirkt, dass die definierte Aktion erst ausgelöst wird, wenn Numpad0 losgelassen wird, aber nur, wenn Sie keine andere Taste drücken, während Numpad0 gedrückt gehalten wurde. In v1.1.14+ kann dieses Verhalten unterdrückt werden, wenn man ein Tilde-Präfix an beiden Hotkeys anfügt.

Modifikatoren: Im Gegensatz zu normalen Hotkeys verhalten sich benutzerdefinierte Kombinationen so, als hätten sie standardmäßig den Platzhalter-Modifikator (*). Zum Beispiel wird 1 & 2:: immer ausgelöst, egal ob man beim Drücken von 1 und 2 die STRG- oder ALT-Taste gedrückt hält, während ^1:: nur durch Drücken von STRG+1 ausgelöst werden kann, und nicht durch STRG+ALT+1.

In Bezug auf standardmäßigen Modifikatortasten funktionieren normale Hotkeys in der Regel genauso oder besser als "benutzerdefinierte" Kombinationen. Zum Beispiel ist <+s:: eher zu empfehlen als LShift & s::.

Kombinationen, die aus drei oder mehr Tasten bestehen, werden nicht unterstützt. Kombinationen können, sofern sie von Ihrer Tastatur unterstützt werden, mithilfe von #If und GetKeyState erkannt werden, allerdings ist ein konsistentes Ergebnis nicht immer gegeben. Zum Beispiel:

; Halten Sie die MENÜ- und ALT-Taste gedrückt, und drücken Sie dann Bindestrich (-).
#if GetKeyState("AppsKey", "P")
Alt & -::MsgBox Hotkey aktiviert.

; Notwendig, wenn ALT zuerst gedrückt gehalten wird:
#if GetKeyState("Alt", "P")
AppsKey & -::MsgBox Hotkey aktiviert.

; , & . & -::
#if GetKeyState(",") && GetKeyState(".")
-::MsgBox

Tastatur-Hook: Benutzerdefinierte Kombinationen, die Tastatur-Tasten enthalten, sowie Hotkeys, die die Präfixtaste als Suffix benutzen, verwenden immer den Tastatur-Hook. Zum Beispiel würde a & b:: bewirken, dass ^a:: immer den Hook einbeziehen wird.

Sonstige Features

NUM-, FESTSTELL- und ROLLEN-Taste: Diese Tasten können gezwungen werden, "AlwaysOn" (immer an) oder "AlwaysOff" (immer aus) zu sein. Zum Beispiel: SetNumlockState AlwaysOn.

Explorer-Tastenkürzel überschreiben: Die vordefinierten Windows-Hotkeys wie WIN+E (#e) und WIN+R (#r) können jeweils mit einer beliebigen benutzerdefinierten Aktion überschrieben werden. Siehe "Überschreiben oder Deaktivieren von Hotkeys" für Details.

Alt-Tab ersetzen: Hotkeys können eine alternative Methode für Alt-Tab bereitstellen. Zum Beispiel bewirken die folgenden zwei Hotkeys, dass die Alt-Tab-Prozedur mit der rechten Hand durchgeführt werden kann:

RControl & RShift::AltTab  ; Halten Sie rechte STRG gedrückt und drücken Sie mehrmals rechte UMSCHALT, um durchzuschalten.
RControl & Enter::ShiftAltTab  ; Halten Sie weiter rechte STRG gedrückt und drücken Sie ENTER, um in die andere Richtung durchzuschalten.

Siehe Alt-Tab für weitere Details.

Mausrad-Hotkeys

Mit den Tastennamen WheelDown und WheelUp können Hotkeys erstellt werden, die durch Drehen des Mausrads ausgelöst werden können. In v1.0.48+ werden auch die Tastennamen WheelLeft und WheelRight unterstützt, allerdings funktionieren diese nicht in Betriebssystemen älter als Windows Vista. Hier einige Beispiele für Mausrad-Hotkeys:

MButton & WheelDown::MsgBox Sie haben das Mausrad nach unten gedreht`, während Sie die mittlere Maustaste gedrückt hielten.
^!WheelUp::MsgBox Sie haben das Mausrad nach oben gedreht`, während Sie STRG+ALT gedrückt hielten.

In v1.0.43.03+ enthält die interne Variable A_EventInfo die Anzahl, wie häufig das Mausrad stufenweise gedreht wurde (üblicherweise 1). Allerdings kann A_EventInfo größer oder kleiner als 1 sein, wenn folgende Bedingungen zutreffen:

Einige der nützlichsten Mausrad-Hotkeys sind solche, die alternative Methoden zum Scrollen eines Fenstertextes bereitstellen. Folgende Hotkey-Paare bewirken beispielsweise, dass das Scrollen horizontal statt vertikal erfolgt, wenn Sie das Mausrad drehen, während Sie die linke STRG-Taste gedrückt halten:

~LControl & WheelUp::  ; Scrollt nach links.
ControlGetFocus, fcontrol, A
Loop 2  ; <-- Erhöhe diesen Wert, um das Scrollen zu beschleunigen.
    SendMessage, 0x114, 0, 0, %fcontrol%, A  ; 0x114 ist WM_HSCROLL und die 0 danach SB_LINELEFT.
return

~LControl & WheelDown::  ; Scrollt nach rechts.
ControlGetFocus, fcontrol, A
Loop 2  ; <-- Erhöhe diesen Wert, um das Scrollen zu beschleunigen.
    SendMessage, 0x114, 1, 0, %fcontrol%, A  ; 0x114 ist WM_HSCROLL und die 1 danach SB_LINERIGHT.
return

Da Mausrad-Hotkeys nur Down-Ereignisse (nie Up-Ereignisse) erzeugen, können sie nicht als KeyUp-Hotkeys verwendet werden.

Tipps und Hinweise

Jede Ziffernblocktaste kann umfunktioniert werden, um je nach Status der NUM-Taste zwei verschiedene Hotkey-Subroutinen zu starten. Alternativ kann man eine Ziffernblocktaste auch die gleiche Subroutine starten lassen, egal welchen Status die NUM-Taste aktuell hat. Zum Beispiel:

NumpadEnd::
Numpad1::
MsgBox, Dieser Hotkey wurde unabhängig vom Status der NUM-Taste ausgelöst.
return

Wenn der Tilde-Operator (~) einmal in Verbindung mit einer Präfixtaste gebracht wurde, ändert er das Verhalten dieser Präfixtaste bei allen Kombinationen. Bei den beiden Hotkeys unten würden beispielsweise alle Rechtsklick-Ereignisse beim aktiven Fenster ankommen, obwohl nur eine der Definitionen das Tilde-Zeichen enthält:

~RButton & LButton::MsgBox Sie haben die linke Maustaste gedrückt`, während Sie die Rechte gedrückt hielten.
RButton & WheelUp::MsgBox Sie haben das Mausrad nach oben gedreht`, während Sie die rechte Maustaste gedrückt hielten.

Der Suspend-Befehl kann vorübergehend alle Hotkeys deaktivieren, außer Hotkeys, die Sie gezielt ausgeschlossen haben. Mit #IfWinActive/Exist kann man besser abstimmen, welche Hotkeys wann und wo aktiv sein sollen.

Mithilfe des Hotkey-Befehls können Hotkeys dynamisch erstellt werden, während das Skript läuft. Der Hotkey-Befehl kann zudem bereits existierende Hotkeys einzeln bearbeiten, deaktivieren oder aktivieren.

Aktuell unterstützen Joystick-Hotkeys keine Modifikatorpräfixe wie ^ (STRG) und # (WIN). Allerdings kann dieser Effekt mit GetKeyState nachgeahmt werden:

Joy2::
if not GetKeyState("Control")  ; Weder die linke noch die rechte STRG-Taste ist unten.
    return  ; also nichts tun.
MsgBox Sie haben die zweite Taste des ersten Joysticks gedrückt`, während Sie die STRG-Taste gedrückt hielten.
return

Manchmal ist es sinnvoll, dass ein Hotkey erst ausgelöst werden soll, wenn seine Modifikatortasten wieder oben sind. Schauen Sie sich dazu das folgende Beispiel an:

^!s::Send {Delete}

Wenn man in diesem Fall STRG+ALT+S drückt, wird das System fälschlicherweise ein STRG+ALT+ENTF erkennen (aufgrund der aggressiven Erkennung dieser Tastenkombination). Um das zu umgehen, verwendet man KeyWait, um auf das Loslassen der Tasten zu warten; zum Beispiel:

^!s::
KeyWait Control
KeyWait Alt
Send {Delete}
return

Wenn ein Hotkey wie z. B. #z:: den Fehler "Invalid Hotkey" (ungültiger Hotkey) erzeugt, ist es sehr wahrscheinlich, dass das betroffene Zeichen ("Z" in diesem Fall) in der Tastaturbelegung/Sprache Ihres Systems fehlt. Versuchen Sie es mit einem Zeichen, das auf Ihrer Tastaturbelegung zu finden ist.

Ein Hotkey-Label kann als Ziel von Gosub oder Goto angegeben werden. Zum Beispiel: Gosub ^!s.

Häufig werden Hotkeys dazu verwendet, eine wiederholende Aktion, z. B. eine Reihe von Tastatureingaben oder Mausklicks, zu starten und zu stoppen. Ein Beispiel dazu findet man in den Häufig gestellten Fragen (FAQ).

Jedes Skript kann quasi aus mehreren Threads bestehen, dadurch ist es möglich, dass ein neuer Hotkey gestartet werden kann, während eine andere Hotkey-Subroutine noch läuft. Neue Hotkeys können jederzeit ausgelöst werden, egal ob ein anderer Hotkey beispielsweise eine MsgBox anzeigt.

Alt-Tab-Hotkeys

Jeder Alt-Tab-Hotkey muss aus zwei Tasten bestehen, die mithilfe eines Und-Zeichens (&) kombiniert wurden. Das folgende Beispiel zeigt, wie man mit der rechten ALT-Taste und den Tasten J oder K im Alt-Tab-Menü navigieren kann:

RAlt & j::AltTab
RAlt & k::ShiftAltTab

AltTab und ShiftAltTab gehören zu speziellen Befehlen, die nur erkannt werden, wenn sie in Verbindung mit einem einzeiligen Hotkey benutzt werden. Hier die komplette Liste:

AltTab: Navigiert im Alt-Tab-Menü nach rechts, sofern das Menü sichtbar ist. Ansonsten wird das Menü geöffnet (nur wenn der Hotkey aus zwei mit "&" kombinierten Tasten besteht, sonst passiert nichts).

ShiftAltTab: Das gleiche wie oben, aber in die andere Richtung.

AltTabAndMenu: Navigiert im Alt-Tab-Menü nach rechts, sofern das Menü sichtbar ist. Ansonsten wird das Menü geöffnet.

AltTabMenuDismiss: Schließt das Alt-Tab-Menü.

Zum Beispiel wäre es möglich, die Alt-Tab-Prozedur mit dem Mausrad durchzuführen. Wenn die folgenden Hotkeys aktiv sind, kann das Menü mit der mittleren Maustaste geöffnet und mit dem Mausrad durchgeschaltet werden:

MButton::AltTabMenu
WheelDown::AltTab
WheelUp::ShiftAltTab

Mit einem Hotkey wie der Folgende kann ein via Hotkey aufgerufenes Alt-Tab-Menü geschlossen werden, ohne dass das ausgewählte Fenster aktiviert werden muss. Möglicherweise sind Anpassungen notwendig, je nachdem: 1) womit das Alt-Tab-Menü ursprünglich geöffnet wurde; und 2) ob das Skript den Tastatur-Hook installiert hat.

LCtrl & CapsLock::AltTab
!MButton::  ; Mittlere Maustaste. Das !-Präfix bewirkt, dass der Hotkey nur ausgelöst werden kann, wenn die ALT-Taste unten ist (das in der Regel der Fall ist, wenn das Alt-Tab-Menü sichtbar ist).
IfWinExist ahk_class #32771  ; Setzt voraus, dass das Alt-Tab-Menü auf dem Bildschirm vorhanden ist.
    Send !{Escape}{Alt up}
return

Zurzeit müssen alle speziellen Alt-Tab-Aktionen direkt einem Hotkey wie oben zugewiesen werden (das heißt, dass sie nicht wie Befehle behandelt werden können). Sie werden nicht von #IfWin oder #If beeinflusst.

Benutzerdefinierte Alt-Tab-Aktionen können auch via Hotkeys erstellt werden. Das folgende Beispiel zeigt, wie man mit F1 das Menü öffnen und durchschalten kann und wie man mit F2 das ausgewählte Fenster aktivieren kann (oder wie man mit ESC das Menü schließen kann):

*F1::Send {Alt down}{tab} ; Sternchen ist in diesem Fall notwendig.
!F2::Send {Alt up}  ; Lässt die ALT-Taste los, um das ausgewählte Fenster zu aktivieren.
~*Escape::
IfWinExist ahk_class #32771
    Send {Escape}{Alt up}  ; Schließt das Menü, ohne das ausgewählte Fenster zu aktivieren.
return

Funktions-Hotkeys [v1.1.20+]

Es ist möglich, einem oder mehreren Hotkeys eine Funktion zuzuweisen, indem man sie einfach unterhalb des Hotkey-Labels definiert. Zum Beispiel:

; STRG+UMSCHALT+O, um den enthaltenen Ordner im Explorer zu öffnen.
; STRG+UMSCHALT+E, um den Ordner zu öffnen und darin die aktuelle Datei zu markieren.
; Unterstützt SciTE und Notepad++.
^+o::
^+e::
    editor_ordner_öffnen() {
        WinGetTitle, pfad, A
        if RegExMatch(pfad, "\*?\K(.*)\\[^\\]+(?= [-*] )", pfad)
            if (FileExist(pfad) && A_ThisHotkey = "^+e")
                Run explorer.exe /select`,"%pfad%"
            else
                Run explorer.exe "%pfad1%"
    }

Es dürfen nur Leerraumzeichen, Kommentare oder Direktiven zwischen den Hotkey-Labels oder dem Label und der Funktion vorkommen. Es werden keine Labels erstellt, wenn Hotkeys auf diese Weise definiert werden; allerdings endet der automatische Ausführungsbereich beim ersten Hotkey, selbst wenn ihm eine Funktion zugewiesen wurde.

Das Verwenden einer Funktion hat den Vorteil, dass lokale Variablen verwendet werden können, um so Konflikte zu vermeiden, wenn zwei oder mehr Hotkeys die gleichen Variablennamen für unterschiedliche Zwecke verwenden. Außerdem fördert es selbstdokumentierende Hotkeys; im Code oben beschreibt der Funktionsname zum Beispiel den Hotkey.

Mit dem Hotkey-Befehl kann einem Hotkey auch eine Funktion oder ein Funktionsobjekt zugewiesen werden.