Loop Reg

Ruft die Inhalte eines bestimmten Registry-Unterschlüssels nacheinander ab.

Loop Reg SchlüsselName , Modus

Parameter

SchlüsselName

Typ: Zeichenkette

Der vollständige Name des Registry-Schlüssels, z.B. "HKLM\Software\BeliebigeApp".

Der Name muss entweder mit HKEY_LOCAL_MACHINE (oder HKLM), HKEY_USERS (oder HKU), HKEY_CURRENT_USER (oder HKCU), HKEY_CLASSES_ROOT (oder HKCR) oder HKEY_CURRENT_CONFIG (oder HKCC) beginnen.

Um auf eine Remote-Registry zuzugreifen, stellen Sie den Computernamen und einen umgekehrten Schrägstrich voran, z.B. "\\workstation01\HKLM".

Modus

Typ: Zeichenkette

Wenn leer oder weggelassen, werden nur Werte einbezogen und Unterschlüssel nicht rekursiv durchwandert. Andernfalls geben Sie einen oder mehrere der folgenden Buchstaben an:

• K = Schlüssel einbeziehen.
• V = Werte einbeziehen. Werte werden auch einbezogen, wenn K und V weggelassen werden.
• R = Unterschlüssel werden rekursiv durchwandert. Wenn R weggelassen wird, werden Schlüssel und Werte innerhalb der Unterschlüssel von SchlüsselName nicht mit einbezogen.

Bemerkungen

Eine Registry-Schleife ist nützlich, wenn mehrere Werte oder Unterschlüssel in der Registry nacheinander abgearbeitet werden sollen. Die Werte und Unterschlüssel werden in umgekehrter Reihenfolge (von unten nach oben) abgerufen, so dass RegDelete und RegDeleteKey innerhalb der Schleife verwendet werden können, ohne die Schleife zu unterbrechen.

Die folgenden Variablen sind nur in einer Registry-Schleife von Bedeutung. Wenn eine innere Registry-Schleife von einer äußeren Registry-Schleife umschlossen ist, hat das Element der innersten Schleife Vorrang:

Innerhalb einer Registry-Schleife können die folgenden Funktionen in vereinfachter Form verwendet werden, um anzugeben, dass sie mit dem aktuell abgerufenen Element arbeiten sollen:

Beim Zugriff auf eine Remote-Registry (über den SchlüsselName-Parameter, wie oben beschrieben) müssen Sie Folgendes beachten:

• Auf dem Zielcomputer muss der Dienst "Remote Registry" laufen.
• Der Zugriff auf eine Remote-Registry kann fehlschlagen, wenn sich der Zielcomputer nicht in derselben Domäne wie Ihr Computer befindet oder wenn der Benutzername auf einem der beiden Computer nicht über ausreichende Berechtigungen verfügt (siehe unten für mögliche Übergangslösungen).
• Je nach Domäne, Arbeitsgruppe und/oder Berechtigungen Ihres Benutzernamens müssen Sie möglicherweise erst eine Verbindung zu einem freigegebenen Gerät herstellen (z.B. über eine Laufwerkszuordnung), bevor Sie auf eine Remote-Registry zugreifen können. Die Herstellung einer solchen Verbindung - unter Verwendung eines Remote-Benutzernamens und -Passworts mit Zugriffsrechten auf die Registry - kann als Nebeneffekt einen Remote-Registry-Zugriff ermöglichen.
• Wenn Sie bereits als anderer Benutzer mit dem Zielcomputer verbunden sind (z.B. mit einem zugeordneten Laufwerk via Benutzer "Gast"), müssen Sie diese Verbindung möglicherweise erst trennen, damit das Remote-Registry-Feature Sie unter Ihrem eigenen, derzeit angemeldeten Benutzernamen neu verbinden und authentifizieren kann.

Der One True Brace (OTB) Style wird unterstützt, d.h. Sie können je nach Bedarf die geschweifte Startklammer am Zeilenende positionieren. Zum Beispiel: Loop Reg "HKLM\Software\AutoHotkey", "V" {.

Auf der Loop-Seite finden Sie Informationen zu Blöcken, Break, Continue und A_Index (die in jeder Schleifenvariante verwendet werden kann).

Nach der Schleife kann optional eine Else-Anweisung angegeben werden, die ausgeführt wird, wenn keine Registry-Elemente des angegebenen Typs gefunden wurden (d.h. wenn die Schleife null Wiederholungen hatte).

Siehe auch

Loop, Break, Continue, Blöcke, RegRead, RegWrite, RegDelete, RegDeleteKey, SetRegView

Beispiele

Loop Reg, "HKEY_LOCAL_MACHINE\Software\BeliebigeApp"
    MsgBox A_LoopRegName

Loop Reg, "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\TypedURLs"
    RegDelete

Loop Reg, "HKCU\Software\Microsoft\Windows", "R KV"  ; Schlüssel und Werte rekursiv abrufen.
{
    if A_LoopRegType = "key"
        Wert := ""
    else
    {
        try
            Wert := RegRead()
        catch
            Wert := "*error*"
    }
    Ergebnis := MsgBox(A_LoopRegName " = " Wert " (" A_LoopRegType ")`n`nWeiter?",, "y/n")
}
Until Ergebnis = "No"

RegSuche("Notepad")

RegSuche(Ziel)
{
    Loop Reg, "HKEY_LOCAL_MACHINE", "KVR"
    {
        if !RegElementPrüfen()  ; Suche stoppen.
            return
    }
    Loop Reg, "HKEY_USERS", "KVR"
    {
        if !RegElementPrüfen()  ; Suche stoppen.
            return
    }
    Loop Reg, "HKEY_CURRENT_CONFIG", "KVR"
    {
        if !RegElementPrüfen()  ; Suche stoppen.
            return
    }
    ; Hinweis: Ich glaube nicht, dass HKEY_CURRENT_USER durchsucht werden muss,
    ; wenn HKEY_USERS durchsucht wird. Ebenso bietet HKEY_CLASSES_ROOT eine
    ; kombinierte Ansicht der Schlüssel von HKEY_LOCAL_MACHINE und
    ; HKEY_CURRENT_USER, so dass eine Suche in allen dreien unnötig ist.

    RegElementPrüfen()
    {
        if A_LoopRegType = "KEY"  ; Dies entfernen, um auch Schlüsselnamen zu prüfen.
            return true
        try
            RegWert := RegRead()
        catch
            return true
        if InStr(RegWert, Ziel)
        {
            Ergebnis := MsgBox(
            (
            "Die folgende Übereinstimmung wurde gefunden:
            " A_LoopRegKey "\" A_LoopRegName "
            Wert = " RegWert "
            
            Weiter?"
            ),, "y/n")
            if Ergebnis = "No"
                return false  ; Aufrufer mitteilen, die Suche zu stoppen.
        }
        return true
    }
}