Hotkeys werden manchmal auch als Tastaturkurzbefehle bezeichnet, weil sie schnell und einfach eine Aktion auslösen können (eine Aktion wäre z.B. das Starten eines Programms oder eines Tastaturmakros). Das folgende Beispiel zeigt, wie Notepad mit dem Hotkey Win+N gestartet werden kann. Das Rautezeichen [#] ist ein sogenannter Modifikator und symbolisiert Win:
#n::
{
Run "notepad"
}
Im obigen Beispiel dienen die geschweiften Klammern dazu, einen Funktionskörper für den Hotkey zu definieren. Die geschweifte Startklammer kann auf derselben Zeile wie das Doppelpunktpaar stehen, um den One True Brace (OTB) Style zu unterstützen. Wenn ein Hotkey jedoch nur eine einzige Zeile ausführen muss, kann diese Zeile rechts neben dem Doppelpunktpaar geschrieben werden. Mit anderen Worten, die geschweiften Klammern sind implizit:
#n::Run "notepad"
Beim Auslösen eines Hotkeys wird der Name des Hotkeys (ohne die Doppelpunkte am Ende) als erster Parameter namens ThisHotkey übergeben. Zum Beispiel:
#n::MsgBox ThisHotkey ; Meldet #n
Bis auf wenige Ausnahmen ähnelt dies der internen Variable A_ThisHotkey. Der Parametername kann mit einer benannten Funktion geändert werden.
Um zu erreichen, dass ein Hotkey von mehr als einem Modifikator ausgelöst werden kann, müssen diese nebeneinander aufgelistet werden (die Reihenfolge spielt keine Rolle). Das folgende Beispiel verwendet ^!s für Strg+Alt+S:
^!s::
{
Send "Mit freundlichen Grüßen,{enter}Max Mustermann" ; Diese Zeile sendet Tastendrücke an das aktive (vorderste) Fenster.
}
Sie können die folgenden Modifikatorsymbole verwenden, um Hotkeys zu definieren:
| Symbol | Beschreibung |
|---|---|
| # |
Win (Windows-Logo-Taste). Hotkeys, die Win enthalten (z.B. #a), warten darauf, bis Win losgelassen wird, bevor sie einen Text senden, der einen L-Tastendruck enthält. Dadurch wird verhindert, dass ein Send in so einem Hotkey den PC unbeabsichtigt sperrt. Dieses Verhalten gilt für alle Send-Modi, außer SendPlay (weil es das nicht braucht), Blind-Modus und Text-Modus. Hinweis: Das Drücken eines Hotkeys, der Win enthält, kann zu zusätzlichen simulierten Tastendrücken führen (standardmäßig Strg). Siehe A_MenuMaskKey. |
| ! |
Alt Hinweis: Das Drücken eines Hotkeys, der Alt enthält, kann zu zusätzlichen simulierten Tastendrücken führen (standardmäßig Strg). Siehe A_MenuMaskKey. |
| ^ | Strg |
| + | Umschalt |
| & | Mit einem Und-Zeichen können zwei beliebige Tasten oder Maustasten zu einem benutzerdefinierten Hotkey kombiniert werden. Einzelheiten finden Sie unten. |
| < | Verwendet die linke Taste des Tastenpaares. Zum Beispiel ist <!a äquivalent zu !a, allerdings kann der Hotkey nur mit der linken Alt-Taste ausgelöst werden. |
| > | Verwendet die rechte Taste des Tastenpaares. |
| <^>! | AltGr (alternative Grafik bzw. alternativer Schriftsatz). Wenn Ihre Tastaturbelegung AltGr anstelle einer rechten Alt-Taste aufweist, kann diese Symbolreihe in der Regel für AltGr verwendet werden. Zum Beispiel: <^>!m::MsgBox "Sie haben ALTGR+M gedrückt." <^<!m::MsgBox "Sie haben STRGLinks+ALTLinks+M gedrückt." Wenn Sie stattdessen AltGr selbst zu einem Hotkey machen wollen, verwenden Sie den folgenden Hotkey (ohne dass Hotkeys wie oben vorhanden sind): LControl & RAlt::MsgBox "Sie haben ALTGR gedrückt." |
| * | Platzhalter: Bewirkt, dass der Hotkey immer ausgelöst wird, egal ob zusätzliche Modifikatoren gedrückt gehalten werden. Dieses Symbol wird oft zum Neubelegen von Tasten oder Maustasten benutzt. Zum Beispiel: *#c::Run "calc.exe" ; WIN+C, UMSCHALT+WIN+C und STRG+WIN+C usw. können diesen Hotkey auslösen. *ScrollLock::Run "notepad" ; ScrollLock wird diesen Hotkey immer auslösen, egal ob Modifikatoren gedrückt gehalten werden. Platzhalter-Hotkeys verwenden immer den Tastatur-Hook, ebenso wie alle Hotkeys, die mit einem Platzhalter-Hotkey übereinstimmen würden. Zum Beispiel würde das Vorhandensein von |
| ~ | Verhindert, dass beim Auslösen des Hotkeys die ursprüngliche Funktion seiner Taste blockiert (vor dem System verborgen) wird. Die Hotkeys im folgenden Beispiel bewirken, dass der Mausklick des Benutzers immer an das aktive Fenster gesendet wird, unabhängig von ihren zugewiesenen Aktionen: ~RButton::MsgBox "Sie haben die rechte Maustaste gedrückt." ~RButton & C::MsgBox "Sie haben C gedrückt, während Sie die rechte Maustaste gedrückt hielten." Im Gegensatz zu den anderen Präfixsymbolen darf das Tilde-Präfix bei einigen Varianten eines Hotkeys vorhanden sein, bei anderen jedoch nicht. Wendet man jedoch eine Tilde auf die Präfixtaste einer benutzerdefinierten Tastenkombination an, die weder ausgeschaltet noch suspendiert ist, beeinflusst die Tilde das Verhalten dieser Präfixtaste bei allen Kombinationen. Spezielle Hotkeys, die etwas mit Alt-Tab zu tun haben, ignorieren immer das Tilde-Präfix. Wendet man das Tilde-Präfix auf eine benutzerdefinierte Modifikatortaste (Präfixtaste) an, die auch als eigener Hotkey verwendet wird, wird dieser Hotkey sofort beim Drücken ausgelöst, nicht erst nach dem Loslassen der Taste. Zum Beispiel wird der ~RButton-Hotkey oben bereits ausgelöst, wenn die Maustaste nach unten gedrückt wird. Wendet man das Tilde-Präfix nur auf die benutzerdefinierte Tastenkombination an, nicht aber auf den kombinationslosen Hotkey, wird die ursprüngliche Funktion der Taste weiterhin blockiert. Zum Beispiel bewirkt das folgende Skript, dass beim Gedrückthalten der Menü-Taste ein Tooltip angezeigt wird, anstatt ein Kontextmenü zu öffnen: AppsKey::ToolTip "Drücke < oder > zum Durchschalten der Fenster."
AppsKey Up::ToolTip
~AppsKey & <::Send "!+{Esc}"
~AppsKey & >::Send "!{Esc}"
Wenn mindestens eine Variante eines Tastatur-Hotkeys den Tilde-Modifikator hat, verwendet dieser Hotkey immer den Tastatur-Hook. |
| $ |
Dieses Präfix wird normalerweise nur benötigt, um zu verhindern, dass der Hotkey von einer Send-Funktion ausgelöst wird. Das $-Präfix zwingt den Tastatur-Hook, diesen Hotkey zu implementieren, so dass dieser nicht mehr durch eine Send-Funktion ausgelöst werden kann. Dieses Präfix ist das gleiche wie, als hätte man Das $-Präfix hat keinen Effekt auf Maus-Hotkeys, weil sie immer den Maus-Hook verwenden. Außerdem hat es keinen Effekt auf Hotkeys, die den Tastatur-Hook bereits von sich aus aktivieren, wie z.B. Tastatur-Hotkeys mit dem Präfix Tilde (~) oder Platzhalter (*), Taste-Oben-Hotkeys und benutzerdefinierte Kombinationen. Mit ListHotkeys können Sie prüfen, ob ein bestimmter Hotkey den Tastatur-Hook verwendet. #InputLevel und SendLevel bieten zusätzliche Kontrolle darüber, welche Hotkeys und Hotstrings durch die Send-Funktion ausgelöst werden können. |
| UP | Das UP-Wort muss nach dem Namen eines Hotkeys erfolgen und bewirkt, dass der Hotkey erst nach dem Loslassen der Taste ausgelöst wird, nicht sofort beim Drücken. Das folgende Beispiel zeigt, wie die linke Win-Taste zur linken Strg-Taste umbelegt werden kann: *LWin::Send "{LControl down}"
*LWin Up::Send "{LControl up}"
UP kann auch auf normale Hotkeys angewendet werden. Zum Beispiel: Einschränkungen: 1) UP funktioniert nicht bei Controllertasten; und 2) ein UP-Hotkey ohne entsprechenden Counterpart (normaler Hotkey oder DOWN-Hotkey) wird diese Taste komplett übernehmen, um zu verhindern, dass sie dauerhaft gedrückt bleibt. Um das zu verhindern, kann beispielsweise ein Tilde-Präfix hinzugefügt werden (z.B. UP-Hotkeys und ihre Counterparts (DOWN-Hotkeys, sofern vorhanden) verwenden immer den Tastatur-Hook. Beachten Sie auch, dass mit einer ähnlichen Methode wie der oben ein Hotkey zu einer Präfixtaste gemacht werden kann. Das hat den Vorteil, dass, obwohl der Hotkey nach dem Loslassen ausgelöst wird, er dies nur tut, wenn Sie keine andere Taste gedrückt haben, während Sie ihn gedrückt hielten. Zum Beispiel: LControl & F1::return ; Macht LControl zum Präfix, wenn es min. einmal vor "&" verwendet wird. LControl::MsgBox "Sie haben LControl ohne Modifikation einer anderen Taste losgelassen." |
Hinweis: Die Tastenliste enthält alle unterstützten Tastatur-, Maus- oder Controllertasten.
Mehrere Hotkeys können vertikal gestapelt werden, um ihnen die gleiche Aktion zuzuweisen. Zum Beispiel:
^Numpad0::
^Numpad1::
{
MsgBox "STRG+Numpad0 oder STRG+Numpad1 zeigt diese Meldung an."
}
Um eine Taste oder Tastenkombination systemweit zu deaktivieren, weisen Sie ihr eine Aktion zu, die nichts bewirkt. Das folgende Beispiel deaktiviert die rechte Win-Taste:
RWin::return
Die #HotIf-Direktive kann verwendet werden, um Hotkeys je nach Bedingung eine andere (oder gar keine) Aktion ausführen zu lassen. Zum Beispiel:
#HotIf WinActive("ahk_class Notepad")
^a::MsgBox "Sie haben STRG+A gedrückt, während Notepad aktiv war. Drückt man STRG+A in einem anderen Fenster, wird die Tastenkombination selbst gesendet."
#c::MsgBox "Sie haben WIN+C gedrückt, während Notepad aktiv war."
#HotIf
#c::MsgBox "Sie haben WIN+C gedrückt, während ein anderes Fenster als Notepad aktiv war."
#HotIf MausIstÜber("ahk_class Shell_TrayWnd") ; Für MausIstÜber, siehe #HotIf-Beispiel 1.
WheelUp::Send "{Volume_Up}" ; Mausrad über die Taskleiste: Lautstärke erhöhen/verringern.
WheelDown::Send "{Volume_Down}" ;
Normalerweise bestehen die Kombinationen von Tastaturkurzbefehlen aus optionalen Präfix-/Modifikatortasten (Strg, Alt, Umschalt und LWin/RWin) und einer einzelnen Suffixtaste. Da die regulären Modifikatortasten standardmäßig nur für diesen Zweck vorgesehen sind, haben sie keinen unmittelbaren Effekt, wenn sie gedrückt werden.
Um eine benutzerdefinierte Kombination von zwei Tasten (einschließlich der Maustasten, aber nicht der Controllertasten) zu definieren, fügen Sie " & " zwischen den Tasten ein. Da sie für die Nutzung mit Präfixtasten gedacht sind, die normalerweise nicht als solche verwendet werden, weisen benutzerdefinierte Kombinationen das folgende Sonderverhalten auf:
Hinweis: Bei Kombinationen mit regulären Modifikatortasten ist es in der Regel besser, die Standardsyntax zu verwenden. Verwenden Sie zum Beispiel <+s:: anstelle von LShift & s::.
Das folgende Beispiel zeigt, wie ein Hotkey ausgelöst werden kann, wenn Numpad0 gedrückt gehalten und danach eine zweite Taste gedrückt wird:
Numpad0 & Numpad1::MsgBox "Sie haben Numpad1 gedrückt, während Sie Numpad0 gedrückt hielten." Numpad0 & Numpad2::Run "Notepad"
Die Präfixtaste verliert ihre ursprüngliche Funktion: Im Beispiel oben wird Numpad0 zu einer Präfixtaste; dadurch verliert Numpad0 aber auch seine ursprüngliche Funktion beim Drücken. Um das zu vermeiden, können Sie das Skript so konfigurieren, dass Numpad0 eine neue Aktion durchführt, wie zum Beispiel:
Numpad0::WinMaximize "A" ; Maximiert das aktive/vorderste Fenster.
Numpad0::Send "{Numpad0}" ; Lässt Numpad0 einen Numpad0-Tastendruck nach dem Loslassen erzeugen. Siehe Kommentar unten.
Beim Loslassen auslösen: Das Vorhandensein einer der obigen benutzerdefinierten Kombinations-Hotkeys bewirkt, dass die gewünschte Aktion erst nach dem Loslassen von Numpad0 ausgeführt wird, aber nur, wenn Sie keine andere Taste gedrückt haben, während Sie Numpad0 gedrückt hielten. Dieses Verhalten lässt sich vermeiden, indem man auf beiden Hotkeys das Tilde-Präfix anwendet.
Modifikatoren: Im Gegensatz zu normalen Hotkeys verhalten sich benutzerdefinierte Kombinationen so, als hätten sie standardmäßig den Platzhalter-Modifikator (*). So wird z.B. 1 & 2:: auch dann ausgelöst, wenn beim Drücken von 1 und 2 der Modifikator Strg oder Alt gedrückt gehalten wird, während ^1:: nur durch Strg+1 und nicht durch Strg+Alt+1 ausgelöst werden würde.
Kombinationen aus drei oder mehr Tasten werden nicht unterstützt. Kombinationen, die von Ihrer Tastatur unterstützt werden, können in der Regel mit #HotIf und GetKeyState erkannt werden, aber das Ergebnis ist nicht immer konsistent. Zum Beispiel:
; Drücke AppsKey und Alt in beliebiger Reihenfolge, dann Bindestrich (-).
#HotIf GetKeyState("AppsKey", "P")
Alt & -::MsgBox "Hotkey aktiviert."
; Sind die Tasten vertauscht, zuerst Alt drücken (immer nur eine nutzen):
#HotIf GetKeyState("Alt", "P")
AppsKey & -::MsgBox "Hotkey aktiviert."
; , & . & -::
#HotIf GetKeyState(",") && GetKeyState(".")
-::MsgBox
Tastatur-Hook: Benutzerdefinierte Kombinationen, die Tastaturtasten enthalten, verwenden immer den Tastatur-Hook, ebenso wie alle Hotkeys, die die Präfixtaste als Suffix verwenden. Zum Beispiel würde a & b:: bewirken, dass ^a:: immer den Hook verwendet.
NUM-, FESTSTELL- und ROLLEN-Taste: Diese Tasten können gezwungen werden, "AlwaysOn" (immer an) oder "AlwaysOff" (immer aus) zu sein. Zum Beispiel: SetNumLockState "AlwaysOn".
Explorer-Hotkeys überschreiben: Die vordefinierten Windows-Hotkeys wie Win+E (#e) und Win+R (#r) können überschrieben werden, indem man ihnen eine Aktion im Skript zuweist. Einzelheiten finden Sie unter Überschreiben oder Deaktivieren von Hotkeys.
Alt-Tab ersetzen: Hotkeys können für das Alt-Tabbing verwendet werden. Zum Beispiel können Sie die folgenden zwei Hotkeys verwenden, um mit der rechten Hand das Alt-Tabben durchzuführen:
RControl & RShift::AltTab ; Halte STRG-RECHTS gedrückt und drücke mehrmals UMSCHALT-RECHTS, um vorwärts zu schalten. RControl & Enter::ShiftAltTab ; Halte STRG-RECHTS gedrückt und drücke ENTER für umgekehrte Richtung.
Weitere Informationen finden Sie unter Alt-Tab-Hotkeys.
Mit den Tastennamen WheelDown und WheelUp können Hotkeys erstellt werden, die beim Drehen des Mausrads ausgelöst werden. Hier einige Beispiele für Mausrad-Hotkeys:
MButton & WheelDown::MsgBox "Sie haben das Mausrad nach unten gedreht, während Sie die mittlere Maustaste gedrückt hielten." ^!WheelUp::MsgBox "Sie haben das Mausrad nach oben gedreht, während Sie STRG+ALT gedrückt hielten."
Wenn die Maus horizontales Scrollen unterstützt, kann dies über die Tastennamen WheelLeft und WheelRight erkannt werden. Einige Mäuse haben ein einzelnes Rad, das hoch und runter gedreht oder nach links und rechts gekippt werden kann. Grundsätzlich werden in solchen Fällen WheelLeft- oder WheelRight-Signale wiederholt gesendet, während das Rad seitlich gekippt wird, um ein kontinuierliches Drehen zu simulieren. Dies führt in der Regel dazu, dass die Hotkeys wiederholt ausgeführt werden.
Die interne Variable A_EventInfo enthält die Anzahl der Schritte, um die das Mausrad gedreht wurde (üblicherweise 120). Allerdings kann A_EventInfo größer oder kleiner als 120 sein, wenn folgende Bedingungen zutreffen:
~WheelDown::ToolTip A_EventInfoEinige der nützlichsten Hotkeys für das Mausrad sind alternative Modi zum Scrollen von Text in einem Fenster. Das folgende Hotkey-Paar beispielsweise scrollt horizontal statt vertikal, wenn Sie das Mausrad bei gedrückter linker Strg-Taste drehen:
~LControl & WheelUp:: ; Scrollt nach links.
{
Loop 2 ; <-- Erhöhe diesen Wert, um schneller zu scrollen.
SendMessage 0x0114, 0, 0, ControlGetFocus("A") ; 0x0114 ist WM_HSCROLL und die 0 danach SB_LINELEFT.
}
~LControl & WheelDown:: ; Scrollt nach rechts.
{
Loop 2 ; <-- Erhöhe diesen Wert, um schneller zu scrollen.
SendMessage 0x0114, 1, 0, ControlGetFocus("A") ; 0x0114 ist WM_HSCROLL und die 1 danach SB_LINERIGHT.
}
Da Mausrad-Hotkeys nur Down-Ereignisse (nie Up-Ereignisse) erzeugen, können sie nicht als Taste-Oben-Hotkeys verwendet werden.
Jede Ziffernblocktaste kann so geändert werden, dass sie je nach Status von Num zwei verschiedene Hotkey-Subroutinen startet. Alternativ kann eine Ziffernblocktaste so geändert werden, dass sie unabhängig vom Status die gleiche Subroutine startet. Zum Beispiel:
NumpadEnd::
Numpad1::
{
MsgBox "Dieser Hotkey wurde unabhängig von NUM ausgelöst."
}
Wenn das Tilde-Symbol (~) mindestens einmal mit einer Präfixtaste verwendet wird, ändert es das Verhalten dieser Präfixtaste bei allen Kombinationen. Bei beiden folgenden Hotkeys beispielsweise empfängt das aktive Fenster alle Rechtsklicks, obwohl nur eine der Definitionen eine Tilde enthält:
~RButton & LButton::MsgBox "Sie haben die linke Maustaste gedrückt, während Sie die rechte Maustaste gedrückt hielten." RButton & WheelUp::MsgBox "Sie haben das Mausrad nach oben gedreht, während Sie die rechte Maustaste gedrückt hielten."
Die Suspend-Funktion kann vorübergehend alle Hotkeys deaktivieren, außer denen, die Sie explizit ausgeschlossen haben. Für ein gezielteres Aktivieren/Deaktivieren von Hotkeys sollten Sie #HotIf verwenden.
Mit der Hotkey-Funktion können Hotkeys dynamisch erstellt werden, während das Skript läuft. Die Hotkey-Funktion kann zudem bereits existierende Hotkeys einzeln modifizieren, deaktivieren oder aktivieren.
Derzeit unterstützen Controller-Hotkeys keine Modifikatorsymbole wie ^ (Strg) und # (Win). Allerdings können Sie diesen Effekt mit GetKeyState nachahmen. Zum Beispiel:
Joy2::
{
if not GetKeyState("Control") ; Weder STRG-LINKS noch -RECHTS ist unten.
return ; Also nichts tun.
MsgBox "Sie haben die zweite Taste des ersten Controllers gedrückt, während Sie die STRG-Taste gedrückt hielten."
}
Manchmal sollte ein Hotkey auf das Loslassen seiner eigenen Modifikatortasten warten, ehe er fortfährt. Schauen Sie sich dazu das folgende Beispiel an:
^!s::Send "{Delete}"
Drückt man in diesem Fall Strg+Alt+S, würde das System fälschlicherweise ein Strg+Alt+Entf erkennen (aufgrund der aggressiven Erkennung dieser Tastenkombination). Um das zu umgehen, nutzen Sie KeyWait, um auf das Loslassen der Tasten zu warten. Zum Beispiel:
^!s::
{
KeyWait "Control"
KeyWait "Alt"
Send "{Delete}"
}
Wenn ein Hotkey wie #z:: den Fehler "Invalid Hotkey" (ungültiger Hotkey) erzeugt, kann es sein, dass die Tastaturbelegung/Sprache Ihres Systems das angegebene Zeichen (in diesem Fall "Z") nicht kennt. Versuchen Sie es mit einem Zeichen, das in Ihrer Tastaturbelegung existiert.
Die Funktion eines Hotkeys kann nur dann explizit vom Skript aufgerufen werden, wenn die Funktion benannt wurde. Siehe Benannte Funktions-Hotkeys.
Hotkeys werden häufig verwendet, um eine sich wiederholende Aktion (z.B. das Drücken mehrerer Tasten) zu starten und zu stoppen. Ein Beispiel dazu finden Sie unter Wie kann eine sich wiederholende Aktion gestoppt werden, ohne das Skript zu beenden?.
Jedes Skript ist quasi-multithreadingfähig; es ist also in der Lage, einen neuen Hotkey während einer laufenden Hotkey-Subroutine zu starten. Zum Beispiel können neue Hotkeys gestartet werden, obwohl der aktuelle Hotkey gerade ein Mitteilungsfenster anzeigt.
Alt-Tab-Hotkeys vereinfachen die Neubelegung der Alt-Tab-Hotkeys des Systems, die zum Aufrufen eines Menüs für den Wechsel von Anwendungen (Aktivieren von Fenstern) verwendet werden.
Jeder Alt-Tab-Hotkey muss entweder eine einzelne Taste oder eine Kombination aus zwei Tasten sein, was in der Regel durch das Und-Zeichen (&) erreicht wird. Das folgende Beispiel befähigt Sie, mit J oder K durch das Alt-Tab-Menü zu navigieren, während Sie die rechte Alt-Taste gedrückt halten:
RAlt & j::AltTab RAlt & k::ShiftAltTab
AltTab und ShiftAltTab gehören zu einer Reihe von Sonderbefehlen, die nur erkannt werden, wenn sie in derselben Zeile wie ein Hotkey verwendet werden. Hier die komplette Liste:
AltTab: Nach rechts navigieren im Alt-Tab-Menü, sofern offen. Andernfalls das Menü öffnen (nur wenn der Hotkey eine Kombination aus zwei Tasten ist, sonst passiert nichts).
ShiftAltTab: Dasselbe wie oben, aber nach links navigieren.
AltTabMenu: Das Alt-Tab-Menü anzeigen oder verstecken.
AltTabAndMenu: Nach rechts navigieren im Alt-Tab-Menü, sofern offen. Andernfalls das Menü öffnen.
AltTabMenuDismiss: Das Alt-Tab-Menü schließen.
Zur Veranschaulichung der obigen Sonderbefehle können Sie das Mausrad zu einem vollständigen Ersatz für Alt-Tab machen. Wenn die folgenden Hotkeys aktiv sind, können Sie das Menü durch Klicken der mittleren Maustaste öffnen und durch Drehen des Mausrads durch das Menü navigieren:
MButton::AltTabMenu WheelDown::AltTab WheelUp::ShiftAltTab
Um das Alt-Tab-Menü zu schließen, ohne das ausgewählte Fenster zu aktivieren, drücken oder senden Sie Esc. Das folgende Beispiel befähigt Sie, mit Feststell das Menü zu öffnen und nach rechts zu navigieren, während Sie die linke Strg-Taste gedrückt halten. Sie können dann die linke Strg-Taste wieder loslassen, um das ausgewählte Fenster zu aktivieren, oder das Mausrad drücken, um abzubrechen. Definieren Sie die AltTabFenster-Fenstergruppe wie unten gezeigt, bevor Sie dieses Beispiel ausführen.
LCtrl & CapsLock::AltTab
#HotIf WinExist("ahk_group AltTabFenster") ; Signalisiert, dass das Alt-Tab-Menü auf dem Bildschirm existiert.
*MButton::Send "{Blind}{Escape}" ; Mit dem *-Präfix kann es unabhängig von ALT ausgelöst werden.
#HotIf
Wenn das Skript {Alt Down} gesendet hat (um z.B. das Alt-Tab-Menü zu öffnen), muss eventuell noch {Alt Up} gesendet werden, wie im Beispiel weiter unten gezeigt.
Derzeit müssen alle speziellen Alt-Tab-Aktionen direkt einem Hotkey zugewiesen werden, wie in den Beispielen oben (d.h. sie können nicht als Funktionen verwendet werden). Sie werden nicht von #HotIf beeinflusst.
Eine Alt-Tab-Aktion kann unabhängig vom up-Schlüsselwort beim Drücken und/oder Loslassen der Taste erfolgen und kann nicht mit einer anderen Aktion auf derselben Taste kombiniert werden. Zum Beispiel wird die kombinierte Verwendung von F1::AltTabMenu und F1 up::AndereAktion() nicht unterstützt.
Benutzerdefinierte Alt-Tab-Aktionen können auch via Hotkeys erstellt werden. Da die Identität des Alt-Tab-Menüs je nach OS-Version unterschiedlich ist, empfiehlt es sich, eine Fenstergruppe zu verwenden, wie unten gezeigt. Bei den Beispielen oben und unten, die ahk_group AltTabFenster verwenden, wird davon ausgegangen, dass diese Fenstergruppe während der Startphase des Skripts definiert ist. Alternativ kann ahk_group AltTabFenster je nach System mit dem entsprechenden ahk_class-Kriterium ersetzt werden.
GroupAdd "AltTabFenster", "ahk_class MultitaskingViewFrame" ; Windows 10 GroupAdd "AltTabFenster", "ahk_class TaskSwitcherWnd" ; Windows Vista, 7, 8.1 GroupAdd "AltTabFenster", "ahk_class #32771" ; Älter, oder mit aktiviertem klassischen Alt-Tab
Das folgende Beispiel befähigt Sie, mit F1 das Menü zu öffnen und nach rechts zu navigieren. Sie können dann F2 drücken, um das ausgewählte Fenster zu aktivieren, oder Esc drücken, um abzubrechen.
*F1::Send "{Alt down}{tab}" ; Sternchen ist in diesem Fall notwendig.
!F2::Send "{Alt up}" ; ALT loslassen, um ausgewähltes Fenster zu aktivieren.
#HotIf WinExist("ahk_group AltTabFenster")
~*Esc::Send "{Alt up}" ; Beim Abbrechen des Menüs ALT automatisch loslassen.
;*Esc::Send "{Esc}{Alt up}" ; Ohne Tilde (~) müsste Escape gesendet werden.
#HotIf
Wenn die Funktion eines Hotkeys aufgerufen werden soll, ohne den Hotkey selbst auszulösen, können Sie einem oder mehreren Hotkeys eine benannte Funktion zuweisen, indem Sie diese einfach unterhalb des Doppelpunktpaares definieren. Zum Beispiel:
; STRG+UMSCHALT+O öffnet den Ordner der Datei im Explorer.
; STRG+UMSCHALT+E öffnet den Ordner der Datei und markiert sie.
; Unterstützt SciTE und Notepad++ (erfordert ggf. Titelleisteneinstellungen).
^+o::
^+e::
editor_ordner_öffnen(hk)
{
pfad := WinGetTitle("A")
if RegExMatch(pfad, "\*?\K(.*)\\[^\\]+(?= [-*] )", &pfad)
if (FileExist(pfad[0]) && hk = "^+e")
Run Format('explorer.exe /select,"{1}"', pfad[0])
else
Run Format('explorer.exe "{1}"', pfad[1])
}
Wenn die Funktion editor_ordner_öffnen explizit vom Skript aufgerufen wird, muss dem ersten Parameter (hk) ein Wert übergeben werden.
Hotstrings können auch auf diese Weise definiert werden. Mehrere Hotkeys oder Hotstrings können vertikal gestapelt werden, um die gleiche Funktion aufzurufen.
Zwischen dem Hotkey und dem Funktionsnamen dürfen nur Leerraumzeichen oder Kommentare stehen.
Die Benennung einer Funktion begünstigt auch die Selbstdokumentation von Hotkeys, wie im obigen Code, wo der Funktionsname den Hotkey beschreibt.
Mit der Hotkey-Funktion kann einem Hotkey auch eine Funktion oder ein Funktionsobjekt zugewiesen werden.