SoundGet

Ermittelt diverse Einstellungen eines Audiogeräts (Master-Stummschaltung, Master-Lautstärke und so weiter).

SoundGet, AusgabeVar , Komponente, Regler, GerätNummer

Parameter

AusgabeVar

Name der Ausgabevariable, in der die abgerufene Einstellung gespeichert werden soll, welche entweder eine Floating-Point-Zahl zwischen 0 und 100 oder das Wort ON oder OFF ist (gilt nur für die Regler ONOFF, MUTE, MONO, LOUDNESS, STEREOENH und BASSBOOST). Die Variable wird leer gemacht, wenn ein Problem beim Abrufen der Einstellung aufgetreten ist. Das Format der Floating-Point-Zahl, z. B. deren Dezimalstellen, wird über SetFormat bestimmt.

Komponente

Wenn dieser Parameter weggelassen wird oder leer ist, wird standardmäßig das Wort MASTER verwendet. Ansonsten kann eines der folgenden Wörter angegeben werden: MASTER (gleichbedeutend mit SPEAKERS), DIGITAL, LINE, MICROPHONE, SYNTH, CD, TELEPHONE, PCSPEAKER, WAVE, AUX, ANALOG, HEADPHONES oder N/A. Wenn das Audiogerät die angegebene Komponente nicht hat, wird ErrorLevel das Problem kennzeichnen.

Die Komponente mit der Bezeichnung Auxiliary muss bei einigen Mixern eventuell via ANALOG statt AUX angesteuert werden.

Wenn ein Gerät mehr als eine Instanz der Komponente hat (zum Beispiel zwei vom Typ LINE), enthält die erste Instanz für gewöhnlich die Wiedergabeeinstellungen und die zweite die Aufnahmeeinstellungen. Um anstelle der ersten Instanz auf eine andere zuzugreifen, müssen Sie nach diesem Parameter ein Doppelpunkt und eine Nummer anfügen. Zum Beispiel: Analog:2 ist die zweite Instanz der analogen Komponente.

Regler

Wenn dieser Parameter weggelassen wird oder leer ist, wird standardmäßig das Wort VOLUME verwendet. Ansonsten kann eines der folgenden Wörter angegeben werden: VOLUME (oder VOL), ONOFF, MUTE, MONO, LOUDNESS, STEREOENH, BASSBOOST, PAN, QSOUNDPAN, BASS, TREBLE, EQUALIZER oder die Nummer eines gültigen Reglers (siehe Soundkartenanalyse-Skript). Wenn die angegebene Komponente den angegebenen Regler nicht hat, wird ErrorLevel das Problem kennzeichnen.

Hinweis: Soundgeräte unterstützen üblicherweise nur VOLUME (oder VOL) und MUTE, auch wenn andere je nach Windows-Version und dem Soundgerät verfügbar sein könnten.

GerätNummer

Eine Nummer zwischen 1 und Gesamtanzahl an unterstützten Geräten. Lässt man diesen Parameter weg, wird standardmäßig 1 verwendet (das erste Audiogerät), oder in Windows Vista oder höher das standardmäßig verwendete Wiedergabegerät des Systems. Dieser Parameter kann ein Ausdruck sein. Das Soundkartenanalyse-Skript könnte dabei helfen, welche Nummer verwendet werden soll.

Fehlerbehandlung

[v1.1.04+]: Dieser Befehl ist in der Lage, bei Misserfolg eine Ausnahme auszulösen. Weitere Informationen finden Sie unter Laufzeitfehler.

ErrorLevel wird auf 0 gesetzt, wenn der Befehl erfolgreich war. Ansonsten wird es auf einen der folgenden Sätze gesetzt:

• Invalid Control Type or Component Type (ungültiger Regler oder Komponente)
• Can't Open Specified Mixer (der angegebene Mixer konnte nicht geöffnet werden)
• Mixer Doesn't Support This Component Type (Mixer unterstützt diese Komponente nicht)
• Mixer Doesn't Have That Many of That Component Type (Mixer hat nicht so viele von dieser Komponente)
• Component Doesn't Support This Control Type (Komponente unterstützt diesen Regler nicht)
• Can't Get Current Setting (aktuelle Einstellung konnte nicht ermittelt werden)

Bemerkungen

Seit v1.1.10 wird Windows Vista und höher unterstützt.

Um den Leistungsumfang der installierten Audiogeräte (Mixer) zu ermitteln -- z. B. verfügbare Komponenten und Regler -- führen Sie das Soundkartenanalyse-Skript aus.

Für mehr Funktionalität und feinere Audio-Steuerung ist die VA-Bibliothek besser geeignet.

Mit SoundSet kann eine Einstellung geändert werden.

Siehe auch

SoundSet, SoundGetWaveVolume, SoundSetWaveVolume, SoundPlay

Beispiele

SoundGet, master_volume
MsgBox, Master-Lautstärke ist bei %master_volume% Prozent.

SoundGet, master_mute,, Mute
MsgBox, Master-Stummschaltung ist zurzeit %master_mute%.

SoundGet, bass_level, Master, Bass
if ErrorLevel
    MsgBox, Fehlerbeschreibung: %ErrorLevel%
else
    MsgBox, Der BASS-Pegel für MASTER ist bei %bass_level% Prozent.

SoundGet, microphone_mute, Microphone, Mute
if (microphone_mute = "Off")
    MsgBox, Das Mikrofon ist nicht stummgeschaltet.