SoundSet - Syntax & Verwendung

Ändert verschiedene Einstellungen eines Audiogeräts (Master-Stummschaltung, Master-Lautstärke usw.).

Parameter

Fehlerbehandlung

[v1.1.04+]: Dieser Befehl ist in der Lage, bei Misserfolg eine Ausnahme auszulösen. Weitere Informationen finden Sie unter Laufzeitfehler.

ErrorLevel wird auf 0 gesetzt, wenn der Befehl erfolgreich war. Andernfalls wird es auf einen der folgenden Sätze gesetzt:

Bemerkungen

Für mehr Funktionalität und feinere Audiosteuerung ist die VA-Bibliothek besser geeignet.

Um die Master-Lautstärke des gesamten Systems zu ändern, kann alternativ ein Skript verwendet werden, das lautstärkespezifische Tastendrücke sendet. Zum Beispiel:

Um den Leistungsumfang der installierten Audiogeräte (Mixer) zu ermitteln - z.B. die verfügbaren Komponenten- und Reglertypen - führen Sie das Soundkartenanalyse-Skript aus.

Windows 2000/XP/2003: Wenn SoundSet die Lautstärke einer Komponente ändert, werden alle Kanäle dieser Komponente (z.B. links und rechts) auf den gleichen Pegel gesetzt. Mit anderen Worten, jede zuvor eingestellte außermittige "Balance" geht verloren. Dies lässt sich bei der WAVE-Komponente durch Nutzung von SoundSetWaveVolume vermeiden, denn es versucht, die bestehende Balance beim Ändern der Lautstärke beizubehalten.

[v1.1.10+]: In Windows Vista und höher versucht SoundSet, die bestehende Balance beim Ändern der Lautstärke beizubehalten.

Siehe auch

Beispiele

Soundkartenanalyse. Das folgende Skript kann verwendet werden, um die Fähigkeiten Ihrer Soundkarte zu ermitteln (Komponenten- und Reglertypen). Es zeigt die Ergebnisse in einer einfachen ListView an. Alternativ kann ein Skript für Windows Vista oder höher heruntergeladen werden, das mehr Details liefert (z.B. die Anzeigenamen der Geräte): https://www.autohotkey.com/board/topic/90877-/

SetBatchLines -1
SplashTextOn,,, Informationen der Soundkarte ermitteln ...

; Die meisten der unten angegebenen reinen Zahlen sind wahrscheinlich nicht in jedem Mixer vorhanden, werden aber der Vollständigkeit halber abgefragt.
; Die Zahlen beziehen sich auf folgende Elemente (in Reihenfolge): CUSTOM, BOOLEANMETER, SIGNEDMETER, PEAKMETER,
; UNSIGNEDMETER, BOOLEAN, BUTTON, DECIBELS, SIGNED, UNSIGNED, PERCENT, SLIDER, FADER, SINGLESELECT, MUX,
; MULTIPLESELECT, MIXER, MICROTIME, MILLITIME
ReglerTypen := "VOLUME,ONOFF,MUTE,MONO,LOUDNESS,STEREOENH,BASSBOOST,PAN,QSOUNDPAN,BASS,TREBLE,EQUALIZER,0x00000000, 0x10010000,0x10020000,0x10020001,0x10030000,0x20010000,0x21010000,0x30040000,0x30020000,0x30030000,0x30050000,0x40020000,0x50030000,0x70010000,0x70010001,0x71010000,0x71010001,0x60030000,0x61030000"

KomponenteTypen := "MASTER,HEADPHONES,DIGITAL,LINE,MICROPHONE,SYNTH,CD,TELEPHONE,PCSPEAKER,WAVE,AUX,ANALOG,N/A"

; Eine ListView erstellen und für die Hauptschleife vorbereiten:
Gui, Add, ListView, w400 h400 vMeineListView, Komponententyp|Reglertyp|Einstellung|Mixer
LV_ModifyCol(4, "Integer")
SetFormat, Float, 0.2  ; Anzahl der Dezimalstellen einer Prozentzahl auf 2 begrenzen.

Loop  ; Für jeden Mixer im System seine Fähigkeiten abrufen.
{
    AktMixer := A_Index
    SoundGet, Einstellung,,, %AktMixer%
    if (ErrorLevel = "Can't Open Specified Mixer")  ; Jeder andere Fehler gibt an, dass der Mixer existiert.
        break

    ; Für jeden Komponententyp in diesem Mixer seine Instanzen und Reglertypen abrufen:
    Loop, parse, KomponenteTypen, `,
    {
        AktKomponente := A_LoopField
        ; Zuerst prüfen, ob dieser Komponententyp überhaupt im Mixer existiert:
        SoundGet, Einstellung, %AktKomponente%,, %AktMixer%
        if (ErrorLevel = "Mixer Doesn't Support This Component Type")
            continue  ; Neue Wiederholung starten, um mit dem nächsten Komponententyp fortzufahren.
        Loop  ; Für jede Instanz dieses Komponententyps seine Reglertypen abrufen.
        {
            AktInstanz := A_Index
            ; Zuerst prüfen, ob diese Instanz dieser Instanz überhaupt im Mixer existiert:
            SoundGet, Einstellung, %AktKomponente%:%AktInstanz%,, %AktMixer%
            ; Die Prüfung der beiden folgenden Fehler ermöglicht die Skriptausführung auf älteren Systemen:
            if ErrorLevel in Mixer Doesn't Have That Many of That Component Type,Invalid Control Type or Component Type
                break  ; Keine weiteren Instanzen von diesem Komponententyp.
            ; Ermittelt die aktuelle Einstellung jedes Reglertyps, der in dieser Instanz dieser Komponente existiert:
            Loop, parse, ReglerTypen, `,
            {
                AktRegler := A_LoopField
                SoundGet, Einstellung, %AktKomponente%:%AktInstanz%, %AktRegler%, %AktMixer%
                ; Die Prüfung der beiden folgenden Fehler ermöglicht die Skriptausführung auf älteren Systemen:
                if ErrorLevel in Component Doesn't Support This Control Type,Invalid Control Type or Component Type
                    continue
                if ErrorLevel  ; Ein anderer unerwarteter Fehler, also in den Ergebnissen anzeigen.
                    Einstellung := ErrorLevel
                KomponenteZkette := AktKomponente
                if (AktInstanz > 1)
                    KomponenteZkette := KomponenteZkette ":" AktInstanz
                LV_Add("", KomponenteZkette, AktRegler, Einstellung, AktMixer)
            }  ; Für jeden Reglertyp.
        }  ; Für jede Instanz der Komponente.
    }  ; Für jeden Komponententyp.
}  ; Für jeden Mixer.

Loop % LV_GetCount("Col")  ; Breite jeder Spalte an ihren Inhalt anpassen.
    LV_ModifyCol(A_Index, "AutoHdr")

SplashTextOff
Gui, Show
return

GuiClose:
ExitApp