FormatTime

Transformiert einen YYYYMMDDHH24MISS-Zeitstempel in ein bestimmtes Datums-/Zeitformat.

Zkette := FormatTime(YYYYMMDDHH24MISS, Format)

Parameter

YYYYMMDDHH24MISS

Typ: Zeichenkette

Wenn leer oder weggelassen, wird standardmäßig die aktuelle Ortszeit verwendet. Andernfalls können Sie den kompletten oder beginnenden Teil eines Zeitstempels im YYYYMMDDHH24MISS-Format angeben.

Format

Typ: Zeichenkette

Wenn leer oder weggelassen, wird standardmäßig die Zeit gefolgt vom langen Datum verwendet, wobei beide entsprechend der aktuellen Sprach- und Regionseinstellungen des Benutzers formatiert werden. Zum Beispiel: 10:24 Freitag, 30. April 2010

Andernfalls geben Sie ein oder mehrere Datums-/Zeitformate aus den unteren Tabellen an, mit beliebig vielen, direkt geschriebenen Leer- und Satzzeichen dazwischen (Kommas müssen nicht mit einem Escapezeichen versehen werden; sie können normal verwendet werden). Beachten Sie im folgenden Beispiel, dass das M großgeschrieben werden muss: d.M.yyyy h:mm:tt

Rückgabewert

Typ: Zeichenkette

Diese Funktion gibt die transformierte Version des angegebenen Zeitstempels zurück.

Wenn YYYYMMDDHH24MISS eine ungültige Datums- (YYYYMMDD) und/oder Zeitkomponente (HH24MISS) enthält (z.B. der 29. Februar eines Nicht-Schaltjahrs), wird das Datum und/oder die Zeit im Rückgabewert weggelassen. Obwohl nur Jahre zwischen 1601 und 9999 unterstützt werden, kann eine formatierte Zeit auch für die Jahre vor 1601 erzeugt werden, solange die Zeitkomponente gültig ist.

Wenn Format mehr als 2000 Zeichen enthält, wird eine leere Zeichenkette zurückgegeben.

Datumsformate (Groß-/Kleinschreibung-sensitiv)

Format	Beschreibung
d	Tag des Monats ohne Null am Anfang (1 – 31)
dd	Tag des Monats mit einer Null am Anfang (01 – 31)
ddd	Kurzschreibweise des Wochentags (z.B. Mo) in der Sprache des aktuellen Benutzers
dddd	Vollständiger Name des Wochentags (z.B. Montag) in der Sprache des aktuellen Benutzers
M	Monat ohne Null am Anfang (1 – 12)
MM	Monat mit einer Null am Anfang (01 – 12)
MMM	Kurzschreibweise des Monats (z.B. Jan) in der Sprache des aktuellen Benutzers
MMMM	Vollständiger Name des Monats (z.B. Januar) in der Sprache des aktuellen Benutzers
y	Jahr ohne Jahrhundert, ohne Null am Anfang (0 – 99)
yy	Jahr ohne Jahrhundert, mit einer Null am Anfang (00 – 99)
yyyy	Jahr mit Jahrhundert. Zum Beispiel: 2005
gg	Zeitrechnung/Ära gemäß den aktuellen Sprach- und Regionseinstellungen des Benutzers (z.B. n. Chr.)

Zeitformate (Groß-/Kleinschreibung-sensitiv)

Format	Beschreibung
h	Stunde ohne Null am Anfang; 12-Stunden-Format (1 – 12)
hh	Stunde mit einer Null am Anfang; 12-Stunden-Format (01 – 12)
H	Stunde ohne Null am Anfang; 24-Stunden-Format (0 – 23)
HH	Stunde mit einer Null am Anfang; 24-Stunden-Format (00 – 23)
m	Minute ohne Null am Anfang (0 – 59)
mm	Minute mit einer Null am Anfang (00 – 59)
s	Sekunde ohne Null am Anfang (0 – 59)
ss	Sekunde mit einer Null am Anfang (00 – 59)
t	Einzelzeichen-Zeitmarker wie A oder P (abhängig von den aktuellen Sprach- und Regionseinstellungen)
tt	Mehrfachzeichen-Zeitmarker wie AM oder PM (abhängig von den aktuellen Sprach- und Regionseinstellungen)

Alleinstehende Formate

Die folgenden Formate sind alleinstehend, d.h. es dürfen keine anderen Formate oder Texte im Format-Parameter angegeben werden. Diese Formate sind nicht Groß-/Kleinschreibung-sensitiv.

Format	Beschreibung
(Leer)	Lassen Sie Format leer, um die Zeit gefolgt vom langen Datum zu erzeugen. Zum Beispiel: 10:24 Freitag, 30. April 2010
Time	Die Uhrzeit gemäß den aktuellen Sprach- und Regionseinstellungen des Benutzers, z.B. 12:04
ShortDate	Das kurze Datum gemäß den aktuellen Sprach- und Regionseinstellungen des Benutzers, z.B. 30.04.2010
LongDate	Das lange Datum gemäß den aktuellen Sprach- und Regionseinstellungen des Benutzers, z.B. Freitag, 30. April 2010
YearMonth	Monat und Jahr gemäß den aktuellen Sprach- und Regionseinstellungen des Benutzers, z.B. April 2010
YDay	Tag des Jahres ohne Nullen am Anfang (1 - 366)
YDay0	Tag des Jahres mit Nullen am Anfang (001 - 366)
WDay	Wochentag (1 - 7). Sonntag ist 1.
YWeek	Vollständiges Jahr und Kalenderwoche gemäß ISO 8601. Zum Beispiel: 200453. Wenn die Woche mit dem 1. Januar mindestens vier Tage im neuen Jahr hat, ist sie Woche 1. Andernfalls ist sie die letzte Woche des Vorjahres und die nächste Woche die erste Woche des neuen Jahres. Folglich sind sowohl der 4. Januar als auch der erste Donnerstag im Januar immer in Woche 1.

Zusätzliche Optionen

Die folgenden Optionen können im YYYYMMDDHH24MISS-Parameter direkt nach dem Zeitstempel angegeben werden (wenn kein Zeitstempel vorhanden ist, können diese Optionen auch allein stehen). Beachten Sie im folgenden Beispiel, dass zwischen den letzten vier Elementen keine Kommas stehen:

AusgabeVar := FormatTime("20040228 LSys D1 D4")

R: Umkehren. Zeigt das Datum vor der Zeit an (nur sinnvoll, wenn Format leer ist).

Ln: Wenn diese Option nicht vorhanden ist, werden die aktuellen Sprach- und Regionseinstellungen des Benutzers für die Formatierung der Zeichenkette verwendet. Geben Sie LSys an, um stattdessen die Sprach- und Regionseinstellungen des Systems zu verwenden. Für andere Sprach- und Regionseinstellungen können Sie den Buchstaben L gefolgt von einem dezimalen oder hexadezimalen Locale-Identifikator (LCID) angeben. Informationen darüber, wie sich ein LCID zusammensetzt, finden Sie unter www.microsoft.com mit folgendem Suchbegriff: Locale Identifiers

Dn: Datumsoptionen. Geben Sie für n eine der folgenden Zahlen an:

0 = Erzwingt die Verwendung der Standardoptionen. Dadurch wird auch das kurze Datum wirksam.
1 = Verwendet das kurze Datum (nur sinnvoll, wenn Format leer ist; nicht kompatibel mit 2 und 8).
2 = Verwendet das lange Datum (nur sinnvoll, wenn Format leer ist; nicht kompatibel mit 1 und 8).
4 = Verwendet einen alternativen Kalender (falls vorhanden).
8 = Verwendet das Jahr-Monat-Format (nur sinnvoll, wenn Format leer ist; nicht kompatibel mit 1 und 2).
0x10 = Fügt Markierungen für ein Links-nach-Rechts-Leselayout hinzu.
0x20 = Fügt Markierungen für ein Rechts-nach-Links-Leselayout hinzu.
0x80000000 = Ignoriert alle Änderungen, die der Benutzer am Standarddatumsformat des Systems vorgenommen hat.
0x40000000 = Verwendet die ANSI-Codepage des Systems zum Übersetzen der Zeichenkette, nicht die Codepage aus den Sprach- und Regionseinstellungen.

Tn: Zeitoptionen. Geben Sie für n eine der folgenden Zahlen an:

0 = Erzwingt die Verwendung der Standardoptionen. Dadurch werden auch Minuten und Sekunden angezeigt.
1 = Lässt die Minuten und Sekunden weg.
2 = Lässt die Sekunden weg.
4 = Lässt den Zeitmarker (z.B. AM/PM) weg.
8 = Verwendet das 24-Stunden-Format anstelle des 12-Stunden-Formats.
12 = Hat den kombinierten Effekt von 4 und 8.
0x80000000 = Ignoriert alle Änderungen, die der Benutzer am Standardzeitformat des Systems vorgenommen hat.
0x40000000 = Verwendet die ANSI-Codepage des Systems zum Übersetzen der Zeichenkette, nicht die Codepage aus den Sprach- und Regionseinstellungen.

Hinweis: Dn und Tn können beliebig oft verwendet werden, um mehr als eine Option wirksam werden zu lassen, zum Beispiel: FormatTime("20040228 D2 D4 T1 T8")

Bemerkungen

Um Buchstaben und Zahlen in Format unverändert auf die finale Zeichenkette zu übertragen, umschließen Sie sie mit einfachen Anführungszeichen. Zum Beispiel: "'Datum:' MM/dd/yy 'Zeit:' hh:mm:ss tt".

Nicht-alphanumerische Zeichen wie Leerzeichen, Tabulatoren, Zeilenvorschübe (`n), Schrägstriche, Doppelpunkte, Kommas und andere Satzzeichen müssen hingegen nicht in einfache Anführungszeichen gesetzt werden. Eine Ausnahme bildet das einfache Anführungszeichen selbst: Um es darzustellen, sind vier aufeinanderfolgende einfache Anführungszeichen ('''') erforderlich, oder nur zwei, wenn das Anführungszeichen bereits von einem äußeren Anführungszeichenpaar umschlossen ist.

Wenn Format sowohl Datums- als auch Zeitelemente enthält, dürfen diese nicht vermischt werden. Mit anderen Worten, die Elemente müssen so angeordnet werden, dass die resultierende Zeichenkette in zwei Hälften geteilt werden kann: Eine Zeithälfte und eine Datumshälfte. Zum Beispiel würde die Formatzeichenkette "hh yyyy mm" nicht das erwartete Ergebnis liefern, weil sich ein Datumselement zwischen zwei Zeitelementen befindet.

Wenn Format einen numerischen Monatstag (d oder dd) gefolgt von einem vollständigen Monatsnamen (MMMM) enthält, wird der Genitiv des Monatsnamens verwendet (sofern die Sprache einen Genitiv hat).

Mit DateAdd und DateDiff können beliebige Datums- und Zeitwerte addiert, subtrahiert und verglichen werden.

Wenn Sie stattdessen den umgekehrten Weg gehen wollen, also die Umwandlung einer formatierten Zeichenkette in das YYYYMMDDHH24MISS-Format, schauen Sie sich diesen archivierten Forumsthread an.

Siehe auch: DateTime-Steuerelement, Format, interne Datums- und Zeitvariablen, FileGetTime

Beispiele

Zeigt verschiedene Verwendungsmöglichkeiten.

ZeitZkette := FormatTime()
MsgBox "Uhrzeit und Datum (Zeit zuerst) ist aktuell " ZeitZkette

ZeitZkette := FormatTime("R")
MsgBox "Uhrzeit und Datum (Datum zuerst) ist aktuell " ZeitZkette

ZeitZkette := FormatTime(, "Time")
MsgBox "Uhrzeit ist aktuell " ZeitZkette

ZeitZkette := FormatTime("T12", "Time")
MsgBox "24-Stunden-Uhrzeit ist aktuell " ZeitZkette

ZeitZkette := FormatTime(, "LongDate")
MsgBox "Datum (Langformat) ist aktuell " ZeitZkette

ZeitZkette := FormatTime(20050423220133, "dddd MMMM d, yyyy hh:mm:ss tt")
MsgBox "Datum und Uhrzeit ist nach dem Formatieren " ZeitZkette

MsgBox FormatTime(200504, "'Monatsname': MMMM`n'Tagesname': dddd")

JahrWoche := FormatTime(20050101, "YWeek")
MsgBox "Der 1. Jan. 2005 liegt in folgender ISO-Jahr-Kalenderwoche: " JahrWoche

Ändert den Zeitstempel einer Datei.

DateiName := FileSelect(3,, "Datei auswählen")
if DateiName = "" ; Der Benutzer hat keine Datei ausgewählt.
    return
DateiZeit := FileGetTime(DateiName)
DateiZeit := FormatTime(DateiZeit)   ; Durch Weglassen des letzten Parameters wird die Uhrzeit und das lange Datum abgerufen.
MsgBox "Die ausgewählte Datei wurde zuletzt am " DateiZeit " geändert."

Wandelt eine bestimmte Anzahl von Sekunden in Stunden, Minuten und Sekunden um (hh:mm:ss-Format).

MsgBox FormatiereSekunden(7384)  ; 7384 = 2 Stunden + 3 Minuten + 4 Sekunden. Rückgabewert: 2:03:04

FormatiereSekunden(SekundenAnzahl)  ; Wandelt eine bestimmte Zahl in das hh:mm:ss-Format um.
{
    Zeit := 19990101  ; *Mitternacht* eines beliebigen Datums.
    Zeit := DateAdd(Zeit, SekundenAnzahl, "Seconds")
    return SekundenAnzahl//3600 ":" FormatTime(Zeit, "mm:ss")
    /*
    ; Im Gegensatz zur obigen Methode würde die folgende nicht mehr als 24 Stunden an Sekunden unterstützen:
    return FormatTime(Zeit, "h:mm:ss")
    */
}