TrayTip

Zeigt eine Sprechblase oder in Windows 10 und höher eine Popupbenachrichtigung in der Nähe des Tray-Symbols an.

TrayTip Text, Titel, Optionen

Parameter

Text

Typ: Zeichenkette

Wenn leer oder weggelassen, wird der Text des Traytips komplett weggelassen, wodurch der Traytip vertikal kürzer wird. Andernfalls geben Sie die Meldung an, die angezeigt werden soll. Nur die ersten 255 Zeichen werden angezeigt.

Wagenrücklauf (`r) oder Zeilenvorschub (`n) können zum Erstellen mehrerer Textzeilen verwendet werden. Zum Beispiel: Zeile1`nZeile2.

Wenn Text relativ lang ist, kann es via Fortsetzungsbereich in mehrere kurze Zeilen aufgeteilt werden, um die Übersichtlichkeit und Wartbarkeit des Skripts zu verbessern.

Titel

Typ: Zeichenkette

Wenn leer oder weggelassen, wird die Titelzeile des Traytips komplett weggelassen, wodurch der Traytip vertikal kürzer wird. Andernfalls geben Sie den Titel des Traytips an. Nur die ersten 63 Zeichen werden angezeigt.

Optionen

Typ: Zeichenkette oder Integer

Wenn leer oder weggelassen, wird standardmäßig 0 verwendet. Andernfalls geben Sie entweder einen Integer (eine Kombination via Addition oder bitweises ODER) oder eine Zeichenkette mit beliebig vielen Optionen an (nicht Groß-/Kleinschreibung-sensitiv), die durch mindestens ein Leer- oder Tabulatorzeichen voneinander getrennt sind. Die Zeichenkette kann auch beliebig viele numerische Optionen enthalten.

Funktion	Dez	Hex	Zkette
Kein Symbol	0	0x0	N/A
Infosymbol	1	0x1	Iconi
Warnsymbol	2	0x2	Icon!
Fehlersymbol	3	0x3	Iconx
Tray-Symbol	4	0x4	N/A
Benachrichtigungssound nicht abspielen.	16	0x10	Mute
Große Version des Symbols verwenden.	32	0x20	N/A

Das Symbol wird auch nicht angezeigt, wenn kein Titel angegeben ist (dies gilt nicht für die Popupbenachrichtigungen in Windows 10 und höher).

In Windows 10 und höher wird das kleine Tray-Symbol grundsätzlich angezeigt, selbst wenn die "Tray-Symbol"-Option (4) weggelassen wird, außerdem kann diese Option dazu führen, dass der Name des Programms in der Benachrichtigung angezeigt wird.

Traytip verstecken

Um den Traytip zu verstecken, lassen Sie alle Parameter weg (oder zumindest den Text- und Titel-Parameter). Zum Beispiel:

TrayTip

Um den Traytip in Windows 10 zu verstecken, entfernen Sie vorübergehend das Tray-Symbol (was nicht immer funktioniert, zumindest einem Bericht zufolge). Zum Beispiel:

TrayTip "#1", "Der erste Traytip"
Sleep 3000   ; 3 Sekunden lang anzeigen lassen.
TrayTipVerstecken
TrayTip "#2", "Die zweite Benachrichtigung."
Sleep 3000

; Kopieren Sie diese Funktion in Ihr Skript, um sie zu verwenden.
TrayTipVerstecken() {
    TrayTip  ; Versuchen, normal zu verstecken.
    if SubStr(A_OSVersion,1,3) = "10." {
        A_IconHidden := true
        Sleep 200  ; Ggf. muss dieser Sleep-Wert angepasst werden.
        A_IconHidden := false
    }
}

Bemerkungen

In Windows 10 sieht ein typischer Traytip wie folgt aus:

Windows 10 und höher ersetzen standardmäßig alle Sprechblasenfenster mit Popupbenachrichtigungen (was aber mit einer Gruppenrichtlinie überschrieben werden kann). Wenn TrayTip mehrmals aufgerufen wird, werden die Benachrichtigungen in eine "Warteschlange" eingereiht und nacheinander abgearbeitet, anstatt sich gegenseitig zu ersetzen.

TrayTip funktioniert nicht, wenn das Skript kein Tray-Symbol hat (via #NoTrayIcon oder A_IconHidden := true). TrayTip funktioniert auch nicht, wenn der folgende REG_DWORD-Wert existiert und auf 0 gesetzt wurde:

HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced >> EnableBalloonTips

Erwähnenswert ist noch, dass ein Tooltip angezeigt wird, wenn der Mauszeiger über das Tray-Symbol des Skripts bewegt wird. Der Inhalt des Tooltips kann wie folgt geändert werden: A_IconTip := "Mein neuer Text".

Siehe auch

ToolTip, SetTimer, Menu-Objekt, MsgBox, InputBox, FileSelect, DirSelect

Beispiele

TrayTip "Mehrzeiliger`nText", "Mein Titel", "Iconi Mute"

TrayTip "Wird 5 Sekunden lang angezeigt.", "Zeitgesteuerter Traytip"
SetTimer () => TrayTip(), -5000

TrayTip "Wird 5 Sekunden lang angezeigt.", "Zeitgesteuerter Traytip"
SetTimer TrayTipVerstecken, -5000

TrayTipVerstecken() {
    TrayTip
}

SetTimer TrayTipErneuern, 1000
TrayTipErneuern  ; Direkt aufrufen, um sofortigen Start zu erzwingen.

TrayTipErneuern()
{
    TrayTip "Dies ist ein permanenter Traytip.", "Erneuerter Traytip", "Mute"
}