Ruft verschiedene Arten von Informationen über die Laufwerke des Computers ab.
DriveGet, AusgabeVar, Unterbefehl , Wert
Der AusgabeVar-Parameter ist Name der Ausgabevariable, in der das Ergebnis gespeichert werden soll. Die Parameter Unterbefehl und Wert sind voneinander abhängig und können wie folgt genutzt werden.
Geben Sie für Unterbefehl Folgendes an:
Ermittelt eine Zeichenkette aus Buchstaben, die jeweils einen Laufwerksbuchstaben im System repräsentieren.
DriveGet, AusgabeVar, List , Typ
Ausgabebeispiel: ACDEZ. Lässt man Typ weg, werden alle Laufwerkstypen abgerufen. Geben Sie ansonsten für Typ eines der folgenden Wörter an, um nur einen bestimmten Laufwerkstyp abzurufen: CDROM, REMOVABLE, FIXED, NETWORK, RAMDISK, UNKNOWN.
Ermittelt die Gesamtkapazität eines Laufwerks, das den angegebenen Pfad enthält (in Megabyte).
DriveGet, AusgabeVar, Capacity, Pfad
Pfad ist ein beliebiger Pfad, der im Laufwerk enthalten ist (kann auch mit UNC-Pfaden und zugeordneten Laufwerken funktionieren). Der Ausgabewert wird auf die nächste ganze Zahl abgerundet. Mit DriveSpaceFree kann der freie Speicherplatz abgerufen werden.
Ermittelt den Typ des Dateisystems eines bestimmten Laufwerks.
DriveGet, AusgabeVar, FileSystem, Laufwerk
Laufwerk ist der Laufwerksbuchstabe, gefolgt von einem Doppelpunkt und einem optionalen umgekehrten Schrägstrich, oder ein UNC-Name wie \\server1\share1. Die möglichen Werte für AusgabeVar sind vom System vorgegeben und können zum Beispiel die folgenden sein: NTFS, FAT32, FAT, CDFS (typisch für CDs) oder UDF (typisch für DVDs). AusgabeVar wird leer gemacht und ErrorLevel auf 1 gesetzt, wenn das Laufwerk kein formatiertes Medium enthält.
Ermittelt die Datenträgerbezeichnung eines bestimmten Laufwerks.
DriveGet, AusgabeVar, Label, Laufwerk
Laufwerk ist der Laufwerksbuchstabe, gefolgt von einem Doppelpunkt und einem optionalen umgekehrten Schrägstrich, oder ein UNC-Name wie \\server1\share1.
Mit dem Label-Unterbefehl von Drive kann die Bezeichnung eines Laufwerks geändert werden, wie z. B. Drive, Label, C:, MeinLabel
Ermittelt die Datenträgerseriennummer eines bestimmten Laufwerks.
DriveGet, AusgabeVar, Serial, Laufwerk
Laufwerk ist der Laufwerksbuchstabe, gefolgt von einem Doppelpunkt und einem optionalen umgekehrten Schrägstrich, oder ein UNC-Name wie \\server1\share1. Siehe Format() oder SetFormat, wie man den Ausgabewert in einen hexadezimalen Wert umwandeln kann.
Ermittelt den Typ eines Laufwerks, das den angegebenen Pfad enthält.
DriveGet, AusgabeVar, Type, Pfad
Pfad ist ein beliebiger Pfad, der im Laufwerk enthalten ist (kann auch mit UNC-Pfaden und zugeordneten Laufwerken funktionieren). AusgabeVar wird leer gemacht, wenn der Pfad ungültig ist (zum Beispiel, weil das Laufwerk nicht existiert). Ansonsten wird es auf eines der folgenden Wörter gesetzt: Unknown, Removable, Fixed, Network, CDROM, RAMDisk.
Ermittelt den Status eines Laufwerks, das den angegebenen Pfad enthält.
DriveGet, AusgabeVar, Status, Pfad
Pfad ist ein beliebiger Pfad, der im Laufwerk enthalten ist (kann auch mit UNC-Pfaden und zugeordneten Laufwerken funktionieren). AusgabeVar wird auf eines der folgenden Wörter gesetzt:
| Status | Hinweise |
|---|---|
| Unknown | Könnte auf ein unformatiertes/RAW-Dateisystem hinweisen. |
| Ready | Kommt am häufigsten vor. |
| NotReady | Typisch für Wechseldatenträger, die kein Medium enthalten. |
| Invalid | Pfad existiert nicht oder ist ein Netzwerklaufwerk, auf das momentan nicht zugegriffen werden kann, usw. |
Ermittelt den Medienstatus eines CD- oder DVD-Laufwerks.
DriveGet, AusgabeVar, StatusCD , Laufwerk
Laufwerk ist der Laufwerksbuchstabe, gefolgt von einem Doppelpunkt. Lässt man Laufwerk weg, wird das Standard-CD/DVD-Laufwerk verwendet. AusgabeVar wird leer gemacht, wenn der Status nicht abgerufen werden kann. Ansonsten wird es auf eine der folgenden Zeichenketten gesetzt:
| Status | Bedeutung |
|---|---|
| not ready | Das Laufwerk ist nicht bereit für den Zugriff, zum Beispiel aufgrund eines Schreibvorgangs. Bekannte Einschränkung: "not ready" tritt auch auf, wenn das Laufwerk eine DVD statt CD enthält. |
| open | Das Laufwerk enthält keine CD, oder ist ausgefahren. |
| playing | Das Laufwerk spielt gerade eine CD ab. |
| paused | Die zuvor abgespielte Audio- oder Videowiedergabe ist nun pausiert. |
| seeking | Das Laufwerk ist am Suchen. |
| stopped | Das Laufwerk enthält eine CD, aber greift momentan nicht darauf zu. |
Dieser Unterbefehl wird eventuell nicht funktionieren, wenn das angegebene Laufwerk ein Netzwerk- oder Nicht-CD/DVD-Laufwerk ist; wenn dieser Befehl in solchen Fällen oder aus einem anderen Grund fehlschlägt, wird AusgabeVar leer gemacht und ErrorLevel auf 1 gesetzt.
Wenn das Laufwerk vor Kurzem geschlossen wurde, kann es zu einer Verzögerung kommen, bevor der Unterbefehl zu Ende ist.
Mit dem Eject-Unterbefehl von Drive kann ein Laufwerk ein- oder ausgefahren werden.
[v1.1.04+]: Dieser Befehl ist in der Lage, bei Misserfolg eine Ausnahme auszulösen. Weitere Informationen finden Sie unter Laufzeitfehler.
ErrorLevel wird bei Misserfolg auf 1 und bei Erfolg auf 0 gesetzt.
Einige dieser Unterbefehle akzeptieren als Pfad oder Laufwerk auch Netzwerkfreigabenamen wie \\MeinServer\MeinFreigabe\.
Erlaubt dem Benutzer, ein Laufwerk zum Analysieren auszuwählen.
FileSelectFolder, Ordner,, 3, Laufwerk zum Analysieren auswählen:
if not Ordner
return
DriveGet, Liste, List
DriveGet, Max, Capacity, %Ordner%
DriveSpaceFree, Frei, %Ordner%
DriveGet, DS, FileSystem, %Ordner%
DriveGet, Name, Label, %Ordner%
DriveGet, Nummer, Serial, %Ordner%
DriveGet, Typ, Type, %Ordner%
DriveGet, Status, Status, %Ordner%
MsgBox Alle Laufwerke: %Liste%`nAusgewähltes Laufwerk: %Ordner%`nTyp: %Typ%`nStatus: %Status%`nKapazität: %Max% M`nFreier Speicher: %Frei% M`nDateisystem: %DS%`nBezeichnung: %Name%`nSeriennummer: %Nummer%