Send / SendRaw / SendInput / SendPlay / SendEvent: Tasten & Klicks senden

Sendet simulierte Tastatureingaben und Mausklicks zum aktiven Fenster.

Send Tasten
SendRaw Tasten
SendInput Tasten
SendPlay Tasten
SendEvent Tasten

Parameter

Tasten

Eine Reihe von Tasten, die gesendet werden soll. Das Komma vor dem ersten Parameter ist, wie bei anderen Befehlen auch, optional.

Raw-Modus - SendRaw oder {Raw}: Die Zeichen ^+!#{} werden als direkt geschriebener Text interpretiert, anstatt z. B. {Enter} in ENTER, ^c in STRG+C usw. zu übersetzen. Um den Raw-Modus bei SendInput, SendPlay oder SendEvent zu verwenden, gibt man {Raw} als erstes Element in der Zeichenkette an; zum Beispiel: SendInput {Raw}abc.

Der Raw-Modus hat keinen Einfluss auf die Interpretation von Escapesequenzen, Variablenverweise und Ausdrücke. Zum Beispiel würde SendRaw, ``100`% die Zeichenkette `100% senden. Beim ControlSend müssen zudem direkt geschriebene Kommas mit einem Escapezeichen versehen werden (`,).

Normal-Modus: Wenn der Raw-Modus nicht aktiv ist, haben folgende Symbole eine besondere Bedeutung: !+^#{}

Die Modifikatoren !+^# beeinflussen nur die direkt darauffolgende Taste. Um die entsprechende Modifikatortaste separat zu senden, umschließt man den Tastennamen mit geschweiften Klammern. Um eine Taste einfach nur zu drücken (gedrückt halten) oder loszulassen, muss nach dem Tastennamen das Wort "down" oder "up" erfolgen, wie unten gezeigt.

Symbol Taste Drücken Loslassen Beispiele
! {Alt} {Alt down} {Alt up} Send !a drückt ALT+a
+ {Shift} {Shift down} {Shift up} Send +abC sendet den Text "AbC"
Send !+a drückt ALT+UMSCHALT+a
^ {Ctrl} {Ctrl down} {Ctrl up} Send ^{Home} drückt STRG+POS1
# {LWin}
{RWin}
{LWin down}
{RWin down}
{LWin up}
{RWin up}
Send #e hält die WIN-Taste gedrückt und drückt dann den Buchstaben "e"
Symbol Bedeutung
{ } Mit geschweiften Klammern werden Tastennamen und andere Optionen umschlossen, um spezielle Zeichen als direkt geschriebener Text zu senden. Zum Beispiel wäre {Tab} die TAB-Taste und {!} ein direkt geschriebenes Ausrufezeichen.

Hinweis: Großbuchstaben werden durch Senden der UMSCHALT-Taste erzeugt, daher würde z. B. A in einigen Programmen eine andere Wirkung als a erzielen. Zum Beispiel würde !A ALT+UMSCHALT+A und !a ALT+a drücken. Im Zweifelsfall sollte man immer Kleinbuchstaben verwenden.


SendInput und SendPlay [v1.0.43+]: SendInput und SendPlay verwenden die gleiche Syntax wie Send, allerdings sind sie in der Regel schneller und zuverlässiger. Desweiteren puffern sie alle physischen Tastatur- oder Mausaktivitäten während des Send-Befehls, um das Vermischen der Benutzereingaben mit den gesendeten Eingaben zu verhindern. Verwende SendMode, um Send zum Synonym für SendInput oder SendPlay zu machen. Um mehr Details über jeden Modus zu erfahren, siehe SendInput und SendPlay.

SendEvent [v1.0.43+]: SendEvent sendet Tastatureingaben mit der gleichen Methode wie der Send-Befehl vor Version 1.0.43. Die Sendegeschwindigkeit von Tastatureingaben wird mit SetKeyDelay bestimmt. Standardmäßig ist Send das Synonym für SendEvent; allerdings kann es via SendMode zum Synonym für SendInput oder SendPlay gemacht werden.

Tastennamen: Die folgende Tabelle listet alle speziellen Tasten auf, die gesendet werden können (jeder Tastenname muss mit geschweiften Klammern umschlossen werden):

   
{F1} - {F24} Funktionstasten. Zum Beispiel: {F12} ist die F12-Taste.
{!} !
{#} #
{+} +
{^} ^
{{} {
{}} }
{Enter} ENTER-Taste
{Escape} oder {Esc} ESC-Taste
{Space} LEERTASTE (nur für Leerzeichen notwendig, die am Anfang oder Ende der Zeichenkette vorkommen - Leerzeichen in der Mitte können direkt geschrieben sein)
{Tab} TAB-Taste
{Backspace} oder {BS} RÜCKTASTE
{Delete} oder {Del} ENTF-Taste
{Insert} oder {Ins} EINFG-Taste
{Up} NACH-OBEN-Taste
{Down} NACH-UNTEN-Taste
{Left} NACH-LINKS-Taste
{Right} NACH-RECHTS-Taste
{Home} POS1-Taste
{End} ENDE-Taste
{PgUp} BILD-NACH-OBEN-Taste
{PgDn} BILD-NACH-UNTEN-Taste
   
{CapsLock} FESTSTELL-Taste (in Win 2k/XP ist SetCapsLockState zuverlässiger). Das Senden von {CapsLock} benötigt möglicherweise vorher SetStoreCapslockMode Off.
{ScrollLock} ROLLEN-Taste (siehe auch: SetScrollLockState)
{NumLock} NUM-Taste (siehe auch: SetNumLockState)
   
{Control} oder {Ctrl} STRG-Taste (technische Info: sendet die neutrale virtuelle Taste, aber den linken Scancode)
{LControl} oder {LCtrl} Linke STRG-Taste (technische Info: sendet nicht die neutrale, sondern die linke virtuelle Taste)
{RControl} oder {RCtrl} Rechte STRG-Taste
{Control Down} oder {Ctrl Down} Hält die STRG-Taste gedrückt, bis {Ctrl Up} gesendet wird. Um stattdessen die linke oder rechte Taste gedrückt zu halten, nutzt man {RCtrl Down} und {RCtrl Up}.
   
{Alt} ALT (technische Info: sendet die neutrale virtuelle Taste, aber den linken Scancode)
{LAlt} Linke ALT-Taste (technische Info: sendet nicht die neutrale, sondern die linke virtuelle Taste)
{RAlt} ALTGR- oder rechte ALT-Taste, abhängig von der Tastaturbelegung.
{Alt Down} Hält die ALT-Taste gedrückt, bis {Alt Up} gesendet wird. Um stattdessen die linke oder rechte Taste gedrückt zu halten, nutzt man {RAlt Down} und {RAlt Up}.
   
{Shift} UMSCHALT-Taste (technische Info: sendet die neutrale virtuelle Taste, aber den linken Scancode)
{LShift} Linke UMSCHALT-Taste (technische Info: sendet nicht die neutrale, sondern die linke virtuelle Taste)
{RShift} Rechte UMSCHALT-Taste
{Shift Down} Hält die UMSCHALT-Taste gedrückt, bis {Shift Up} gesendet wird. Um stattdessen die linke oder rechte Taste gedrückt zu halten, nutzt man {RShift Down} und {RShift Up}.
   
{LWin} Linke WIN-Taste
{RWin} Rechte WIN-Taste
{LWin Down} Hält die linke WIN-Taste gedrückt, bis {LWin Up} gesendet wird.
{RWin Down} Hält die rechte WIN-Taste gedrückt, bis {RWin Up} gesendet wird.
   
{AppsKey} MENÜ-Taste (öffnet das Rechtsklick- oder Kontextmenü)
{Sleep} SLEEP-Taste (auf den meisten Tastaturen nicht vorhanden).
{ASC nnnnn}

Sendet eine ALT+nnnnn-Tastenkombination per Ziffernblock, um Sonderzeichen zu erzeugen, die auf der Tastatur normalerweise nicht vorhanden sind. Um ASCII-Zeichen zu generieren, gibt man eine Nummer zwischen 1 und 255 an. Um ANSI-Zeichen zu generieren (Standard in den meisten Sprachen), gibt man zuerst eine 0 an und danach eine Nummer zwischen 128 und 255, zum Beispiel {Asc 0133}.

Um Unicode-Zeichen zu generieren, gibt man eine Nummer zwischen 256 und 65535 an (ohne 0 davor). Allerdings wird das nicht von jeder Anwendung unterstützt. Alternativen dazu finden Sie im nächsten Abschnitt.

{U+nnnn}

[AHK_L 24+]: Sendet ein Unicode-Zeichen - nnnn ist der hexadezimale Wert des Zeichens ohne 0x-Präfix. Diese Methode ist in den Unicode-Versionen von AutoHotkey üblicherweise nicht notwendig, weil ihr Send und ControlSend von sich aus Unicode-Text unterstützen.

Wenn das Zeichen keinem virtuellen Tastencode zugeordnet ist, wird SendInput() oder WM_CHAR verwendet, um das Zeichen zu senden, und der aktuelle Send-Modus ignoriert.

{vkXX}
{scYYY}
{vkXXscYYY}

Sendet eine Tastatureingabe, die die virtuelle Taste XX und den Scancode YYY hat. Zum Beispiel: Send {vkFFsc159}. Wenn man den sc- oder vk-Bereich weglässt, wird der am besten geeignete Wert an seiner Stelle gesendet.

Die Werte für XX und YYY sind hexadezimal und können üblicherweise über den Menüpunkt View-> Key history im Hauptfenster abgerufen werden. Siehe auch: Sondertasten

   
{Numpad0} - {Numpad9} Ziffernblocktasten (wenn Numlock eingeschaltet ist). Zum Beispiel: {Numpad5} ist die Zahl 5.
{NumpadDot} , (wenn Numlock eingeschaltet ist)
{NumpadEnter} ENTER-Taste
{NumpadMult} *
{NumpadDiv} /
{NumpadAdd} +
{NumpadSub} -
   
{NumpadDel} ENTF-Taste (diese und die nachfolgenden Ziffernblocktasten sind nur verwendbar, wenn Numlock ausgeschaltet ist)
{NumpadIns} EINFG-Taste
{NumpadClear} Funktionslose Taste
{NumpadUp} NACH-OBEN-Taste
{NumpadDown} NACH-UNTEN-Taste
{NumpadLeft} NACH-LINKS-Taste
{NumpadRight} NACH-RECHTS-Taste
{NumpadHome} POS1-Taste
{NumpadEnd} ENDE-Taste
{NumpadPgUp} BILD-NACH-OBEN-Taste
{NumpadPgDn} BILD-NACH-UNTEN-Taste
   
{Browser_Back} Browser "Zurück"
{Browser_Forward} Browser "Vorwärts"
{Browser_Refresh} Browser "Aktualisieren"
{Browser_Stop} Browser "Stopp"
{Browser_Search} Browser "Suchen"
{Browser_Favorites} Browser "Favoriten"
{Browser_Home} Startet den Browser und öffnet die Startseite
{Volume_Mute} Gesamtlautstärke stummschalten bzw. Stummschaltung aufheben. Normalerweise das gleiche wie SoundSet, +1, , mute.
{Volume_Down} Gesamtlautstärke leiser machen. Normalerweise das gleiche wie SoundSet, -5.
{Volume_Up} Gesamtlautstärke lauter machen. Normalerweise das gleiche wie SoundSet, +5.
{Media_Next} Media Player "Nächster Track"
{Media_Prev} Media Player "Vorheriger Track"
{Media_Stop} Media Player "Stopp"
{Media_Play_Pause} Media Player "Wiedergabe/Anhalten"
{Launch_Mail} E-Mail-Programm öffnen
{Launch_Media} Media Player öffnen
{Launch_App1} Benutzerdefiniertes Programm 1 öffnen
{Launch_App2} Benutzerdefiniertes Programm 2 öffnen
   
{PrintScreen} DRUCK-Taste
{CtrlBreak} STRG+UNTBR
{Pause} PAUSE-Taste
   
{Click [Optionen]}
[v1.0.43+]
Sendet einen Mausklick, das die gleichen Optionen verwendet wie die vom Click-Befehl. Zum Beispiel würde {Click} die linke Maustaste einmal bei der aktuellen Mausposition klicken, und {Click 100, 200} würde auf den Koordinaten 100, 200 klicken (basierend auf CoordMode). Um den Mauszeiger ohne Klicken zu verschieben, gibt man nach den Koordinaten eine 0 an; zum Beispiel: {Click 100, 200, 0}. Die Verzögerung zwischen den Mausklicks wird durch SetMouseDelay bestimmt (nicht SetKeyDelay).
{WheelDown}, {WheelUp}, {WheelLeft}, {WheelRight}, {LButton}, {RButton}, {MButton}, {XButton1}, {XButton2} Sendet ein Maustastenereignis auf die aktuelle Mausposition (um die Position und weitere Optionen zu kontrollieren, siehe {Click}). Die Verzögerung zwischen den Mausklicks wird durch SetMouseDelay bestimmt. WheelLeft/Right benötigen v1.0.48+, allerdings funktionieren sie nicht in Betriebssystemen älter als Windows Vista.
{Blind}

Wenn {Blind} das erste Element in der Zeichenkette ist, wird das Programm das Loslassen von ALT/STRG/UMSCHALT/WIN verhindern, sofern sie zu Beginn im gedrückten Zustand waren. Zum Beispiel würde der Hotkey +s::Send {Blind}abc ABC statt abc senden, weil der Benutzer die UMSCHALT-Taste gedrückt hält.

{Blind} bewirkt auch, dass SetStoreCapslockMode ignoriert wird; das heißt, dass der Status der Festelltaste nicht geändert wird. Zudem lässt {Blind} die zusätzlichen STRG-Tasten weg, die ansonsten gesendet werden würden; solche Tastatureingaben verhindern: 1) die Darstellung des Startmenüs während LWIN/RWIN-Eingaben; 2) die Aktivierung der Menüleiste während ALT-Eingaben.

Der Blind-Modus wird beim Neubelegen einer Taste automatisch verwendet. Zum Beispiel würde die Neubelegung a::b folgendes erzeugen: 1) "b" wenn man "a" eingibt; 2) großes B wenn man ein großes A eingibt; und 3) STRG+B wenn man STRG+A eingibt.

{Blind} wird nicht in Verbindung mit SendRaw und ControlSendRaw unterstützt. Desweiteren wird es nicht in Verbindung mit SendPlay unterstützt, besonders im Umgang mit Modifikatortasten (STRG, ALT, UMSCHALT und WIN).

{Raw}
[v1.0.43+]
Aktiviert den Raw-Modus, wodurch die folgenden Zeichen als direkt geschriebener Text interpretiert werden: ^+!#{}. Zwar muss {Raw} nicht am Anfang der Zeichenkette vorkommen, allerdings bleibt es, wenn es einmal angegeben wurde, für den Rest der Zeichenkette aktiv.

Mehrfaches oder haltendes Drücken einer Taste

Mehrfaches Drücken: Umschließen Sie den Namen der Taste und die Anzahl an Wiederholungen mit geschweiften Klammern. Zum Beispiel:

Send {DEL 4}  ; Drückt viermal die ENTF-Taste.
Send {S 30}   ; Sendet 30 große S-Zeichen.
Send +{TAB 4}  ; Drückt viermal UMSCHALT+TAB.

Halten oder Loslassen: Umschließen Sie den Namen der Taste und das Wort Down oder Up mit geschweiften Klammern. Zum Beispiel:

Send {b down}{b up}
Send {TAB down}{TAB up}
Send {Up down}  ; Drückt die NACH-OBEN-Taste nach unten.
Sleep 1000  ; Hält sie eine Sekunde lang gedrückt.
Send {Up up}  ; Lässt die NACH-OBEN-Taste los.

Wenn eine Taste mit der Methode oben gedrückt gehalten wird, erfolgt keine Auto-Wiederholung, wie es beim physischen Gedrückthalten geschehen würde (Auto-Wiederholung ist nämlich ein Treiber/Hardware-Feature). Allerdings kann mit einer Schleife das Auto-Wiederholen künstlich erzeugt werden. Das folgende Beispiel sendet 20 Tabulator-Eingaben:

Loop 20
{
    Send {Tab down}  ; Auto-Wiederholen besteht aus fortlaufenden Down-Ereignissen (ohne Up-Ereignisse).
    Sleep 30  ; Die Anzahl an Millisekunden zwischen den Tastatureingaben (oder verwende SetKeyDelay).
}
Send {Tab up}  ; Lässt die Taste los.

Das Wort DownTemp kann auch verwendet werden. Sein Effekt das gleiche wie Down, außer bei Modifikatortasten (STRG/UMSCHALT/ALT/WIN). DownTemp benachrichtigt nachfolgende Send-Befehle, dass die Taste nicht permanent im gedrückten Zustand ist, und dass sie jederzeit losgelassen werden könnte. Zum Beispiel würde Send {Control DownTemp} und dann Send a ein normales "a" erzeugen, nicht einen STRG+A-Tastendruck.

Allgemeine Bemerkungen

Es gibt keine bestimmten Einschränkungen bezüglich der Zeichen, die gesendet werden können. Wenn ein Zeichen auf der aktuellen Tastaturbelegung nicht existiert, wird es durch Senden eines Unicode-Zeichenpackets oder einer ALT+nnnnn-Kombination künstlich erzeugt, abhängig von der AutoHotkey-Version. In den Unicode-Versionen von AutoHotkey können Unicode-Zeichen direkt angegeben werden, bei allen anderen Versionen nur mithilfe der {U+nnnn}-Schreibweise.

BlockInput im Vergleich zu SendInput/SendPlay: Zwar kann man mit dem BlockInput-Befehl verhindern, dass physische Benutzereingaben den simulierten Eingabeverlauf unterbrechen, allerdings sollte man dafür besser SendInput oder SendPlay verwenden. SendInput/Play verhindert im Gegensatz zu BlockInput, dass die eingegebenen Tasten des Benutzers während des Sendens verworfen werden; stattdessen werden solche Tastendrücke zwischengespeichert, um sie anschließend zu senden.

Beim Senden vieler Tastatureingaben kann ein Fortsetzungsbereich hilfreich sein, um den Text besser lesbar und verwaltbar zu machen.

Da das Betriebssystem das Simulieren von STRG+ALT+ENTF nicht erlaubt, kann so etwas wie Send ^!{Delete} nicht funktionieren.

Send könnte nicht funktionieren in Windows Vista oder höher, wenn das aktive Fenster mit administrativen Rechten läuft, und das Skript nicht. Das hängt mit dem Sicherheitsmechanismus "User Interface Privilege Isolation" (UIPI) zusammen.

SendInput [v1.0.43+]

SendInput ist in der Regel die bevorzugte Methode, um Tastatureingaben und Mausklicks zu senden, weil sie bedeutend schneller und zuverlässiger ist. In den meisten Fällen wird SendInput die Tastatureingaben sofort senden, selbst bei langen Zeichenketten. Aufgrund dieser Schnelligkeit ist SendInput auch zuverlässiger, weil die Chance geringer ist, dass ein anderes Fenster unerwartet erscheint und die Tastatureingaben abfängt. Die Zuverlässigkeit erhöht sich nochmals durch die Tatsache, dass die Benutzereingaben während eines SendInput-Befehls bis zum Schluss zwischengespeichert werden.

Im Gegensatz zu den anderen Sendmethoden ist SendInput auf ca. 5000 Zeichen begrenzt (dieser Grenzwert variiert je nach Version des Betriebssystems und Performance-Einstellungen). Zeichen und Ereignisse oberhalb des Limits werden nicht gesendet.

Hinweis: SendInput ignoriert SetKeyDelay, weil das Betriebssystem keine Verzögerung in diesem Modus unterstützt. Wenn SendInput allerdings aufgrund der unten genannten Bedingungen auf SendEvent zurückgreift, wird es SetKeyDelay -1, 0 verwenden (wenn aber SendEvent's Tastenverzögerung -1, -1 ist, wird -1, -1 verwendet). Wenn SendInput auf SendPlay zurückgreift, wird es SendPlay's Tastenverzögerung verwenden.

Wenn ein Skript - außer das Skript, das SendInput ausführt - einen systemnahen Tastatur-Hook installiert hat, wird SendInput automatisch auf SendEvent zurückgreifen (oder auf SendPlay, wenn SendMode InputThenPlay wirksam ist). Dieses Verhalten ist notwendig, weil das Vorhandensein eines externen Hooks alle Vorteile von SendInput zunichte machen würde, so dass es sowohl SendPlay als auch SendEvent unterlegen wäre. Da SendInput jedoch einen systemnahen Hook in Programmen außer v1.0.43+ nicht erkennen kann, wird es in solchen Fällen nicht auf einen anderen Modus zurückgreifen, wodurch es unzuverlässiger als SendPlay/Event werden würde.

Wenn SendInput einen Mausklick mithilfe von z. B. {Click} sendet, während CoordMode Mouse, Relative aktiv ist (die Standardeinstellung), wird jeder Klick relativ zum Fenster sein, das vor dem Senden aktiv war. Demzufolge, wenn SendInput absichtlich ein anderes Fenster aktiviert (z. B. mit ALT+TAB), werden die Koordinaten der nachfolgenden Klicks innerhalb des gleichen Befehls falsch sein, weil sie weiterhin relativ zum alten statt zum neuen Fenster sind.

SendPlay [v1.0.43+]

Hinweis: SendPlay funktioniert möglicherweise überhaupt nicht, wenn UAC aktiviert ist, selbst wenn das Skript mit Administratorrechten läuft. Weitere Informationen finden Sie in der FAQ.

SendPlay's größter Vorteil ist seine Fähigkeit, Tastatureingaben und Mausklicks bei einer breiteren Auswahl an Spielen "wiedergeben" zu können. Zum Beispiel könnten Hotstrings in einem Spiel nur funktionieren, wenn sie die SendPlay-Option haben.

SendPlay ist, im Gegensatz zu den anderen Sendemethoden, am ungewöhnlichsten, weil dieser Modus selbst keine Tastatureingaben und Mausklicks simuliert. Stattdessen erstellt es eine Reihe von Ereignissen (Meldungen), die direkt in das aktive Fenster einfließen (so ähnlich wie ControlSend, aber auf einem niedrigeren Niveau). Demzufolge kann SendPlay keine Hotkeys oder Hotstrings auslösen.

Wie bei SendInput auch, können sich SendPlay's Tastatureingaben nicht mit den Benutzereingaben vermischen. Wenn der Benutzer also während SendPlay etwas eingibt, werden solche Tastatureingaben bis zum Schluss zwischengespeichert.

Zwar ist SendPlay deutlich langsamer als SendInput, aber schneller als der traditionelle SendEvent-Modus (selbst wenn Tastenverzögerung auf -1 ist).

Die WIN-Tasten (LWin und RWin) werden während SendPlay automatisch blockiert, wenn der Tastatur-Hook installiert ist. Dadurch wird verhindert, dass das Startmenü angezeigt wird, wenn der Benutzer versehentlich eine WIN-Taste während des Sendens drückt. Alle anderen Tasten außer LWin und RWin müssen nicht blockiert werden, weil das Betriebssystem sie automatisch zwischenspeichert, bis SendPlay durchgeführt wurde (via Puffer).

SendPlay verwendet nicht die Standardeinstellungen von SetKeyDelay und SetMouseDelay. Stattdessen gilt standardmäßig überhaupt keine Verzögerung, das wie folgt geändert werden kann:

SetKeyDelay, 0, 10, Play  ; Beachten Sie, dass sowohl 0 als auch -1 das gleiche sind im SendPlay-Modus.
SetMouseDelay, 10, Play

SendPlay kann die FESTSTELL-, NUM- oder ROLLEN-Taste weder ein- noch ausschalten. SendPlay kann zudem den Status einer Taste, wie von GetKeyState gesehen, nicht ändern, es sei denn, die Tastatureingaben werden zu den Fenstern des Skripts gesendet. Selbst dann können Änderungen an den linken/rechten Modifikatortasten (z. B. RControl) nur über ihrem neutralen Gegenstück (z. B. Control) erkannt werden. Außerdem gelten für SendPlay noch weitere Einschränkungen, die auf der SendMode-Seite zu finden sind.

Im Gegensatz zu SendInput und SendEvent kann SendPlay von einem Benutzer unterbrochen werden, indem er STRG+ALT+ENTF oder STRG+ESC drückt. Wenn dies geschieht, werden die restlichen Tastatureingaben nicht gesendet, und danach das Skript fortgesetzt, als ob das SendPlay normal abgeschlossen wurde.

Zwar kann SendPlay LWin- und RWin-Ereignisse senden, allerdings werden sie direkt zum aktiven Fenster gesendet, anstatt ihre interne Betriebssystemfunktion durchzuführen. Um das zu umgehen, nutzt man SendEvent. Zum Beispiel würde SendEvent #r das Ausführen-Dialogfenster des Startmenüs anzeigen.

Siehe auch

SendMode, SetKeyDelay, SetStoreCapslockMode, Escapezeichen (z. B. `%), ControlSend, BlockInput, Hotstrings, WinActivate

Beispiele

Send Mit freundlichen Grüßen,{enter}John Smith  ; Schreibt eine zweizeilige Signatur.
Send !ds ; Öffnet das Dateimenü und wählt Speichern aus (ALT+D, gefolgt von S).
Send {End}+{Left 4} ; Springt ans Textende und sendet viermal UMSCHALT+NACH-LINKS.
SendInput {Raw}Eine Reihe unberarbeiteter Zeichen, die mit der schnellsten Methode (SendInput) gesendet wurden.