TreeView

GuiCtrl := MeineGui.Add("TreeView", Optionen)
GuiCtrl := MeineGui.AddTreeView(Optionen)

MeineGui := Gui()
TV := MeineGui.Add("TreeView")
P1 := TV.Add("Erstes Elternelement")
P1C1 := TV.Add("Erstes Kinderelement von Elternelement 1", P1)  ; P1 als Elternelement für dieses Element festlegen.
P2 := TV.Add("Zweites Elternelement")
P2C1 := TV.Add("Erstes Kinderelement von Elternelement 2", P2)
P2C2 := TV.Add("Zweites Kinderelement von Elternelement 2", P2)
P2C2C1 := TV.Add("Erstes Kinderelement von Elternelement 2", P2C2)

MeineGui.Show()  ; Das Fenster und dessen TreeView anzeigen.

Add

Fügt ein neues Element zur TreeView hinzu.

ElementID := TV.Add(Name, ElternElementID, Optionen)

Parameter

Name

Typ: Zeichenkette

Der Anzeigetext des Elements, der textuell oder numerisch sein kann (einschließlich numerischer Ergebnisse von Ausdrücken).

ElternElementID

Typ: Integer

Wenn weggelassen, wird standardmäßig 0 verwendet, d.h. das Element wird als Top-Level-Element hinzugefügt. Andernfalls geben Sie die ID-Nummer des Elternelements des neuen Elements an.

Optionen

Typ: Zeichenkette

Wenn leer oder weggelassen, werden standardmäßig keine Optionen verwendet. Andernfalls geben Sie eine oder mehrere Optionen aus der unteren Liste an (nicht Groß-/Kleinschreibung-sensitiv). Trennen Sie alle Optionen jeweils durch ein Leer- oder Tabulatorzeichen. Um eine Option zu entfernen, setzen Sie ein Minuszeichen davor. Um eine Option hinzuzufügen, lassen Sie das Vorzeichen weg oder setzen Sie ein Pluszeichen davor.

Bold: Stellt den Namen des Elements in fetter Schrift dar. Um dessen Schrift später wieder zu normalisieren, verwenden Sie TV.Modify(ElementID, "-Bold"). Direkt nach dem Wort Bold kann optional eine 0 oder 1 angegeben werden, um den Startzustand zu bestimmen.

Check: Zeigt ein Häkchen links neben dem Element an (sofern die TreeView über Kontrollkästchen verfügt). Um das Häkchen später wieder zu entfernen, verwenden Sie TV.Modify(ElementID, "-Check"). Direkt nach dem Wort Check kann optional eine 0 oder 1 angegeben werden, um den Startzustand zu bestimmen. Mit anderen Worten, "Check" ist dasselbe wie "Check" . VarEnhältEins (wobei der Punkt ein Verkettungsoperator ist).

Expand: Klappt das Element auf, um seine Kinderelemente (falls vorhanden) anzuzeigen. Um das Element später wieder zuzuklappen, verwenden Sie TV.Modify(ElementID, "-Expand"). Wenn es keine Kinderelemente hat, gibt die Modify-Methode 0 anstelle der Element-ID zurück. Die Add-Methode hingegen markiert das Element als aufgeklappt, falls später noch Kinderelemente hinzugefügt werden. Im Gegensatz zur Select-Option unten wird beim Aufklappen eines Elements nicht automatisch das Elternelement aufgeklappt. Direkt nach dem Wort Expand kann optional eine 0 oder 1 angegeben werden, um den Startzustand zu bestimmen. Mit anderen Worten, "Expand" ist dasselbe wie "Expand" . VarEnhältEins.

First | Sort | N: Diese Optionen gelten nur für die Add-Methode. Sie bestimmen die Position des neuen Elements relativ zu seinen Geschwisterelementen (ein Geschwisterelement befindet sich auf derselben Ebene). Wenn keine dieser Optionen vorhanden ist, wird das neue Element als letztes/unterstes Geschwisterelement hinzugefügt. Andernfalls geben Sie das Wort First an, um das Element als erstes/oberstes Geschwisterelement hinzuzufügen, oder das Wort Sort, um das Element unter seinen Geschwisterelementen in alphabetischer Reihenfolge einzufügen. Wenn eine Nummer (N) angegeben ist, wird diese als ID-Nummer des Geschwisterelements vermutet, hinter dem das neue Element eingefügt werden soll (wenn N die einzige Option ist, muss sie nicht in Anführungszeichen gesetzt werden).

Icon: Geben Sie das Wort Icon an, unmittelbar gefolgt von der Nummer des Symbols, das links neben dem Elementnamen angezeigt werden soll. Wenn diese Option fehlt, wird das erste Symbol in der ImageList verwendet. Um ein leeres Symbol anzuzeigen, geben Sie eine Nummer größer als die Anzahl der Symbole in der ImageList an. Wenn dem Steuerelement keine ImageList zugewiesen wurde, wird kein Symbol angezeigt und kein Platz dafür reserviert.

Select: Wählt das Element aus. Da immer nur ein Element ausgewählt werden kann, wird das zuvor ausgewählte Element automatisch abgewählt. Außerdem bewirkt diese Option, dass alle Elternelemente des neuen Elements, das ausgewählt wurde, aufgeklappt werden, falls erforderlich. Um die aktuelle Auswahl zu ermitteln, verwenden Sie die GetSelection-Methode.

Sort: In Verbindung mit der Modify-Methode bewirkt diese Option, dass die Kinderelemente des angegebenen Elements in alphabetischer Reihenfolge sortiert werden. Um stattdessen alle Top-Level-Elemente zu sortieren, verwenden Sie TV.Modify(0, "Sort"). Wenn es keine Kinderelemente hat, wird 0 anstelle der ID des geänderten Elements zurückgegeben.

Vis: Stellt sicher, dass das Element vollständig sichtbar ist, ggf. durch Scrollen der TreeView und/oder Aufklappen des Elternelements.

VisFirst: Dasselbe wie oben, außer dass die TreeView zusätzlich gescrollt wird, um das Element nach Möglichkeit ganz oben anzuzeigen. Diese Option ist in Verbindung mit der Modify-Methode grundsätzlich effektiver als mit der Add-Methode.

Rückgabewert

Typ: Integer

Bei Erfolg gibt diese Methode die eindeutige ID-Nummer des neuen Elements zurück. Bei Misserfolg gibt sie 0 zurück.

Bemerkungen

Um das Hinzufügen sehr vieler Elemente performanter zu machen, verwenden Sie TV.Opt("-Redraw"), bevor Sie die Elemente hinzufügen, und danach TV.Opt("+Redraw"). Weitere Informationen finden Sie unter Redraw.

Modify

Ändert die Attribute und/oder den Namen eines Elements.

ElementID := TV.Modify(ElementID , Optionen, NeuerName)

Parameter

ElementID

Typ: Integer

Die ID-Nummer des Elements, das geändert werden soll.

Optionen

Typ: Zeichenkette

Wenn dieser und der NeuerName-Parameter weggelassen werden, wird das Element ausgewählt. Andernfalls geben Sie eine oder mehrere Optionen aus der obigen Liste an.

NeuerName

Typ: Zeichenkette

Wenn weggelassen, bleibt der aktuelle Name unverändert. Andernfalls geben Sie den neuen Namen des Elements an.

Rückgabewert

Typ: Integer

Diese Methode gibt die ID des Elements zurück.

Delete

Löscht ein bestimmtes Element oder alle Elemente.

TV.Delete(ElementID)

Parameter

ElementID

Typ: Integer

Wenn weggelassen, werden alle Elemente in der TreeView gelöscht. Andernfalls geben Sie die ID-Nummer des Elements an, das gelöscht werden soll.

GetSelection

Gibt die ID-Nummer des ausgewählten Elements zurück.

ElementID := TV.GetSelection()

Rückgabewert

Typ: Integer

Diese Methode gibt die ID-Nummer des ausgewählten Elements zurück.

GetCount

Gibt die Gesamtzahl der Elemente im Steuerelement zurück.

Anzahl := TV.GetCount()

Rückgabewert

Typ: Integer

Diese Methode gibt die Gesamtzahl der Elemente im Steuerelement zurück. Der Wert wird immer sofort zurückgegeben, da das Steuerelement diese Zählung zwischenspeichert.

GetParent

Gibt die ID-Nummer des Elternelements eines bestimmten Elements zurück.

ElternElementID := TV.GetParent(ElementID)

Parameter

ElementID

Typ: Integer

Die ID-Nummer des Elements, das geprüft werden soll.

Rückgabewert

Typ: Integer

Diese Methode gibt die ID-Nummer des Elternelements des angegebenen Elements zurück. Wenn das Element kein Elternelement hat, gibt sie 0 zurück, was für alle Top-Level-Elemente gilt.

GetChild

Gibt die ID-Nummer des ersten/obersten Kinderelements eines bestimmten Elements zurück.

KinderelementID := TV.GetChild(ElementID)

Parameter

ElementID

Typ: Integer

Die ID-Nummer des Elements, das geprüft werden soll. Wenn 0, wird die ID-Nummer des ersten/obersten Elements in der TreeView zurückgegeben.

Rückgabewert

Typ: Integer

Diese Methode gibt die ID-Nummer des ersten/obersten Kinderelements des angegebenen Elements zurück. Wenn dort kein Kinderelement vorhanden ist, gibt sie 0 zurück.

GetPrev

Gibt die ID-Nummer des Geschwisterelements zurück, das sich oberhalb eines bestimmten Elements befindet.

VorherigesElementID := TV.GetPrev(ElementID)

Parameter

ElementID

Typ: Integer

Die ID-Nummer des Elements, das geprüft werden soll.

Rückgabewert

Typ: Integer

Diese Methode gibt die ID-Nummer des Geschwisterelements zurück, das sich oberhalb des angegebenen Elements befindet. Wenn dort kein Geschwisterelement vorhanden ist, gibt sie 0 zurück.

GetNext

Gibt die ID-Nummer des nächsten Elements zurück, das sich unterhalb eines bestimmten Elements befindet.

NächstesElementID := TV.GetNext(ElementID, ElementTyp)

Parameter

ElementID

Typ: Integer

Wenn weggelassen, wird standardmäßig 0 verwendet, d.h. es wird die ID-Nummer des ersten/obersten Elements in der TreeView zurückgegeben. Andernfalls geben Sie die ID-Nummer des Elements an, das geprüft werden soll.

ElementTyp

Typ: Zeichenkette

Wenn weggelassen, wird die ID-Nummer des Geschwisterelements abgerufen, das sich unterhalb des angegebenen Elements befindet. Andernfalls geben Sie eine der folgenden Zeichenketten an:

Full oder F: Ruft das nächste Element unabhängig von seiner Beziehung zum angegebenen Element ab. Dadurch kann das Skript auf einfache Weise die gesamte TreeView Element für Element durchgehen. Siehe das Beispiel unten.

Check, Checked oder C: Ruft nur das nächste angehakte Element ab.

Rückgabewert

Typ: Integer

Diese Methode gibt die ID-Nummer des nächsten Elements zurück, das sich unterhalb des angegebenen Elements befindet. Wenn dort kein nächstes Element vorhanden ist, gibt sie 0 zurück.

Bemerkungen

Das folgende Beispiel durchläuft die gesamte TreeView Element für Element:

ElementID := 0  ; Die Suche beim ersten Element beginnen.
Loop
{
    ElementID := TV.GetNext(ElementID, "Full")  ; Ersetzen Sie "Full" mit "Checked", um alle angehakten Elemente zu finden.
    if not ElementID  ; Keine weiteren Elemente verfügbar.
        break
    ElementText := TV.GetText(ElementID)
    MsgBox('Das nächste Element ist ' ElementID ' und enthält "' ElementText '".')
}

GetText

Ruft den Text/Namen eines bestimmten Elements ab.

Text := TV.GetText(ElementID)

Parameter

ElementID

Typ: Integer

Die ID-Nummer des Elements, dessen Text abgerufen werden soll.

Rückgabewert

Typ: Zeichenkette

Diese Methode gibt den abgerufenen Text zurück. Es werden nur bis zu 8191 Zeichen abgerufen.

Get

Gibt die ID-Nummer eines bestimmten Elements zurück, unter Beachtung des angegebenen Attributs.

ElementID := TV.Get(ElementID, Attribut)

Parameter

ElementID

Typ: Integer

Die ID-Nummer des Elements, das geprüft werden soll.

Attribut

Typ: Zeichenkette

Geben Sie eine der folgenden Zeichenketten an:

E, Expand oder Expanded: Das Element ist gerade aufgeklappt (d.h. seine Kinderelemente werden angezeigt).

C, Check oder Checked: Das Element hat ein Häkchen.

B oder Bold: Das Element wird gerade fett dargestellt.

Rückgabewert

Typ: Integer

Wenn das angegebene Element das angegebene Attribut hat, wird dessen ID zurückgegeben. Andernfalls wird 0 zurückgegeben.

Bemerkungen

Da eine IF-Anweisung jeden Wert ungleich 0 als "wahr" ansieht, sind die folgenden zwei Zeilen funktionsgleich: if TV.Get(ElementID, "Checked") = ElementID und if TV.Get(ElementID, "Checked").

SetImageList

Setzt oder ersetzt eine ImageList zur Darstellung von Symbolen.

VorherigeImageListID := TV.SetImageList(ImageListID , SymbolTyp)

Parameter

ImageListID

Typ: Integer

Die ID-Nummer, die von einem früheren Aufruf von IL_Create zurückgegeben wurde.

SymbolTyp

Typ: Integer

Wenn weggelassen, wird standardmäßig 0 verwendet. Andernfalls geben Sie 2 für Zustandssymbole an (Zustandssymbole werden nur indirekt via SendMessage unterstützt).

Rückgabewert

Typ: Integer

Bei Erfolg gibt diese Methode die ImageList-ID zurück, die zuvor mit der TreeView verknüpft war. Bei Misserfolg gibt sie 0 zurück. Jede nicht mehr verwendete ImageList sollte normalerweise mit IL_Destroy zerstört werden.

MeineGui := Gui()
ImageListID := IL_Create(10)  ; Eine ImageList mit einer anfänglichen Kapazität von 10 Symbolen erstellen.
Loop 10  ; ImageList mit einigen Standardsymbolen des Systems füllen.
    IL_Add(ImageListID, "shell32.dll", A_Index)
TV := MeineGui.Add("TreeView", "ImageList" . ImageListID)
TV.Add("Elementname", 0, "Icon4")  ; Element zur TreeView hinzufügen und ein Ordnersymbol zuweisen.
MeineGui.Show()

MeineGui.Add("Button", "Hidden Default", "OK").OnEvent("Click", ButtonOK)
...
ButtonOK(*) {
    global
    if MeineGui.FocusedCtrl != TV
        return
    MsgBox("Sie haben ENTER gedrückt. Die ID des ausgewählten Elements ist " TV.GetSelection())
}

MeineGui := Gui()
TV := MeineGui.Add("TreeView", "-ReadOnly")
TV.Add("A")
TV.Add("B")
TV.Add("C")
TV.OnEvent("ItemEdit", TV_Edit)  ; TV_Edit jedes Mal aufrufen, nachdem ein Element editiert wurde.
MeineGui.Show()

TV_Edit(TV, Element)
{
    TV.Modify(TV.GetParent(Element), "Sort")  ; Funktioniert auch, wenn das Element kein Elternelement hat.
}

; Der folgende Ordner definiert den Stammordner der TreeView. Beachten Sie, dass
; das Laden lange dauern kann, wenn ein ganzes Laufwerk wie C:\ angegeben ist:
TreeRoot := A_MyDocuments
TreeViewBreite := 280
ListViewBreite := A_ScreenWidth/2 - TreeViewBreite - 30

; GUI-Fenster erstellen und Root-Ordner in der Titelleiste anzeigen:
MeineGui := Gui("+Resize", TreeRoot)  ; Dem Benutzer erlauben, das Fenster zu maximieren oder dessen Größe zu ändern.

; Eine ImageList erstellen und mit einigen Standardsymbolen des Systems füllen:
ImageListID := IL_Create(5)
Loop 5 
    IL_Add(ImageListID, "shell32.dll", A_Index)
; Eine TreeView und ListView nebeneinandersetzen, ähnlich dem Windows Explorer:
TV := MeineGui.Add("TreeView", "r20 w" TreeViewBreite " ImageList" ImageListID)
LV := MeineGui.Add("ListView", "r20 w" ListViewBreite " x+10", ["Name", "Änderungsdatum"])

; Statusleiste erstellen, um Anzahl der Dateien und Gesamtgröße anzuzeigen:
SB := MeineGui.Add("StatusBar")
SB.SetParts(60, 85)  ; Leiste in drei Segmente aufteilen (das dritte Segment füllt die restliche Breite aus).

; Ordner und ihre Unterordner zur TreeView hinzufügen. Status anzeigen, falls das Laden länger dauert:
M := Gui("ToolWindow -SysMenu Disabled AlwaysOnTop", "Lade Baumstruktur..."), M.Show("w200 h0")
VerzListe := UnterordnerInBaumEinfügen(TreeRoot, Map())
M.Hide()

; TV_ItemSelect aufrufen, wenn ein neues Element ausgewählt wird:
TV.OnEvent("ItemSelect", TV_ItemSelect)

; Gui_Size aufrufen, wenn die Fenstergröße geändert wird:
MeineGui.OnEvent("Size", Gui_Size)

; Spaltenbreiten der ListView setzen (dies ist optional):
Spalte2Breite := 70  ; Kürzen, um nur den YYYYMMDD-Teil anzuzeigen.
LV.ModifyCol(1, ListViewBreite - Spalte2Breite - 30)  ; Platz für den vertikalen Scrollbalken schaffen.
LV.ModifyCol(2, Spalte2Breite)

; Das Fenster anzeigen. Das Skript wird benachrichtigt, wenn der Benutzer eine gültige Aktion ausführt:
MeineGui.Show()

UnterordnerInBaumEinfügen(Ordner, VerzListe, ElternElementID := 0)
{
    ; Diese Funktion fügt alle Unterordner eines Ordners zur TreeView hinzu
    ; und speichert deren Pfade zusammen mit einer ID in ein Objekt für den späteren Gebrauch.
    ; Sie ruft sich selbst rekursiv auf, um Unterordner in beliebiger Tiefe zu erfassen.
    Loop Files, Ordner "\*.*", "D"  ; Alle Unterordner des Ordners abrufen.
    {
        ElementID := TV.Add(A_LoopFileName, ElternElementID, "Icon4")
        VerzListe[ElementID] := A_LoopFilePath
        VerzListe := UnterordnerInBaumEinfügen(A_LoopFilePath, VerzListe, ElementID)
    }
    return VerzListe
}

TV_ItemSelect(thisCtrl, Element)  ; Diese Funktion wird aufgerufen, wenn ein neues Element ausgewählt wird.
{
    ; Dateien in die ListView einfügen:
    LV.Delete()  ; Alle Zeilen löschen.
    LV.Opt("-Redraw")  ; Performanz verbessern durch Abschalten von Redraw beim Laden.
    GesamtGröße := 0  ; Für die untere Schleife initialisieren.
    Loop Files, VerzListe[Element] "\*.*"  ; Nur die Dateien in der ListView anzeigen.
    {
        LV.Add(, A_LoopFileName, A_LoopFileTimeModified)
        GesamtGröße += A_LoopFileSize
    }
    LV.Opt("+Redraw")

    ; Die drei Segmente der Statusleiste mit Infos über den aktuell ausgewählten Ordner aktualisieren:
    SB.SetText(LV.GetCount() " Dateien", 1)
    SB.SetText(Round(GesamtGröße / 1024, 1) " KB", 2)
    SB.SetText(VerzListe[Element], 3)
}

Gui_Size(thisGui, MinMax, Breite, Höhe)  ; ListView und TreeView kleiner/größer machen, wenn Benutzer die Fenstergröße ändert.
{
    if MinMax = -1  ; Das Fenster wurde minimiert. Keine Aktion notwendig.
        return
    ; Andernfalls wurde das Fenster kleiner/größer gemacht oder maximiert. Größe der Steuerelemente anpassen.
    TV.GetPos(,, &TV_W)
    TV.Move(,,, Höhe - 30)  ; -30 für StatusBar und Abstände.
    LV.Move(,, Breite - TV_W - 30, Höhe - 30)
}