Loop Files

Ruft bestimmte Dateien oder Ordner nacheinander ab.

Loop Files DateiMuster , Modus

Parameter

DateiMuster

Typ: Zeichenkette

Name einer Datei oder eines Ordners oder ein Platzhaltermuster wie "C:\Temp\*.tmp". Wenn kein absoluter Pfad angegeben ist, wird DateiMuster im A_WorkingDir-Verzeichnis vermutet.

Als Platzhalter werden sowohl Sternchen als auch Fragezeichen unterstützt. Eine Übereinstimmung erfolgt, wenn das Suchmuster entweder im langen/normalen Namen oder 8.3-Kurznamen der Datei erscheint.

Wenn dieser Parameter eine einzelne Datei oder ein einzelner Ordner ist (also ohne Platzhalter) und enthält Modus ein R, werden mehrere Übereinstimmungen gefunden, wenn der angegebene Dateiname in mehreren Ordnern vorkommt.

Suchmuster länger als 259 Zeichen können aufgrund von Systemlimitierungen (MAX_PATH) dazu führen, dass keine Dateien gefunden werden. Diese Limitierung kann mit dem Langer-Pfad-Präfix \\?\ umgangen werden, allerdings sind dabei einige Besonderheiten zu beachten.

Modus

Typ: Zeichenkette

Wenn leer oder weggelassen, werden nur Dateien einbezogen und Unterverzeichnisse nicht rekursiv durchwandert. Andernfalls geben Sie einen oder mehrere der folgenden Buchstaben an:

• D = Verzeichnisse (Ordner) einbeziehen.
• F = Dateien einbeziehen. Wenn sowohl F als auch D weggelassen werden, werden nur Dateien einbezogen, keine Ordner.
• R = Unterverzeichnisse (Unterordner) werden rekursiv durchwandert. Es werden alle Unterordner rekursiv durchwandert, nicht nur solche, die dem DateiMuster entsprechen. Wenn R weggelassen wird, werden Dateien und Ordner in den Unterordnern nicht mit einbezogen.

Sondervariablen innerhalb einer Datei-Schleife

Die folgenden Variablen können innerhalb einer Datei-Schleife verwendet werden. Wenn eine innere Datei-Schleife von einer äußeren Datei-Schleife umschlossen ist, hat die Datei der innersten Schleife Vorrang:

Loop Files, "C:\Meine Dokumente\Adressliste.txt"
    KurzPfadName := A_LoopFileShortPath

Bemerkungen

Eine Datei-Schleife ist nützlich, wenn mehrere Dateien und/oder Ordner nacheinander abgearbeitet werden sollen.

Alle gefundenen Dateien werden abgerufen, auch versteckte Dateien. OS-Features wie der DIR-Befehl ignorieren hingegen standardmäßig versteckte Dateien. Um versteckte, systemspezifische und/oder schreibgeschützte Dateien innerhalb einer Schleife zu überspringen, kann z.B. Folgendes verwendet werden:

if A_LoopFileAttrib ~= "[HRS]"  ; Jede Datei überspringen, die H (versteckt), R (schreibgeschützt) oder S (systemspezifisch) ist. Siehe Tilde-Operator.
    continue  ; Diese Datei überspringen und zur nächsten übergehen.

Um bei einer rekursiven Suche relative statt absolute Dateipfade abzurufen, ändern Sie den Basisordner mit SetWorkingDir, bevor Sie die Schleife verwenden, und lassen Sie dann den Pfad bei der Schleife weg (z.B. Loop Files, "*.*", "R"). Dies hat zur Folge, dass A_LoopFilePath einen Dateipfad enthält, der relativ zum Basisordner ist.

Eine Datei-Schleife kann sich selbst unterbrechen, wenn sie Dateien oder Ordner innerhalb ihres eigenen Geltungsbereichs erstellt oder umbenennt. Verwendet die Schleife z.B. FileMove, um Dateien umzubenennen, könnten solche Dateien zweimal gefunden werden: Einmal mit dem alten Namen und ein weiteres Mal mit dem neuen Namen. Um das zu umgehen, erstellen Sie zuerst eine Liste von Dateien, bevor Sie sie umbenennen. Zum Beispiel:

DateiListe := ""
Loop Files, "*.jpg"
    DateiListe .= A_LoopFileName "`n"
Loop Parse, DateiListe, "`n"
    FileMove A_LoopField, "umbenannt_" A_LoopField

Dateien in einem NTFS-Dateisystem werden wahrscheinlich immer in alphabetischer Reihenfolge abgerufen. Bei anderen Dateisystemen ist die Reihenfolge unbestimmt. Um eine bestimmte Reihenfolge festzulegen, verwenden Sie die Sort-Funktion, wie im Beispielabschnitt unten gezeigt.

Dateimuster länger als 259 Zeichen werden nur unterstützt, wenn mindestens eine der folgenden Bedingungen erfüllt ist:

• Auf dem System ist die Langer-Pfad-Unterstützung aktiviert (erfordert Windows 10 Version 1607 oder höher).
• Das Langer-Pfad-Präfix \\?\ wird verwendet.

In allen anderen Fällen werden Dateimuster länger als 259 Zeichen keine Dateien oder Ordner finden. Diese Limitierung gilt sowohl für DateiMuster als auch für alle temporären Muster, die beim rekursiven Durchwandern eines Unterordners verwendet werden.

Der One True Brace (OTB) Style wird unterstützt, d.h. Sie können je nach Bedarf die geschweifte Startklammer am Zeilenende positionieren. Zum Beispiel: Loop Files "*.txt", "R" {.

Auf der Loop-Seite finden Sie Informationen zu Blöcken, Break, Continue und A_Index (die in jeder Schleifenvariante verwendet werden kann).

Nach der Schleife kann optional eine Else-Anweisung angegeben werden, die ausgeführt wird, wenn keine passenden Dateien oder Verzeichnisse gefunden wurden (d.h. wenn die Schleife null Wiederholungen hatte).

Die Funktionen FileGetAttrib, FileGetSize, FileGetTime, FileGetVersion, FileSetAttrib und FileSetTime können in einer Datei-Schleife ohne ihren DateiName/DateiMuster-Parameter verwendet werden.

Siehe auch

Loop, Break, Continue, Blöcke, SplitPath, FileSetAttrib, FileSetTime

Beispiele

Loop Files, A_ProgramFiles "\*.txt", "R"  ; Unterordner rekursiv durchwandern.
{
    Ergebnis := MsgBox("Dateiname = " A_LoopFilePath "`n`nWeiter?",, "y/n")
    if Ergebnis = "No"
        break
}

OrdnerGrößeKB := 0
WelcherOrdner := DirSelect()  ; Benutzer einen Ordner auswählen lassen.
Loop Files, WelcherOrdner "\*.*", "R"
    OrdnerGrößeKB += A_LoopFileSizeKB
MsgBox WelcherOrdner " ist " OrdnerGrößeKB " KB groß."

DateiListe := ""  ; Als leere Variable initialisieren.
Loop Files, "C:\*.*"
    DateiListe .= A_LoopFileName "`n"
DateiListe := Sort(DateiListe, "R")  ; Die R-Option sortiert in umgekehrter Richtung. Siehe Sort für weitere Optionen.
Loop Parse, DateiListe, "`n"
{
    if A_LoopField = ""  ; Das leere Element am Ende der Liste ignorieren.
        continue
    Ergebnis := MsgBox("Datei Nr. " A_Index " ist " A_LoopField ".  Weiter?",, "y/n")
    if Ergebnis = "No"
        break
}

DateiListe := ""
Loop Files, A_MyDocuments "\Fotos\*.*", "FD"  ; Dateien und Ordner einbeziehen
    DateiListe .= A_LoopFileTimeModified "`t" A_LoopFileName "`n"
DateiListe := Sort(DateiListe)  ; Nach Datum sortieren.
Loop Parse, DateiListe, "`n"
{
    if A_LoopField = "" ; Das letzte LF-Zeichen (leere Element) am Ende der Liste ignorieren.
        continue
    DateiElement := StrSplit(A_LoopField, A_Tab)  ; Bei einem Tab-Zeichen in zwei Teile aufteilen.
    Ergebnis := MsgBox("Die nächste Datei ist (geändert am " DateiElement[1] "):`n" DateiElement[2] "`n`nWeiter?",, "y/n")
    if Ergebnis = "No"
        break
}

KopierenWennNeuer(QuelleMuster, Ziel)
{
    Loop Files, QuelleMuster
    {
        Kopieren := false
        if !FileExist(Ziel "\" A_LoopFileName)  ; Immer kopieren, wenn Zieldatei noch nicht existiert.
            Kopieren := true
        else
        {
            Zeit := FileGetTime(Ziel "\" A_LoopFileName)
            Zeit := DateDiff(Zeit, A_LoopFileTimeModified, "Seconds")  ; Zeit der Quelldatei von der Zeit der Zieldatei subtrahieren.
            if Zeit < 0  ; Quelldatei ist neuer als Zieldatei.
                Kopieren := true
        }
        if Kopieren
        {
            try
                FileCopy A_LoopFilePath, Ziel "\" A_LoopFileName, 1   ; Kopieren und bei Bedarf überschreiben
            catch
                MsgBox '"' A_LoopFilePath '" konnte nicht nach "' Ziel '\' A_LoopFileName '" kopiert werden.'
        }
    }
}

for EingabePfad in A_Args  ; Für jeden Parameter (oder für jede auf ein Skript gezogene Datei):
{
    Loop Files, EingabePfad, "FD"  ; Dateien und Verzeichnisse einbeziehen.
        LangerPfad := A_LoopFilePath
    MsgBox "Der lange Pfadname mit korrekter Groß-/Kleinschreibung der Datei`n" EingabePfad "`nist:`n" LangerPfad
}