InputBox

Zeigt ein Eingabefenster an, das den Benutzer zur Eingabe einer Zeichenkette auffordert.

InputBoxObj := InputBox(Anzeigetext, Titel, Optionen, Standardwert)

Parameter

Anzeigetext

Typ: Zeichenkette

Wenn leer oder weggelassen, wird standardmäßig kein Text verwendet. Andernfalls geben Sie einen Text an, der in der Regel dem Benutzer mitteilt, welche Art von Eingabe erwartet wird. Wenn Anzeigetext relativ lang ist, kann es via Fortsetzungsbereich in mehrere kurze Zeilen aufgeteilt werden, um die Übersichtlichkeit und Wartbarkeit des Skripts zu verbessern.

Titel

Typ: Zeichenkette

Wenn weggelassen, wird standardmäßig der aktuelle Wert von A_ScriptName verwendet. Andernfalls geben Sie den Titel des Eingabefensters an.

Optionen

Typ: Zeichenkette

Wenn leer oder weggelassen, wird das Eingabefenster horizontal und vertikal auf dem Bildschirm zentriert, mit einer Standardgröße von etwa 380x200 Pixeln, abhängig von der Version und dem Design des Betriebssystems. Andernfalls geben Sie eine Zeichenkette an, die aus einer oder mehreren der folgenden Optionen besteht, jeweils getrennt durch ein Leer- oder Tabulatorzeichen:

Xn und Yn: Die X- und Y-Koordinate des Dialogfensters. Zum Beispiel bewirkt x0 y0, dass das Fenster in der oberen linken Ecke des Desktops platziert wird. Wenn eine dieser Koordinaten weggelassen wird, wird das Fenster in dieser Dimension zentriert. Jede Koordinate kann negativ sein, um das Dialogfenster teilweise oder vollständig außerhalb des Desktops (oder auf dem sekundären Bildschirm in einer Multi-Bildschirm-Konfiguration) zu positionieren.

Wn und Hn: Die Breite und Höhe des Clientbereichs des Dialogfensters (das ist der Bereich ohne Titelleiste und Rahmen). Zum Beispiel w200 h100.

Tn: Gibt das Zeitlimit in Sekunden an. Zum Beispiel bewirkt T10.0 ein Zeitlimit von zehn Sekunden. Wenn ein Zeitlimit höher als 2147483 (24,8 Tage) angegeben ist, wird es automatisch auf 2147483 zurückgesetzt. Nach Ablauf des Zeitlimits wird das Eingabefenster automatisch geschlossen und InputBoxObj.Result auf das Wort Timeout gesetzt. InputBoxObj.Value enthält die Zeichenkette, die der Benutzer währenddessen eingegeben hat.

Password: Maskiert die Benutzereingabe (z.B. für eine Passworteingabe), d.h. alle Zeichen, die der Benutzer einträgt, werden mit einem Maskierungszeichen ersetzt. Wenn Sie ein anderes Maskierungszeichen benötigen, geben Sie es direkt nach dem Wort Password an. Zum Beispiel bewirkt Password*, dass das Sternchen als Maskierungszeichen verwendet wird, nicht der ausgefüllte Kreis.

Standardwert

Typ: Zeichenkette

Wenn leer oder weggelassen, wird standardmäßig keine Zeichenkette verwendet. Andernfalls geben Sie eine Zeichenkette an, die im Eingabefeld des Eingabefensters erscheint, wenn das Fenster zum ersten Mal angezeigt wird. Der Benutzer kann die Zeichenkette z.B. durch Backspacing (wiederholtes Löschen des letzten Zeichens) ändern.

Rückgabewert

Typ: Objekt

Diese Funktion gibt ein Objekt mit den folgenden Eigenschaften zurück:

Bemerkungen

Ein typisches Eingabefenster sieht wie folgt aus:

InputBox

Das Dialogfenster ermöglicht dem Benutzer, einen beliebigen Text einzugeben und dann OK oder CANCEL (Abbrechen) zu drücken. Der Benutzer kann die Größe des Dialogfensters durch Ziehen des Rahmens ändern.

Ein GUI-Fenster kann mit der OwnDialogs-Option ein modales Eingabefenster anzeigen. Ein modales Eingabefenster hindert den Benutzer daran, mit dem GUI-Fenster zu interagieren, bis er das Eingabefenster wieder schließt.

Gui-Objekt, MsgBox, FileSelect, DirSelect, ToolTip, InputHook

Beispiele

Lässt den Benutzer ein verstecktes Passwort eingeben.

Passwort := InputBox("(Ihre Eingabe wird versteckt)", "Bitte Passwort eingeben", "password").Value

Lässt den Benutzer eine Telefonnummer eingeben.

IB := InputBox("Bitte geben Sie eine Telefonnummer ein.", "Telefonnummer", "w640 h480")
if IB.Result = "Cancel"
    MsgBox "Sie haben '" IB.Value "' eingegeben, aber dann auf Abbrechen gedrückt."
else
    MsgBox "Sie haben '" IB.Value "' eingegeben."