Hotstring() - Syntax & Verwendung

Erstellt, bearbeitet, aktiviert oder deaktiviert einen Hotstring, während das Skript läuft.

Parameter

Fehlerbehandlung

Diese Funktion löst eine Ausnahme aus, wenn die Parameter ungültig sind oder eine Speicherreservierung fehlschlägt. Sie hat keinen Einfluss auf ErrorLevel.

Eine Ausnahme wird auch ausgelöst, wenn Ersatz weggelassen wird und Zkette gültig ist, aber nicht mit einem existierenden Hotstring übereinstimmt. Dieser Sachverhalt kann genutzt werden, um die Existenz eines Hotstrings zu testen. Zum Beispiel:

Bemerkungen

Ein Label oder eine Funktion kann das Ziel von mehreren Hotstrings sein. Wenn Sie wissen, dass ein Label oder eine Funktion durch einen Hotstring aufgerufen wurde, können Sie auf die interne Variable A_ThisHotkey zurückgreifen, um zu überprüfen, welcher Hotstring das war.

Wenn das Skript suspendiert ist, werden neu hinzugefügte/aktivierte Hotstrings ebenfalls suspendiert, bis die Suspension wieder aufgehoben wird (es sei denn, sie sind davor geschützt, wie im Suspend-Abschnitt beschrieben).

Die Tastatur- und/oder Maus-Hooks werden bei dieser Funktion je nach Bedarf automatisch installiert oder entfernt.

Diese Funktion kann Hotstrings von anderen Skripten nicht direkt aktivieren oder deaktivieren.

Sobald ein Skript mindestens einen Hotstring hat, wird es persistent; das heißt, dass ExitApp anstelle von Exit verwendet werden muss, um dieses Skript terminieren zu können. Hotstring-Skripte sind zudem automatisch #SingleInstance (einzeln vorkommend), sofern nicht #SingleInstance, Off verwendet wurde.

Hotstring-Varianten (-Duplikate)

Ein bestimmter Hotstring kann mehr als einmal erstellt werden, wenn für jede Definition ein anderes IfWin-Kriterium, eine andere Groß-/Kleinschreibung-Sensitivität (C vs. C0/C1) oder Wort-Sensitivität (?) angegeben wird. Auch bekannt als Hotstring-Varianten. Zum Beispiel:

Bei mehreren gleichzeitig aktiven Varianten eines Hotstrings wird nur die zuerst erstellte Variante ausgelöst.

EndChars

Ermittelt oder modifiziert einen Satz von Zeichen, die vom Hotstring-Erkenner als Endungszeichen verwendet werden. Zum Beispiel:

Es ist derzeit nicht möglich, für jeden Hotstring einen anderen Satz von Endungszeichen anzugeben.

MouseReset

Ermittelt oder modifiziert die globale Einstellung, die bestimmt, ob Mausklicks den Hotstring-Erkenner zurücksetzen dürfen, wie hier beschrieben. NeuerWert sollte 1 (True) sein, um die Erkennung von Mausklicks und das Zurücksetzen des Hotstring-Erkenners zu aktivieren, oder 0 (False), um es zu deaktivieren. Der Rückgabewert ist die Einstellung, die vor dem Aufruf der Funktion wirksam war.

Der Maus-Hooks wird bei dieser Funktion je nach Bedarf automatisch installiert oder entfernt.

#Hotstring NoMouse wirkt sich auch auf diese Einstellung aus, und ist das gleiche wie, als würde man False für NeuerWert angeben.

Reset [v1.1.28.01+]

Setzt sofort den Hotstring-Erkenner zurück. Das heißt, dass das Skript auf einen völlig neuen Hotstring wartet und dass alles, was Sie zuvor eingegeben haben, verworfen wird.

Standardoptionen setzen

Um neue Standardoptionen für danach erstellte Hotstrings zu bestimmen, übergeben Sie die Optionen ohne Doppelpunkte am Anfang oder Ende an die Hotstring-Funktion. Zum Beispiel: Hotstring("T").

Das Einschalten der Groß-/Kleinschreibung-Sensitivität (C) oder der Wort-Sensitivität (?) wirkt sich auch darauf aus, welche vorhandenen Hotstrings gefunden werden, wenn man die Hotstring-Funktion aufruft. Zum Beispiel wird Hotstring(":T:btw") standardmäßig ::BTW finden, aber nicht, wenn Hotstring("C") oder #Hotstring C wirksam ist. Um das rückgängig zu machen oder zu überschreiben, übergeben Sie eine Option, die die andere Option automatisch ausschließt; C0 und C1 beispielsweise würde C überschreiben.

Siehe auch

Beispiele

Hotstring Helper. Das folgende Skript könnte nützlich sein, wenn Sie Hotstrings intensiv nutzen. Es basiert auf das Skript von Andreas Borutta. Drücken Sie Win+H (oder einen anderen Hotkey Ihrer Wahl), um den aktuell markierten Text in einen Hotstring umzuwandeln. Wenn Sie in einem Textverarbeitungsprogramm zum Beispiel "beziehungsweise" markieren und Win+H drücken, wird das Skript Sie auffordern, eine Abkürzung für diesen Text zu bestimmen (z. B. bzw), und dann den neuen Hotstring in das Skript einfügen. Der Hotstring wird aktiviert, ohne dass das Skript neu geladen werden muss.

#h::  ; Hotkey: WIN+H
; Ermittelt den aktuell markierten Text. Es wird die Zwischenablage statt
; "ControlGet Selected" benutzt, um das Skript für mehr Texteditoren
; funktionsfähig zu machen. Speichert die aktuelle Zwischenablage und
; stellt sie später wieder her (allerdings funktioniert das nur mit
; reinem Text):
ClipboardAlt := Clipboard
Clipboard := "" ; Muss vorerst leer sein, damit die Erkennung funktioniert.
Send ^c
ClipWait 1
if ErrorLevel  ; ClipWait hat die Zeit überschritten.
    return
; Ersetze CRLF und/oder LF mit `n für einen Hotstring im Raw-Modus:
; Das gleiche wird für jedes andere Zeichen getan,
; das ein Problem im Raw-Modus sein könnte:
ClipInhalt := StrReplace(Clipboard, "``", "````")  ; Zuerst diese Ersetzung, um die darunter nicht zu stören.
ClipInhalt := StrReplace(ClipInhalt, "`r`n", "``n")
ClipInhalt := StrReplace(ClipInhalt, "`n", "``n")
ClipInhalt := StrReplace(ClipInhalt, "`t", "``t")
ClipInhalt := StrReplace(ClipInhalt, "`;", "```;")
Clipboard := ClipboardAlt  ; Den vorherigen Inhalt der Zwischenablage wiederherstellen.
ZeigeInputBox(":T:`::" ClipInhalt)
return

ZeigeInputBox(Standardwert)
{
    ; Den Textcursor des Eingabefensters auf eine benutzerfreundliche Position verschieben:
    SetTimer, VerschiebeTextcursor, 10
    ; Das Eingabefenster mit dem vordefinierten Hotstring anzeigen:
    InputBox, BenutzerEingabe, Neuer Hotstring,
    (
    Fügen Sie Ihre Abkürzung an die Position des Textcursors ein. Bei Bedarf können Sie den Ersatztext noch ändern.

    Beispieleintrag: :R:bzw`::beziehungsweise
    ),,,,,,,, %Standardwert%
    if ErrorLevel  ; Der Benutzer hat Abbrechen gedrückt.
        return

    if RegExMatch(BenutzerEingabe, "O)(?P<Label>:.*?:(?P<Abkuerzung>.*?))::(?P<Ersatztext>.*)", Hotstring)
    {
        if !Hotstring.Abkuerzung
            Mitteilung := "Sie haben keine Abkürzung angegeben"
        else if !Hotstring.Ersatztext
            Mitteilung := "Sie haben keinen Ersatztext angegeben"
        else
        {
            Hotstring(Hotstring.Label, Hotstring.Ersatztext)  ; Aktiviert jetzt den Hotstring.
            FileAppend, `n%BenutzerEingabe%, %A_ScriptFullPath%  ; Speichert den Hotstring für den späteren Gebrauch.
        }
    }
    else
        Mitteilung := "Der Hotstring scheint falsch strukturiert zu sein"

    if Mitteilung
    {
        MsgBox, 4,, %Mitteilung%. Möchten Sie es noch einmal versuchen?
        IfMsgBox, Yes
            ZeigeInputBox(Standardwert)
    }
    return
    
    VerschiebeTextcursor:
    WinWait, Neuer Hotstring
    ; Den Textcursor des Eingabefensters auf eine Position verschieben, wo der Benutzer die Abkürzung eintragen kann.
    Send {Home}{Right 3}
    SetTimer,, Off
    return
}

Hotstring() [v1.1.28+]