Formatiert eine beliebige Anzahl von Eingabewerten gemäß einer Formatzeichenkette.
Zkette := Format(FormatZkette , Werte...)
Typ: Zeichenkette
Eine Formatzeichenkette, bestehend aus direkt geschriebenem Text und Platzhaltern, im Format {Index:Format}.
Index ist ein Integer, der angibt, welcher Eingabewert verwendet werden soll. 1 ist der erste Wert, 2 der zweite usw.
Format ist eine optionale Formatspezifikation, wie unten beschrieben.
Lassen Sie die Indexnummer weg, um den nächsten Eingabewert in der Sequenz zu verwenden (selbst wenn die Indexnummer bereits zuvor in der Zeichenkette verwendet wurde). Zum Beispiel formatiert "{2:i} {:i}" den zweiten und dritten Eingabewert als dezimale Integer, getrennt durch ein Leerzeichen. Wenn Index weggelassen wird, muss Format weiterhin mit : beginnen. Geben Sie leere geschweifte Klammern an, um den nächsten Eingabewert mit Standardformatierung zu verwenden: {}
Mit {{} und {}} können direkt geschriebene geschweifte Klammern in die Zeichenkette eingefügt werden. Alle anderen ungültigen Platzhalter werden unverändert in das Ergebnis eingefügt.
Leerraumzeichen innerhalb der geschweiften Klammern sind nicht erlaubt (nur als Flag).
Typ: Zeichenkette, Integer oder Float
Eingabewerte, die formatiert und in die finale Zeichenkette eingefügt werden sollen. Jeder Wert ist ein einzelner Parameter. Der erste Wert hat die Indexnummer 1.
Mit einem variadischen Funktionsaufruf kann ein Array von Werten übergeben werden:
arr := [13, 240]
MsgBox Format("{2:x}{1:02x}", arr*)
Typ: Zeichenkette
Diese Funktion gibt die formatierte Version der angegebenen Zeichenkette zurück.
Jede Formatspezifikation kann die folgenden Komponenten enthalten (in genau dieser Reihenfolge, ohne Leerzeichen):
Flags Breite .Genauigkeit ULT Typ
Flags: Beliebig viele Flags aus der Flag-Tabelle unten, um Präfix und Ausrichtung der Ausgabe zu beeinflussen.
Breite: Ein dezimaler Integer, der die Mindestbreite des formatierten Wertes bestimmt (in Zeichen). Standardmäßig werden Werte rechtsbündig gemacht und Leerzeichen zum Auffüllen verwendet. Diese Standardeinstellung kann mit den Flags - (linksbündig) und 0 (Null-Präfix) überschrieben werden.
.Genauigkeit: Ein dezimaler Integer, der je nach Ausgabetyp die maximale Anzahl von Zeichen, Dezimalstellen oder signifikanten Stellen festlegt. Es muss ein Dezimalpunkt davor sein. Die Angabe einer Genauigkeit kann dazu führen, dass der Wert gekürzt oder gerundet wird. Die folgende Auflistung zeigt, wie sich der Genauigkeitswert auf bestimmte Ausgabetypen auswirkt (eine Erklärung zu jedem Ausgabetyp finden Sie in der unteren Tabelle):
f, e, E: Genauigkeit bestimmt die Ziffernanzahl nach dem Dezimalpunkt. Standardmäßig 6.g, G: Genauigkeit bestimmt die maximale Anzahl signifikanter Stellen. Standardmäßig 6.s: Genauigkeit bestimmt die maximale Anzahl von Zeichen, die angezeigt werden. Überschüssige Zeichen werden nicht angezeigt.d, i, u, x, X, o) verhält sich Genauigkeit wie Breite mit 0-Präfix und einem Standardwert von 1.ULT: Ändert die Groß-/Kleinschreibung eines Zeichenkettenwertes -- Upper (groß), Lower (klein) oder Title (Anfangsbuchstabe groß). Nur in Verbindung mit s gültig. Zum Beispiel {:U} oder {:.20Ts}. Die Kleinbuchstaben l und t werden ebenfalls unterstützt, aber u ist für vorzeichenlose Integer reserviert.
Typ: Ein Zeichen aus der Typentabelle unten, das angibt, wie der Eingabewert interpretiert werden soll. Wenn weggelassen, wird standardmäßig s verwendet.
| Flag | Bedeutung |
|---|---|
- |
Macht das Ergebnis innerhalb der angegebenen Feldbreite linksbündig (und füllt die rechte Seite mit Leerzeichen, falls nötig). Zum Beispiel: Wenn weggelassen, wird das Ergebnis innerhalb der vorgegebenen Feldbreite rechtsbündig gemacht. |
+ |
Setzt ein Vorzeichen (+ oder -) vor einem vorzeichenfähigen Ausgabewert. Zum Beispiel: Wenn weggelassen, erscheint das Vorzeichen nur bei negativen vorzeichenfähigen Werten (-). |
0 |
Wenn Breite mit einer 0 beginnt, werden solange Nullen auf der linken Seite hinzugefügt, bis die Mindestbreite erreicht wurde. Zum Beispiel: Wenn weggelassen, wird der Wert nicht mit Nullen gefüllt. |
|
Verwenden Sie ein Leerzeichen, um dem Ausgabewert ein einzelnes Leerzeichen voranzustellen, wenn der Wert vorzeichenfähig und positiv ist. Das Leerzeichen wird ignoriert, wenn sowohl das Wenn weggelassen, erscheint kein Leerzeichen. |
# |
Wenn dieses Flag mit dem o-, x- oder X-Format verwendet wird, beginnt ein Ausgabewert ungleich 0 mit Wenn dieses Flag mit dem e-, E-, f-, a- oder A-Format verwendet wird, enthält der Ausgabewert immer einen Dezimalpunkt. Zum Beispiel: Wenn dieses Flag mit dem g- oder G-Format verwendet wird, enthält der Ausgabewert immer einen Dezimalpunkt, und es werden keine Nullen am Ende entfernt. Wenn dieses Flag mit dem c-, d-, i-, u- oder s-Format verwendet wird, wird es ignoriert. |
| Typzeichen | Argument | Ausgabeformat |
|---|---|---|
d oder i |
Integer | Vorzeichenfähiger dezimaler Integer. Zum Beispiel: Format("{:d}", 1.23) gibt 1 zurück. |
u |
Integer | Vorzeichenloser dezimaler Integer. |
x oder X |
Integer | Vorzeichenloser hexadezimaler Integer; ein kleines x bewirkt, dass die Hexadezimalzeichen kleingeschrieben werden. Das 0x-Präfix ist nur enthalten, wenn das #-Flag vorhanden ist, wie in {:#x}. Mit 0x{:x} o.ä. kann immer das Präfix hinzugefügt werden. Zum Beispiel: Format("{:X}", 255) gibt FF zurück. |
o |
Integer | Vorzeichenloser oktaler Integer. Zum Beispiel: Format("{:o}", 255) gibt 377 zurück. |
f |
Floating-Point | Vorzeichenfähiger Wert im Format [ - ]dddd.dddd, wobei dddd eine oder mehrere Dezimalziffern sind. Die Ziffernanzahl vor dem Dezimalpunkt hängt von der Größe der Zahl ab, während die Ziffernanzahl nach dem Dezimalpunkt von der gewünschten Genauigkeit abhängt. Zum Beispiel: Format("{:.2f}", 1) gibt 1.00 zurück. |
e |
Floating-Point | Vorzeichenfähiger Wert im Format [ - ]d.dddd e [Vorzeichen]dd[d], wobei d eine Dezimalziffer ist, dddd eine oder mehrere Dezimalziffern sind, dd[d] zwei oder drei Dezimalziffern je nach Ausgabeformat und Größe des Exponenten sind und Vorzeichen + oder - ist. Zum Beispiel: Format("{:e}", 255) gibt 2.550000e+02 zurück. |
E |
Floating-Point | Wie das e-Format, außer dass der Exponent mit E statt e beginnt. |
g |
Floating-Point | Vorzeichenfähige Werte werden im f- oder e-Format angezeigt, je nachdem, welches Format den Wert und die Genauigkeit kompakter darstellen kann. Das e-Format wird nur verwendet, wenn der Exponent des Wertes kleiner als -4 oder größer gleich Genauigkeit ist. Nullen am Ende werden entfernt; der Dezimalpunkt ist nur enthalten, wenn Dezimalstellen vorhanden sind. |
G |
Floating-Point | Wie das g-Format, außer dass der Exponent ggf. mit E statt e beginnt. |
a |
Floating-Point | Vorzeichenfähiger hexadezimaler Floating-Point-Wert mit doppelter Genauigkeit im Format [?]0xh.hhhh p±dd, wobei h.hhhh die Hexadezimalziffern (unter Nutzung von Kleinbuchstaben) der Mantisse und dd eine oder mehrere Ziffern für den Exponenten sind. Die Genauigkeit bestimmt die Ziffernanzahl nach dem Punkt. Zum Beispiel: Format("{:a}", 255) gibt 0x1.fe00000000000p+7 zurück. |
A |
Floating-Point | Wie das a-Format, außer dass der Exponent mit P statt p beginnt. |
p |
Integer | Zeigt das Argument als Speicheradresse in Hexadezimalziffern an. Zum Beispiel: Format("{:p}", 255) gibt 00000000000000FF zurück. |
s |
Zeichenkette | Gibt eine Zeichenkette an. Wenn der Eingabewert numerisch ist, wird er automatisch in eine Zeichenkette umgewandelt, bevor die Argumente Breite und Genauigkeit angewendet werden. |
c |
Zeichencode | Gibt ein einzelnes Zeichen über seinen Ordinalwert an, ähnlich wie Chr(n). Wenn der Eingabewert außerhalb des erwarteten Bereichs liegt, wird er umgekehrt. Zum Beispiel: Format("{:c}", 116) gibt t zurück. |
Größenspezifikationen wie bei printf werden nicht unterstützt. Alle Integer und Floating-Point-Eingabewerte sind 64-Bit.
Zeigt verschiedene Verwendungsmöglichkeiten.
s := ""
; Einfache Substitution
s .= Format("{2}, {1}!`r`n", "Welt", "Hallo")
; Mit Leerzeichen füllen
s .= Format("|{:-10}|`r`n|{:10}|`r`n", "Links", "Rechts")
; Hexadezimal
s .= Format("{1:#x} {2:X} 0x{3:x}`r`n", 3735928559, 195948557, 0)
; Floating-Point
s .= Format("{1:0.3f} {1:.10f}", 4*ATan(1))
ListVars ; Hauptfenster des Skripts zum Anzeigen gleichbreiter Zeichen nutzen.
WinWaitActive "ahk_class AutoHotkey"
ControlSetText(s, "Edit1")
WinWaitClose