TrayTip

Erstellt eine Sprechblase in der Nähe des Tray-Symbols. In Windows 10 wird eine Popupbenachrichtigung angezeigt.

TrayTip , Titel, Text, Sekunden, Optionen

Parameter

Titel

Der Titel des Fensters. Es werden nur die ersten 73 Zeichen angezeigt.

Wenn Titel leer ist, wird die Titelzeile des Fensters komplett weggelassen und das Fenster vertikal gekürzt.

Warnung: Das Fenster wird nicht angezeigt, wenn der Text-Parameter weggelassen wird, selbst wenn ein Titel angegeben ist.

Text

Eine Nachricht, die angezeigt werden soll. Es werden nur die ersten 265 Zeichen angezeigt.

Wenn dieser Parameter weggelassen wird oder leer ist, werden alle derzeit angezeigten TrayTip-Sprechblasenfenster entfernt. Um allerdings eine Popupbenachrichtigung von Windows 10 zu verstecken, ist es eventuell notwendig, das Tray-Symbol vorübergehend zu entfernen.

Die Zeilenumbruchszeichen CR (`r) oder LF (` n) können verwendet werden, um mehrere Textzeilen zu erstellen. Zum Beispiel: Zeile1`nZeile2.

Wenn der Text relativ lang ist, kann er via Fortsetzungsbereich in mehreren kurzen Zeilen aufgeteilt werden, um die Übersichtlichkeit und Wartbarkeit des Skripts zu erhöhen.

Sekunden

Hinweis: Dieser Parameter funktioniert nicht in Windows Vista und höher.

Die ungefähre Anzahl an Sekunden, wie lange das Fenster angezeigt werden soll, bevor es danach wieder vom Betriebssystem entfernt wird. Die Angabe einer Zahl kleiner als 10 oder größer als 30 bewirkt, dass stattdessen die minimale (10) oder maximale (30) Anzeigedauer verwendet wird. Wenn dieser Parameter weggelassen wird oder leer ist, wird üblicherweise die minimale Zeit verwendet. Dieser Parameter kann ein Ausdruck sein.

Das tatsächliche Zeitlimit weicht von dem ab, was angegeben wurde. Eine Erklärung von Microsoft: "Wenn der Benutzer keine Aktionen auf dem Computer ausführt, berücksichtigt das System diese Zeit bei der Berechnung des Timeouts nicht." (technische Details hier). Zur genauen Bestimmung der Anzeigedauer des TrayTip-Fensters kann der Sleep-Befehl, gefolgt von TrayTip ohne Parameter, verwendet werden, oder SetTimer, wie im unteren Beispielabschnitt gezeigt.

Optionen

Der Optionen-Parameter kann eine Kombination (Summe) von null oder mehreren der folgenden Werte sein.

FunktionDezimal-WertHex-Wert
Infosymbol10x1
Warnungssymbol20x2
Fehlersymbol30x3
Windows XP und höher: Benachrichtigungs-Sound nicht abspielen.160x10
Windows Vista und höher: Große Version des Symbols verwenden.320x20

Lässt man diesen Parameter weg, wird standardmäßig 0 verwendet (kein Symbol). Das Symbol ist außerdem nur in einem Sprechblasenfenster sichtbar, wenn ein Titel vorhanden ist (dies gilt nicht für Popupbenachrichtigungen von Windows 10).

Dieser Parameter kann ein Ausdruck sein.

Bemerkungen

Ein typisches TrayTip-Fenster sieht in Windows 10 wie folgt aus:

TrayTip

Standardmäßig ersetzt Windows 10 alle Sprechblasenfenster mit Popupbenachrichtigungen (das aber mit einer Gruppenrichtlinie überschrieben werden kann). Ruft man TrayTip mehrmals auf, werden die Benachrichtigungen in eine "Warteschlange" gesetzt und nacheinander abgearbeitet, anstatt sich gegeneinander zu ersetzen. Um eine Benachrichtigung zu verstecken, kann es hilfreich sein, das Tray-Symbol vorübergehend zu entfernen. Zum Beispiel:

TrayTip #1, Das erste TrayTip
Sleep 3000   ; 3 Sekunden lang anzeigen lassen.
TrayTipVerstecken()
TrayTip #2, Die zweite Benachrichtigung.
Sleep 3000

; Fügen Sie diese Funktion in Ihr Skript ein, um es zu benutzen.
TrayTipVerstecken() {
    TrayTip  ; Normale Methode zum Verstecken benutzen.
    if SubStr(A_OSVersion,1,3) = "10." {
        Menu Tray, NoIcon
        Sleep 200  ; Möglicherweise muss dieser Sleep-Wert angepasst werden.
        Menu Tray, Icon
    }
}

TrayTip funktioniert nicht, wenn das Tray-Symbol des Skripts deaktiviert ist (via #NoTrayIcon oder Menu, Tray, NoIcon). TrayTip funktioniert auch nicht, wenn der folgende REG_DWORD-Wert vorhanden und auf 0 gesetzt ist:

HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced >> EnableBalloonTips

Beachten Sie zudem, dass ein Tooltip angezeigt wird, sobald sich der Mauszeiger über das Tray-Symbol des Skripts befindet. Der Inhalt des Tooltips kann wie folgt geändert werden: Menu, Tray, Tip, Neuer Text.

ToolTip, SetTimer, Menu, SplashTextOn, MsgBox, InputBox, FileSelectFile, FileSelectFolder

Beispiele

Zeigt eine mehrzeilige Sprechblase oder Toast-Benachrichtigung für 20 Sekunden in der Nähe des Tray-Symbols an, ohne den Benachrichtigungston abzuspielen. Sie hat auch einen Titel und enthält ein Info-Symbol.

TrayTip, Mein Titel, Mehrzeiliger`nText, 20, 17

Ermöglicht eine genauere Kontrolle über die Anzeigedauer, ohne Sleep verwenden zu müssen (das den aktuellen Thread anhalten würde). Handelt es sich um Windows 10, ersetzen Sie diese Funktion mit der oben definierten.

#Persistent
TrayTip, Zeitgesteuertes TrayTip, Wird 5 Sekunden lang angezeigt.
SetTimer, TrayTipVerstecken, -5000

TrayTipVerstecken() {
    TrayTip
}

Zeigt ein TrayTip permanent an, indem es periodisch via Timer erneuert wird. Beachten Sie, dass dies in Windows 10 wegen der oben genannten Gründe wahrscheinlich nicht gut funktionieren wird.

#Persistent
SetTimer, TrayTipErneuern, 1000
Gosub, TrayTipErneuern  ; Einmal direkt aufrufen, um einen sofortigen Start zu erzwingen.
return

TrayTipErneuern:
TrayTip, Erneuertes TrayTip, Dies ist ein permanentes TrayTip., , 16
return