MouseGetPos

Ruft die aktuelle Position des Mauszeigers ab, und optional das Fenster oder Steuerelement, über dem sich der Mauszeiger befindet.

MouseGetPos &AusgabeVarX, &AusgabeVarY, &AusgabeVarFenster, &AusgabeVarStrlmnt, Flag

Parameter

&AusgabeVarX, &AusgabeVarY

Typ: VarRef

Wenn weggelassen, wird der zugehörige Wert nicht gespeichert. Andernfalls geben Sie Referenzen an, die auf Ausgabevariablen verweisen, in denen die X- und Y-Koordinate gespeichert werden sollen. Standardmäßig sind die abgerufenen Koordinaten relativ zum Clientbereich des aktiven Fensters. Mit CoordMode können die Koordinaten relativ zum Bildschirm gemacht werden.

&AusgabeVarFenster

Typ: VarRef

Wenn weggelassen, wird der zugehörige Wert nicht gespeichert. Andernfalls geben Sie eine Referenz an, die auf eine Ausgabevariable verweist, in der die eindeutige ID (HWND) des Fensters unter dem Mauszeiger gespeichert werden soll. Wenn das Fenster nicht ermittelt werden kann, wird diese Variable leer gemacht.

Das Fenster muss nicht aktiv sein, um erkannt zu werden. Versteckte Fenster können nicht erkannt werden.

&AusgabeVarStrlmnt

Typ: VarRef

Wenn weggelassen, wird der zugehörige Wert nicht gespeichert. Andernfalls geben Sie Referenzen an, die auf Ausgabevariablen verweisen, in der die ClassNN des Steuerelements unter dem Mauszeiger gespeichert werden soll. Wenn das Steuerelement nicht ermittelt werden kann, wird diese Variable leer gemacht.

Das Fenster des Steuerelements unter dem Mauszeiger muss nicht aktiv sein, um erkannt zu werden.

Flag

Typ: Integer

Wenn weggelassen, wird standardmäßig 0 verwendet, d.h. es wird die Standardmethode zum Ermitteln von AusgabeVarStrlmnt verwendet und die ClassNN des Steuerelements abgerufen. Andernfalls geben Sie eine Kombination (Summe) der folgenden Zahlen an:

1: Verwendet eine einfachere Methode zum Ermitteln von AusgabeVarStrlmnt. Diese Methode ermittelt korrekt das aktive/oberste untergeordnete Fenster einer MDI-Anwendung (Multiple Document Interface) wie SysEdit oder TextPad. Allerdings ist sie für andere Zwecke, wie z.B. die Erkennung von Steuerelementen innerhalb eines GroupBox-Steuerelements, weniger genau.

2: Speichert das HWND des Steuerelements in AusgabeVarStrlmnt, nicht dessen ClassNN.

Zum Beispiel können Sie den Flag-Parameter auf 3 setzen, um beide Optionen zu aktivieren.

Bemerkungen

Wenn bestimmte Informationen nicht benötigt werden, können die entsprechenden Ausgabevariablen weggelassen werden.

Auf Systemen mit mehreren Bildschirmen, die unterschiedliche DPI-Einstellungen haben, kann die zurückgegebene Position aufgrund der OS-DPI-Skalierung anders als erwartet ausfallen.

CoordMode, Win-Funktionen, SetDefaultMouseSpeed, Click

Beispiele

Meldet die Position des Mauszeigers.

MouseGetPos &xpos, &ypos 
MsgBox "Der Zeiger befindet sich auf X" xpos " Y" ypos

Zeigt das HWND, den Klassennamen, den Titel und die Steuerelemente des Fensters an, das sich gerade unter dem Mauszeiger befindet.

SetTimer ZeigerÜberwachen, 100

ZeigerÜberwachen()
{
    MouseGetPos , , &ID, &Strlmnt
    ToolTip
    (
        "ahk_id " ID "
        ahk_class " WinGetClass(ID) "
        " WinGetTitle(ID) "
        Steuerelement: " Strlmnt
    )
}