Loop (Dateiinhalt lesen) - Syntax & Verwendung

Ruft die Zeilen einer Textdatei nacheinander ab (performanter als FileReadLine).

Parameter

Bemerkungen

Eine dateilesende Schleife ist nützlich, wenn alle Zeilen in einer Textdatei nacheinander abgearbeitet werden sollen. Diese Schleife ist performanter als FileReadLine, weil: 1) die Datei während der gesamten Operation geöffnet bleibt; und 2) die Datei nicht jedes Mal neu eingelesen werden muss, um die gewünschte Zeilennummer zu finden.

Die interne Variable A_LoopReadLine ist nur in einer dateilesenden Schleife von Bedeutung. Sie enthält den Inhalt der aktuellen Zeile ohne das Wagenrücklauf-Zeilenvorschub-Paar (`r`n) am Ende. Wenn eine innere dateilesende Schleife von einer äußeren dateilesenden Schleife umschlossen ist, hat die Dateizeile der innersten Schleife Vorrang.

Es können Zeilen mit einer Länge von bis zu 65534 Zeichen gelesen werden. Wenn eine Zeile diese Länge überschreitet, werden die restlichen Zeichen bei der nächsten Schleifenwiederholung gelesen.

In einer dateilesenden Schleife wird oft StrSplit(), StringSplit oder eine parsende Schleife verwendet, um den Inhalt von jeder gefundenen Zeile in EingabeDatei zu parsen. Wenn z.B. jede Zeile in EingabeDatei eine Reihe von tabgetrennten Feldern ist, können solche Felder einzeln wie folgt abgerufen werden:

Um eine komplette Datei in eine Variable zu laden, verwenden Sie FileRead, weil es deutlich performanter ist als eine Schleife (insbesondere bei großen Dateien).

Um mehrere Dateien simultan zu lesen oder zu schreiben, verwenden Sie FileOpen().

Auf der Loop-Seite finden Sie Informationen zu Blöcken, Break, Continue und A_Index (die in jeder Schleifenvariante verwendet werden kann).

Mit FileEncoding können Sie kontrollieren, wie eine Datei ohne Byte-Order-Markierung dekodiert werden soll.

Siehe auch

Beispiele

Prüft nacheinander alle Zeilen in der ersten Datei, ob sie das Wort FAMILIE enthalten. Ist dies der Fall, wird die jeweilige Zeile in die zweite Datei geschrieben. Entkommentieren Sie die erste Zeile, um die zweite Datei zu überschreiben, anstatt ihr Text anzufügen.

;FileDelete, C:\Dokumente\Familienadressen.txt

Loop, read, C:\Dokumente\Adressliste.txt, C:\Dokumente\Familienadressen.txt
{
    if InStr(A_LoopReadLine, "Familie")
        FileAppend, %A_LoopReadLine%`n
}

Versucht, alle FTP- und HTTP-URLs aus einer Text- oder HTML-Datei zu extrahieren.

FileSelectFile, QuelleDatei, 3,, Wählen Sie eine Text- oder HTML-Datei zur Analyse aus:
if (QuelleDatei = "")
    return  ; Beendet das Skript in diesem Fall.

SplitPath, QuelleDatei,, QuelleDateiPfad,, QuelleDateiOhneEnd
ZielDatei := QuelleDateiPfad "\" QuelleDateiOhneEnd " Extrahierte Links.txt"

if FileExist(ZielDatei)
{
    MsgBox, 4,, Existierende Datei überschreiben? Drücken Sie Nein, um die Links anzufügen.`n`nDATEI: %ZielDatei%
    IfMsgBox, Yes
        FileDelete, %ZielDatei%
}

LinksAnzahl := 0
Loop, read, %QuelleDatei%, %ZielDatei%
{
    URLSuchZkette := A_LoopReadLine
    Gosub, URLSuche
}
MsgBox %LinksAnzahl% Links wurden gefunden und in "%ZielDatei%" geschrieben.
return


URLSuche:
; Das wird so gemacht, weil einige URLs andere URLs eingebettet haben:
URLStart1 := InStr(URLSuchZkette, "https://")
URLStart2 := InStr(URLSuchZkette, "http://")
URLStart3 := InStr(URLSuchZkette, "ftp://")
URLStart4 := InStr(URLSuchZkette, "www.")

; Die Startposition ganz links finden:
URLStart := URLStart1  ; Standardwert setzen.
Loop
{
    ; Es hilft der Performanz (zumindest in einem Skript mit vielen Variablen),
    ; "URLStart%A_Index%" nur einmal aufzulösen:
    ArrayElement := URLStart%A_Index%
    if (ArrayElement = "")  ; Ende des Pseudo-Arrays erreicht.
        break
    if (ArrayElement = 0)  ; Dieses Element ist disqualifiziert.
        continue
    if (URLStart = 0)
        URLStart := ArrayElement
    else ; URLStart enthält gültige Position, also mit ArrayElement vergleichen.
    {
        if (ArrayElement != 0)
            if (ArrayElement < URLStart)
                URLStart := ArrayElement
    }
}

if (URLStart = 0)  ; Keine URLs in URLSuchZkette.
    return

; Andernfalls diese URL extrahieren:
URL := SubStr(URLSuchZkette, URLStart)  ; Beginnenden/unwichtigen Teil auslassen.
Loop, parse, URL, %A_Tab%%A_Space%<>  ; Erstes Leer-, Tab- oder Winkelzeichen finden (falls verfügbar).
{
    URL := A_LoopField
    break  ; d.h. Schleife nur 1x wiederholen, um das erste "Feld" abzurufen.
}
; Wenn die obige Schleife wegen fehlender Endungszeichen null Wiederholungen
; hatte, den Inhalt der URL-Variable unverändert lassen.

; Wenn URL mit einem doppelten Anführungszeichen endet, dieses entfernen.
; Vorerst wird StrReplace verwendet, aber beachte, dass Anführungszeichen
; in URLs scheinbar legitim sind und dadurch beschädigt werden könnten:
BereinigteURL := StrReplace(URL, "`"")
FileAppend, %BereinigteURL%`n
LinksAnzahl += 1

; Prüfen, ob weitere URLs in dieser Zeile vorkommen:
ZuEntfernendeZeichen := StrLen(URL)
ZuEntfernendeZeichen += URLStart
URLSuchZkette := SubStr(URLSuchZkette, ZuEntfernendeZeichen)
Gosub, URLSuche  ; Rekursiver Aufruf von sich selbst.
return