Hotstring - Syntax & Verwendung

Erstellt, modifiziert, aktiviert oder deaktiviert einen Hotstring, während das Skript läuft.

Parameter

Unterfunktionen

EndChars

Ermittelt oder modifiziert einen Satz von Zeichen, die vom Hotstring-Erkenner als Endungszeichen verwendet werden.

Es ist derzeit nicht möglich, für jeden Hotstring einen anderen Satz von Endungszeichen anzugeben.

MouseReset

Ermittelt oder modifiziert die globale Einstellung, die bestimmt, ob Mausklicks den Hotstring-Erkenner zurücksetzen dürfen, wie hier beschrieben.

NeuerWert sollte 1 (true) sein, um die Erkennung von Mausklicks und das Zurücksetzen des Hotstring-Erkenners zu aktivieren, oder 0 (false), um es zu deaktivieren. Der Rückgabewert ist die Einstellung, welche vor dem Aufruf der Funktion wirksam war.

Der Maus-Hook wird bei dieser Funktion je nach Bedarf automatisch installiert oder entfernt.

#Hotstring NoMouse wirkt sich auch auf diese Einstellung aus und entspricht der Angabe von False für NeuerWert.

Reset

Mit anderen Worten, das Skript wartet auf einen völlig neuen Hotstring und verwirft alles, was Sie zuvor eingegeben haben.

Fehlerbehandlung

Diese Funktion löst eine Ausnahme aus, wenn die Parameter ungültig sind oder eine Speicherreservierung fehlschlägt.

Es wird ein TargetError ausgelöst, wenn Ersatz weggelassen wird und Zkette gültig ist, aber nicht mit einem existierenden Hotstring übereinstimmt. Dies kann verwendet werden, um zu prüfen, ob ein Hotstring existiert. Zum Beispiel:

Bemerkungen

Wenn das Skript suspendiert ist und neue Hotstrings hinzugefügt oder aktiviert werden, werden diese ebenfalls suspendiert, bis die Suspension wieder aufgehoben wird (es sei denn, sie sind davor geschützt, wie im Suspend-Abschnitt beschrieben).

Die Tastatur- und/oder Maus-Hooks werden bei dieser Funktion je nach Bedarf automatisch installiert oder entfernt.

Diese Funktion kann Hotstrings anderer Skripte nicht direkt aktivieren oder deaktivieren.

Sobald ein Skript mindestens einen Hotstring hat, wird es persistent; das heißt, dass ExitApp anstelle von Exit verwendet werden sollte, um dieses Skript zu terminieren.

Hotstring-Varianten (-Duplikate)

Ein bestimmter Hotstring kann mehr als einmal erstellt werden, wenn für jede Definition ein anderes HotIf-Kriterium, eine andere Groß-/Kleinschreibung-Sensitivität (C vs. C0/C1) oder Wort-Sensitivität (?) angegeben wird. Diese werden als Hotstring-Varianten bezeichnet. Zum Beispiel:

Wenn mehr als eine Variante eines Hotstrings zum Auslösen geeignet ist, wird nur die zuerst erstellte Variante ausgelöst.

Siehe auch

Beispiele

Hotstring Helper. Das folgende Skript könnte nützlich sein, wenn Sie viel mit Hotstrings arbeiten. Es basiert auf dem v1-Skript von Andreas Borutta. Drücken Sie Win+H (oder einen anderen Hotkey Ihrer Wahl), um den aktuell markierten Text zu einem Hotstring zu machen. Wenn Sie z.B. in einem Textverarbeitungsprogramm "beziehungsweise" markieren und Win+H drücken, wird das Skript Sie auffordern, eine Abkürzung für diesen Text einzugeben (z.B. bzw), und dann den neuen Hotstring in das Skript einfügen und aktivieren.

#h::  ; Hotkey: WIN+H
{
    ; Ruft den aktuell markierten Text ab. Es wird die Zwischenablage statt
    ; EditGetSelectedText verwendet, um das Skript für mehr Texteditoren
    ; funktionsfähig zu machen. Speichert die aktuelle Zwischenablage und
    ; stellt sie später wieder her (allerdings funktioniert das nur mit
    ; reinem Text):
    ClipboardAlt := A_Clipboard
    A_Clipboard := "" ; Muss vorerst leer sein, damit die Erkennung funktioniert.
    Send "^c"
    if !ClipWait(1)  ; ClipWait hat das Zeitlimit überschritten.
    {
        A_Clipboard := ClipboardAlt ; Den vorherigen Inhalt der Zwischenablage vor dem Return wiederherstellen.
        return
    }
    ; Ersetze CRLF und/oder LF mit `n für einen Hotstring im Raw-Modus:
    ; Dasselbe wird für jedes andere Zeichen getan,
    ; das ein Problem im Raw-Modus sein könnte:
    ClipInhalt := StrReplace(A_Clipboard, "``", "````")  ; Zuerst diese Ersetzung, um die darunter nicht zu stören.
    ClipInhalt := StrReplace(ClipInhalt, "`r`n", "``n")
    ClipInhalt := StrReplace(ClipInhalt, "`n", "``n")
    ClipInhalt := StrReplace(ClipInhalt, "`t", "``t")
    ClipInhalt := StrReplace(ClipInhalt, "`;", "```;")
    A_Clipboard := ClipboardAlt  ; Den vorherigen Inhalt der Zwischenablage wiederherstellen.
    ZeigeInputBox(":T:`::" ClipInhalt)
}

ZeigeInputBox(Standardwert)
{
    ; Den Textcursor des Eingabefensters auf eine benutzerfreundliche Position verschieben:
    SetTimer VerschiebeTextcursor, 10
    ; Das Eingabefenster mit dem vordefinierten Hotstring anzeigen:
    IB := InputBox("
    (
    Fügen Sie Ihre Abkürzung an der Position des Textcursors ein. Bei Bedarf können Sie den Ersatztext noch ändern.

    Beispieleintrag: :T:bzw`::beziehungsweise
    )", "Neuer Hotstring",, Standardwert)
    if IB.Result = "Cancel"  ; Der Benutzer hat Abbrechen gedrückt.
        return

    if RegExMatch(IB.Value, "(?P<Label>:.*?:(?P<Abkuerzung>.*?))::(?P<Ersatztext>.*)", &Eingabe)
    {
        if !Eingabe.Abkuerzung
            Mitteilung := "Sie haben keine Abkürzung angegeben"
        else if !Eingabe.Ersatztext
            Mitteilung := "Sie haben keinen Ersatztext angegeben"
        else
        {
            Hotstring Eingabe.Label, Eingabe.Ersatztext  ; Aktiviert jetzt den Hotstring.
            FileAppend "`n" IB.Value, A_ScriptFullPath  ; Speichert den Hotstring für den späteren Gebrauch.
        }
    }
    else
        Mitteilung := "Der Hotstring scheint falsch strukturiert zu sein"

    if IsSet(Mitteilung)
    {
        Ergebnis := MsgBox(Mitteilung ". Möchten Sie es noch einmal versuchen?",, 4)
        if Ergebnis = "Yes"
            ZeigeInputBox(Standardwert)
    }
    
    VerschiebeTextcursor()
    {
        WinWait "Neuer Hotstring"
        ; Andernfalls den Textcursor des Eingabefensters auf eine Position verschieben, wo der Benutzer die Abkürzung eintragen kann.
        Send "{Home}{Right 3}"
        SetTimer , 0
    }
}