Loop (Registry)

Ruft die Inhalte eines bestimmten Registry-Unterschlüssels einzeln ab.

Neue Syntax [v1.1.21+]

Loop, Reg, SchlüsselName , Modus

Parameter

Reg

Das direkt geschriebene Wort Reg (nicht Groß-/Kleinschreibung-sensitiv). Dieser Parameter darf weder eine Variable noch ein Ausdruck sein.

SchlüsselName

Der vollständige Name des Registry-Schlüssels wie z. B. HKLM\Software oder %KompletterPfadDesSchlüssels%.

Der Name muss entweder mit HKEY_LOCAL_MACHINE, HKEY_USERS, HKEY_CURRENT_USER, HKEY_CLASSES_ROOT oder HKEY_CURRENT_CONFIG beginnen (oder jeweils die Abkürzung, wie z. B. HKLM). Um Zugriff auf eine Remote-Registry zu erhalten, setzen Sie wie folgt den Computernamen und einen Doppelpunkt davor: \\workstation01:HKEY_LOCAL_MACHINE

Modus

Wenn dieser Parameter weggelassen wird oder leer ist, werden nur Werte einbezogen und Unterschlüssel nicht rekursiv durchwandert. Ansonsten können Sie einen oder mehrere der folgenden Buchstaben angeben:

• K = Schlüssel einbeziehen.
• V = Werte einbeziehen. Werte werden auch einbezogen, wenn K und V weggelassen werden.
• R = Unterschlüssel werden rekursiv durchwandert. Lässt man R weg, werden Schlüssel und Werte innerhalb der Unterschlüssel von SchlüsselName nicht mit einbezogen.

Alte Syntax

Veraltet: Diese Syntax ist nicht für neue Skripte empfohlen. Verwenden Sie stattdessen die neue Syntax.

Loop, RootSchlüssel , Schlüssel, UnterschlüsselEinbeziehen?, Rekursiv?

Parameter

RootSchlüssel

Muss entweder HKEY_LOCAL_MACHINE (oder HKLM), HKEY_USERS (oder HKU), HKEY_CURRENT_USER (oder HKCU), HKEY_CLASSES_ROOT (oder HKCR) oder HKEY_CURRENT_CONFIG (oder HKCC) sein.

Um Zugriff auf eine Remote-Registry zu erhalten, setzen Sie wie folgt den Computernamen und einen Doppelpunkt davor: \\workstation01:HKEY_LOCAL_MACHINE

Schlüssel

Name des Schlüssels (z. B. Software\BeliebigeAnwendung). Wenn dieser Parameter weggelassen wird oder leer ist, werden die Inhalte von RootSchlüssel abgerufen.

UnterschlüsselEinbeziehen?

Wenn dieser Parameter weggelassen wird oder leer ist, wird standardmäßig 0 (nur Werte werden abgerufen) verwendet. Ansonsten können Sie eine der folgenden Ziffern angeben:

• 0 = Unterschlüssel innerhalb von Schlüssel werden nicht abgerufen (nur die Werte).
• 1 = Alle Werte und Unterschlüssel werden abgerufen.
• 2 = Nur die Unterschlüssel werden abgerufen (nicht die Werte).

Rekursiv?

Wenn dieser Parameter weggelassen wird oder leer ist, wird standardmäßig 0 (Unterschlüssel werden nicht rekursiv durchwandert) verwendet. Ansonsten können Sie eine der folgenden Ziffern angeben:

• 0 = Unterschlüssel werden nicht rekursiv durchwandert.
• 1 = Unterschlüssel werden rekursiv durchwandert, was zur Folge hat, dass alle darin enthaltene Werte und Unterschlüssel abgerufen werden.

Bemerkungen

Eine Registry-Schleife ist nützlich, um mehrere Werte und Unterschlüssel einzeln abzuarbeiten. Die Werte und Unterschlüssel werden in umgekehrter Reihenfolge abgerufen (von unten nach oben), so dass RegDelete innerhalb der Schleife verwendet werden kann, ohne die Schleife zu unterbrechen.

Die folgenden Variablen sind nur in einer Registry-Schleife von Bedeutung. Wenn eine innere Registry-Schleife von einer äußeren Registry-Schleife umschlossen ist, hat das Element der innersten Schleife Vorrang:

Innerhalb einer Registry-Schleife können bei folgenden Befehlen die Parameter weggelassen werden, um zu kennzeichnen, dass das aktuell abgerufene Element abgearbeitet werden soll:

Beim Zugriff auf eine Remote-Registry (über den RootSchlüssel- oder SchlüsselName-Parameter, wie oben beschrieben) gelten folgende Hinweise:

• Auf dem Zielrechner muss der Dienst "Remote Registry" laufen.
• Der Zugriff auf eine Remote-Registry kann fehlschlagen, wenn der Zielcomputer nicht zur Domäne des Benutzers gehört oder der Benutzername nicht genügend Berechtigungen hat (siehe unten für mögliche Übergangslösungen).
• Abhängig von der Domäne, der Arbeitsgruppe und/oder den Berechtigungen kann es sein, dass sich der Benutzer mit einem freigegebenen Gerät erst verbinden muss (z. B. durch eine Laufwerkszuordnung), bevor der Remotezugriff auf die Registry erfolgt. Das Aufbauen von so einer Verbindung -- unter Verwendung eines Remote-Benutzernamens, der zum Bearbeiten der Registry berechtigt ist -- könnte auch dazu führen, dass der Remote-Registry-Zugriff aktiviert wird.
• Wenn Sie bereits mit einem anderen Benutzernamen auf dem Zielcomputer angemeldet sind (z. B. als Gast auf ein zugeordnetes Laufwerk), müssen Sie wahrscheinlich zuvor diese Verbindung beenden, so dass die Remote-Registry sich neu verbinden und Ihren aktuell angemeldeten Benutzernamen authentifizieren kann.
• Für Windows Server 2003 und Windows XP Professional heißt es in MSDN: "Wenn der [Server der Registry] Computer mit einer Arbeitsgruppe verbunden ist und die Sicherheitsrichtlinie Einfache Dateifreigabe aktiviert ist, dann schlägt die Funktion fehl. Beachten Sie, dass diese Sicherheitsrichtlinie standardmäßig aktiviert ist, wenn der Computer mit einer Arbeitsgruppe verbunden ist."
• Für Windows XP Home Edition weist MSDN darauf hin, dass "diese Funktion immer fehlschlägt". In der Home Edition fehlt für die Registry sowohl der Server als auch der Client, jedoch kann der Client aus einer CAB-Datei des Betriebssystems extrahiert werden.

Auf der Loop-Seite finden Sie Informationen zu Blöcken, Break, Continue und A_Index (sie können in jeder Schleifenvariante verwendet werden).

Siehe auch

Loop, Break, Continue, Blöcke, RegRead, RegWrite, RegDelete, SetRegView

Beispiele

Loop, HKEY_CURRENT_USER, Software\Microsoft\Internet Explorer\TypedURLs
    RegDelete

Loop, Reg, HKEY_CURRENT_USER\Software\Microsoft\Windows, KVR
{
    if (A_LoopRegType = "key")
        Wert := ""
    else
    {
        RegRead, Wert
        if ErrorLevel
            Wert := "*error*"
    }
    MsgBox, 4, , %A_LoopRegType% = %Wert% (%A_LoopRegType%)`n`nWeiter?
    IfMsgBox, NO, break
}

SetBatchLines -1  ; Führt die Operation mit maximaler Geschwindigkeit aus.
RegSuchziel := "Notepad"  ; Teilt der Subroutine mit, was gesucht werden soll.
Gosub, RegSuche
return

RegSuche:
RegSucheFortfahren := true
Loop, Reg, HKEY_LOCAL_MACHINE, KVR
{
    Gosub, RegElementPrüfen
    if not RegSucheFortfahren ; Teilt uns mit, dass sie gestoppt werden soll.
        return
}
Loop, Reg, HKEY_USERS, KVR
{
    Gosub, RegElementPrüfen
    if not RegSucheFortfahren ; Teilt uns mit, dass sie gestoppt werden soll.
        return
}
Loop, Reg, HKEY_CURRENT_CONFIG, KVR
{
    Gosub, RegElementPrüfen
    if not RegSucheFortfahren ; Teilt uns mit, dass sie gestoppt werden soll.
        return
}
; Hinweis: Ich glaube, dass HKEY_CURRENT_USER nicht durchsucht werden muss,
; wenn HKEY_USERS durchsucht wird.  Das gleiche könnte auch für HKEY_CLASSES_ROOT gelten,
; wenn HKEY_LOCAL_MACHINE durchsucht wird.
return

RegElementPrüfen:
if (A_LoopRegType = "KEY")  ; Entfernen Sie diese zwei Zeilen, wenn Sie die Schlüsselnamen auch überprüfen lassen wollen.
    return
RegRead, RegWert
if ErrorLevel
    return
if InStr(RegWert, RegSuchziel)
{
    MsgBox, 4, , Der folgende Treffer wurde gefunden:`n%A_LoopRegKey%\%A_LoopRegSubKey%\%A_LoopRegName%`nWert = %RegWert%`n`nWeiter?
    IfMsgBox, No
        RegSucheFortfahren := false  ; Teilt unserem Aufrufer mit, die Suche zu stoppen.
}
return