Else

Bestimmt eine oder mehrere Anweisungen, die ausgeführt werden, wenn der Körper der zugehörigen Anweisung nicht ausgeführt wurde.

Else Anweisung

Else
{
    Anweisungen
}

Bemerkungen

Jedes Else muss zu einem darüber liegenden If, Catch, For, Loop oder While gehören (mit ihm verbunden sein). Ein Else bezieht sich immer auf die nächstmögliche unbeanspruchte Anweisung über ihm, es sei denn, ein Block wurde verwendet, um dieses Verhalten zu ändern. Die Bedingung für die Ausführung einer Else-Anweisung hängt von der zugehörigen Anweisung ab:

If-Ausdruck: Die Auswertung des Ausdrucks ergab False.
For, Loop (beliebiger Art), While: Die Schleife hatte null Wiederholungen.
Loop Read: Wie oben, aber das Vorhandensein von Else verhindert auch, dass ein Fehler ausgelöst wird, wenn die Datei oder der Pfad nicht gefunden wurde. Entsprechend wird Else ausgeführt, wenn die Datei leer ist oder nicht existiert.
Try...Catch: Innerhalb des Try-Blocks wurde keine Ausnahme ausgelöst.

Unmittelbar nach einem Else kann eine beliebige andere Einzelanweisung folgen. Diese Methode wird häufig bei "else if"-Konstruktionen verwendet (siehe Beispiele unten).

Wenn ein Else mehr als eine Zeile hat, müssen diese Zeilen mit geschweiften Klammern umschlossen werden (um einen Block zu bilden). Hat ein Else jedoch nur eine Zeile, können die geschweiften Klammern weggelassen werden. Zum Beispiel:

if (Anzahl > 0)  ; Die nächste Zeile muss nicht mit geschweiften Klammern umschlossen werden, da es nur eine Zeile ist.
    MsgBox "Drücken Sie OK, um zu starten."
else  ; Der nächste Abschnitt muss mit geschweiften Klammern umschlossen werden, da es mehrere Zeilen sind.
{
    WinClose "Unbenannt - Editor"
    MsgBox "Es sind keine Elemente vorhanden."
}

Je nach Bedarf kann der One True Brace (OTB) Style bei einem Else verwendet werden. Zum Beispiel:

if IstFertig {
    ; ...
} else if (x < y) {
    ; ...
} else {
    ; ...
}

Blöcke, If, Kontrollanweisungen

Beispiele

Typische Verwendung einer Else-Anweisung. Dieses Beispiel wird wie folgt ausgeführt:

Wenn Notepad existiert:
1. Aktiviere es
2. Sende die Zeichenkette "Das ist ein Test." gefolgt von Enter.
Andernfalls (also wenn Notepad nicht existiert):
1. Aktiviere ein anderes Fenster
2. Linksklicke auf die Koordinaten 100, 200

if WinExist("Unbenannt - Editor")
{
    WinActivate
    Send "Das ist ein Test.{Enter}"
}
else
{
    WinActivate "Ein anderes Fenster"
    MouseClick "Left", 100, 200
}

Zeigt verschiedene Möglichkeiten, wie die Else-Anweisung verwendet werden kann.

if (x = 1)
    ersteFunktion()
else if (x = 2) ; "else if"-Stil
    zweiteFunktion()
else if x = 3
{
    dritteFunktion()
    Sleep 1
}
else Standardfunktion()  ; Einzelanweisungen können unmittelbar nach einem Else folgen.

Führt etwas Code aus, wenn eine Schleife null Wiederholungen hatte.

; Fenster/Tabs des Datei-/Internet-Explorers anzeigen.
for window in ComObject("Shell.Application").Windows
    MsgBox "Fenster Nr. " A_Index ": " window.LocationName
else
    MsgBox "Kein Shell-Fenster gefunden."

Else

Bemerkungen

Siehe auch

Beispiele