A_Clipboard

A_Clipboard ist eine interne Variable, die den aktuellen Inhalt der Windows-Zwischenablage enthält, sofern dieser Inhalt als Text ausgegeben werden kann.

Jede Textzeile in A_Clipboard endet normalerweise mit einem Wagenrücklauf-Zeilenvorschub-Paar (`r`n). Dateien (die z.B. mit Strg+C kopiert wurden) werden als Text betrachtet: Jedes Mal, wenn auf A_Clipboard zugegriffen wird, werden sie automatisch in ihre Dateinamen umgewandelt (mit vollständigem Pfad). Um die Dateien einzeln zu durchlaufen, gehen Sie wie folgt vor:

Loop Parse A_Clipboard, "`n", "`r"
{
    Ergebnis := MsgBox("Datei Nr. " A_Index " ist " A_LoopField ".`n`nWeiter?",, 4)
    if Ergebnis = "No"
        break
}

Mit der Sort-Funktion können die Dateinamen alphabetisch sortiert werden. Um die Dateinamen aus der Zwischenablage in eine Datei zu schreiben, verwenden Sie FileAppend A_Clipboard "`r`n", "C:\Meine Datei.txt". Mit #ClipboardTimeout können Sie festlegen, wie lange das Skript versuchen soll, die Zwischenablage zu öffnen (z.B. wenn die Zwischenablage von einer anderen Anwendung blockiert wird).

Mit ClipWait kann festgestellt werden, wann die Zwischenablage Daten enthält (optional auch Nicht-Text-Daten):

A_Clipboard := ""  ; Für ClipWait leer machen.
Send "^c"
ClipWait  ; Warten, bis die Zwischenablage Text enthält.
MsgBox "STRG+C hat den folgenden Inhalt in die Zwischenablage kopiert:`n`n" A_Clipboard

ClipboardAll: Um mit allem zu arbeiten, was sich in der Zwischenablage befindet, wie Bilder und Formatierungen.
OnClipboardChange: Um Änderungen in der Zwischenablage zu erkennen und darauf zu reagieren.

Beispiele

Ersetzt die Zwischenablage mit neuem Inhalt.

A_Clipboard := "mein Text"

Leert die Zwischenablage.

A_Clipboard := ""

Wandelt kopierte Dateien, HTML oder andere formatierte Texte in Klartext um.

A_Clipboard := A_Clipboard

Fügt etwas Text an die Zwischenablage an.

A_Clipboard .= " angefügter Text."

Ersetzt alle Vorkommen von ABC mit DEF (inkl. Umwandlung der Zwischenablage in Klartext).

A_Clipboard := StrReplace(A_Clipboard, "ABC", "DEF")

Zwischenablageprogramme, die mit AutoHotkey v1 programmiert wurden:

Deluxe Clipboard: Erlaubt eine unbegrenzte Anzahl von privaten, benannten Zwischenablagen, um einen markierten Text zu kopieren, auszuschneiden, einzufügen, anzuhängen oder auszuschneiden und anzuhängen.
ClipStep: Mehrere Zwischenablagen nur mit Strg+X/C/V kontrollieren.

A_Clipboard

Siehe auch

Beispiele